Time Saver (redundant Screenshot+ snippets).ahk

    PrintScreen = SCREENSHOT+
        Quick-press to use native fn, double-press to save to desktop as well & long-press to take screenshot or keep previous on demand, saving either one to desktop.


*PrintScreen::
{
    static _ := OnClipboardChange(HandleClipChanged), hasScreenshotInClipboard := false, latestScreenshotTime := 0, dialogCountdown
    pressStartTime := A_TickCount
    shouldTakeNewScreenshot := 0

    loop
    {
        Sleep(10)

        if (!GetKeyState("PrintScreen", "P"))
        {
            ; PrintScreen Quick-Press. This takes a new screenshot
            if (A_TickCount - latestScreenshotTime > 500)
            {
                Send("{Blind}{PrintScreen}") ; Blind mode allows the native Win+PrtScn hotkey to save it in the `Screenshots` folder
                latestScreenshotTime := A_TickCount

                return
            }

            ; PrintScreen Double-Press. This saves the screenshot of the first press to desktop
            break
        }

        ; PrintScreen Long-Press. This conditionally takes a new screenshot and saves a screenshot to desktop
        if (A_TickCount - pressStartTime > 750)
        {
            ; To identify a long-press and to execute the default action for long-press
            shouldTakeNewScreenshot := "OK"

            break
        }
    }

    ; Auto-saving any existing screenshot that is currently in the clipboard on long-press, w/ the option to take a new screenshot instead
    if (shouldTakeNewScreenshot := "OK" && hasScreenshotInClipboard) ;DllCall("IsClipboardFormatAvailable", "UInt", CF_BITMAP := 2))
    {
        dialogCountdown := 8
        HookEvent(EVENT_OBJECT_CREATE, HandleCreatedDialogEvent)
        shouldTakeNewScreenshot := MsgBox("Auto-saving in 8 seconds..", "Existing image in clipboard detected!", "0x40000 T8") ; Saves "OK" or "Timeout"
        Sleep(200) ; Waiting for the dialog close animation to end
    }

    if (shouldTakeNewScreenshot = "OK")
    Send("{PrintScreen}"), latestScreenshotTime := A_TickCount

    RunWait("PowerShell.exe -Command `"$img = get-clipboard -format image; $img.save('" A_Desktop "\screenshot " A_Now ".jpg')`"",, "Hide")
    TrayTip("Saved to desktop", "Screenshot taken", 0x34)
    SetTimer(HideTrayTip, -4000)
    KeyWait("PrintScreen") ; Prevents the printscreen hotkey from triggering again while it's still pressed down

    HandleClipChanged(*) => hasScreenshotInClipboard := A_TickCount - latestScreenshotTime < 1000

    HandleCreatedDialogEvent(hWinEventHook, event, hWnd, *)
    {
        try
            if (WinGetClass(hWnd) = "#32770")
            {
                DllCall("UnhookWinEvent", "Ptr", hWinEventHook)
                DllCall("EnableMenuItem", "Ptr", DllCall("GetSystemMenu", "UInt", hWnd, "Int", 0), "UInt", SC_CLOSE := 0xF060, "UInt", MF_GRAYED := 0x00000001)
                ControlMove(24,, 150,, "Button1", hWnd)
                ControlSetText("Take New Screenshot", "Button1", hWnd)
                SetTimer(() => UpdateDialogTime(hWnd), 1000)
            }

        UpdateDialogTime(hWnd)
        {
            try ControlSetText("Auto-saving in " (--dialogCountdown) " seconds..", "Static1", hWnd)
            catch
                SetTimer(, 0)
        }
    }
}