Follow the sound

10 gosub 60000 : rem screen
11 gosub 60500 : rem inizializza SID
12 gosub 60300 : rem inizializza un po' di variabili
14 gosub 10000 : rem inizializza generatore random
15 for q= 1 to 5: k=s(q): r=400: if q=5 then r=800
16 gosub 59900: next: so=1:st$="{reverse on}{red}premi un tasto":gosub 21100
18 r=500: rem lunghezza note
20 lv=lv+1: sl=1: rem l = livello e sl = sottolivello
30 sq$ = "": print "{home}{white}livello";lv;" sottolivello";sl;" vite:";vt
40 for q= 1 to lv+1: gosub 10040: k=rd: gosub 59900
50 sq$ = sq$ + str$(rd):next
60 so=0:st$="{reverse on}{yellow}ripeti":gosub 21100
62 gosub 100:if er=1 then vt=vt-1: if vt = 0 thengoto 80
65 r=r-240: sl=sl+1:if sl>2 then r=500:goto20
70 goto 30
80 end


 99 rem Routine di controllo della sequenza
100 pt = 0:er=0
105 get a$
110 if a$ = "i" then k = 1: goto160
120 if a$ = "o" then k = 2: goto160
130 if a$ = "k" then k = 3: goto160
140 if a$ = "l" then k = 4: goto160
150 goto 105
160 pt=pt+1: ct$ = mid$(sq$, pt*2-1, 2)
170 gosub 59900
175 if ct$ <> str$(k) then er=1:so=1:st$="{reverse on}{red}errore":gosub 21100: goto 200
180 if pt = int(len(sq$)/2) then :so=1:st$="{reverse on}{red}  ok  ":gosub 21100: goto 200:rem sequenza conclusa correttamente
190 goto 105
200 return

9999 rem init voice 3 rumore random
10000 poke 54286, 255: rem LSB voce 3 frequenza d'onda al massimo
10010 poke 54287, 255: rem MSB voce 3 frequenza d'onda al massimo
10020 poke 54290, 128: rem Voce 3, rumore bianco, senza attivare audio
10030 return

10039 rem random 1 4
10040 rd = peek(54299)
10045 rd = rd - int(rd/4)*4 + 1
10050 return

21000 poke 780,0
21010 poke 781,y
21020 poke 782,x
21030 sys 65520
21040 return

21099 rem stampa una stringa al centro dello schermo e attende un tasto se so = 1
21100 y=12:x= 19 - int(len(st$)/2):gosub 21000
21120 print st$: if so<>1 goto 21160
21130 poke 198,0: wait 198,1:poke 198,0
21140 y=12:x=0:gosub 21000
21150 print "       {cyan}{reverse on} {reverse off}{096}{096}{096}{096}{096}{096}{096}{096}{096}{096}{096}{123}{096}{096}{096}{096}{096}{096}{096}{096}{096}{096}{096}{reverse on} "
21160 return


59900 poke SB+0,fl(k): poke SB+1,fh(k): poke SB+24,15
59910 x=px(k):y=py(k)
59915 for j = 1 to 2
59916 c$="{reverse off}"
59918 if j = 1 then c$ = "{reverse on}" + co$(k)
59920 gosub 21000
59925 print c$ + t$(k)
59945 if j = 2 goto 59955
59950 for i = 1 to r: next
59952 poke sb+24,0
59955 next
59980 return


60000 print "                   {reverse on}{cyan} "
60010 print " fff ooo l        {reverse on}{191}{reverse off}B{191}     l   ooo w   w"
60020 print " f   o o l       {reverse on}{191}{reverse off} B {191}    l   o o w   w"
60030 print " ff  o o l      {reverse on}{191}{reverse off}  B  {191}   l   o o w w w"
60040 print " f   o o l     {reverse on}{191}{reverse off}   B   {191}  l   o o w w w"
60050 print " f   ooo lll  {reverse on}{191}{reverse off}    B    {191} lll ooo ww ww"
60060 print "             {reverse on}{191}{reverse off}     B     {191}"
60070 print "            {reverse on}{191}{reverse off}      B      {191}"
60080 print "           {reverse on}{191}{reverse off}       B       {191}"
60090 print "          {reverse on}{191}{reverse off}        B        {191}"
60100 print "         {reverse on}{191}{reverse off}         B         {191}"
60110 print "        {reverse on}{191}{reverse off}          B          {191}"
60120 print "       {reverse on} {reverse off}{096}{096}{096}{096}{096}{096}{096}{096}{096}{096}{096}{123}{096}{096}{096}{096}{096}{096}{096}{096}{096}{096}{096}{reverse on} "
60130 print "        {191}          B          {reverse on}{191}"
60140 print "         {191}         B         {reverse on}{191}"
60150 print "          {191}        B        {reverse on}{191}"
60160 print "           {191}       B       {reverse on}{191}"
60170 print "            {191}      B      {reverse on}{191}"
60180 print "             {191}     B     {reverse on}{191}"
60190 print "              {191}    B    {reverse on}{191}"
60200 print "               {191}   B   {reverse on}{191}"
60210 print "                {191}  B  {reverse on}{191}"
60220 print "                 {191} B {reverse on}{191}"
60230 print "                  {191}B{reverse on}{191}"
60240 print "tasti iokl         {reverse on} {reverse off} {reverse on}by gdm soft";
60250 return

60300 fh(1)=12:fh(2)=14:fh(3)=11:fh(4)=8
60310 fl(1)=43:fl(2)=24:fl(3)=48:fl(4)=97
60320 t$(1)=" {down}{left*2}  {down}{left*3}   {down}{left*4}    {down}{left*5}     "
60330 t$(1)=t$(1)+"{down}{left*6}      {down}{left*7}       {down}{left*8}        "
60340 t$(1)=t$(1)+"{down}{left*9}         {down}{left*10}          "
60350 t$(2)=" {down}{left}  {down}{left*2}   {down}{left*3}    {down}{left*4}     "
60360 t$(2)=t$(2)+"{down}{left*5}      {down}{left*6}       {down}{left*7}        {down}{left*8}         "
60370 t$(2)=t$(2)+"{down}{left*9}          "
60380 t$(3)=" {up}{left*2}  {up}{left*3}   {up}{left*4}    {up}{left*5}     "
60390 t$(3)=t$(3)+"{up}{left*6}      {up}{left*7}       {up}{left*8}        "
60400 t$(3)=t$(3)+"{up}{left*9}         {up}{left*10}          "
60410 t$(4)=" {up}{left}  {up}{left*2}   {up}{left*3}    {up}{left*4}     "
60420 t$(4)=t$(4)+"{up}{left*5}      {up}{left*6}       {up}{left*7}        {up}{left*8}         "
60430 t$(4)=t$(4)+"{up}{left*9}          "
60440 px(1)=18:px(2)=20:px(3)=18:px(4)=20
60450 py(1)=2:py(2)=2:py(3)=22:py(4)=22
60455 s(1)=1:s(2)=2:s(3)=3:s(4)=3:s(5)=4
60460 co$(1)="{yellow}":co$(2)="{red}":co$(3)="{green}":co$(4)="{blue}"
60470 poke 53281,0:er=0:vt=3
60498 return

60499 rem SID BASE
60500 SB = 54272
60530 poke SB+24,0: rem volume 0-15
60550 poke SB+2,128: poke SB+3,8
60560 poke SB+5,97: poke SB+6,200
60570 poke SB+4,65
60580 return