קבלת נתונים מן הבקר לפיירבייס

#include <Arduino.h>

// חיבור ספריות Wi-Fi בהתאם לסוג הבקר (ESP32 או ESP8266)
#if defined(ESP32)
  #include <WiFi.h>
#elif defined(ESP8266)
  #include <ESP8266WiFi.h>
#endif

#include <Firebase_ESP_Client.h>

// ספריות לטיפול בתהליכי יצירת אסימונים ועזרי Firebase
#include "addons/TokenHelper.h" // מספק מידע על יצירת אסימונים
#include "addons/RTDBHelper.h"  // מספק כלים לעבודה עם נתוני RTDB

// פרטי החיבור לרשת האלחוטית
#define WIFI_SSID "Galaxy S22+3663"        // שם הרשת (SSID) פה לשנות!!!!!!!!!!!!!!!!
#define WIFI_PASSWORD "fnyh1479"          // סיסמת הרשת פה לשנות!!!!!!!!!!!!!!!!

// מפתח API של פרויקט Firebase
#define API_KEY "AIzaSyAjG_MOsClpLU7N7o-D1PkI08_tFO84w-c"  // מפתח API של Firebase פה לשנות!!!!!!!!!!!!!!!!

// כתובת URL של מסד הנתונים בזמן אמת (RTDB) של Firebase
#define DATABASE_URL "https://facerecognition-tank-default-rtdb.firebaseio.com"  // כתובת RTDB פה לשנות!!!!!!!!!!!!!!!!

// יצירת אובייקט נתונים ל-Firebase
FirebaseData fbdo;

// אובייקטים עבור אימות והגדרות Firebase
FirebaseAuth auth;
FirebaseConfig config;

// משתנים לשליטה בזמני העלאת הנתונים וספירה
unsigned long sendDataPrevMillis = 0; // משתנה לשמירת זמן ההעלאה האחרון
int count = 0;  // מונה נתונים
bool signupOK = false;  // סטטוס הרשמה ל-Firebase

void setup() {
  Serial.begin(115200); // אתחול חיבור סריאלי לניפוי שגיאות

  WiFi.begin(WIFI_SSID, WIFI_PASSWORD); // התחברות ל-Wi-Fi
  Serial.print("Connecting to Wi-Fi");
  while (WiFi.status() != WL_CONNECTED) { // המתנה עד לחיבור
    Serial.print(".");
    delay(300);
  }
  Serial.println();
  Serial.print("Connected with IP: ");
  Serial.println(WiFi.localIP()); // הצגת כתובת IP
  Serial.println();

  config.api_key = API_KEY; // הגדרת מפתח ה-API
  config.database_url = DATABASE_URL; // הגדרת כתובת RTDB

  if (Firebase.signUp(&config, &auth, "", "")) { // הרשמה אנונימית ל-Firebase
    Serial.println("ok");
    signupOK = true; // אם ההרשמה הצליחה
  } else {
    Serial.printf("%s\n", config.signer.signupError.message.c_str()); // הצגת שגיאת הרשמה
  }

  config.token_status_callback = tokenStatusCallback; // פונקציה לטיפול במצב האסימון
  Firebase.begin(&config, &auth); // אתחול Firebase
  Firebase.reconnectWiFi(true); // הפעלה מחדש של חיבור Wi-Fi במידת הצורך
}

void loop() {
  if (Firebase.ready() && signupOK && (millis() - sendDataPrevMillis > 15000 || sendDataPrevMillis == 0)) { // בדיקת מוכנות Firebase והמתנה של 15 שניות
    sendDataPrevMillis = millis(); // עדכון הזמן האחרון

    if (Firebase.RTDB.setInt(&fbdo, "test/int", count)) { // כתיבת ערך שלם למסד הנתונים בנתיב "test/int"
      Serial.println("PASSED");
      Serial.println("PATH: " + fbdo.dataPath());
      Serial.println("TYPE: " + fbdo.dataType());
    } else {
      Serial.println("FAILED");
      Serial.println("REASON: " + fbdo.errorReason());
    }
    count++; // הגדלת המונה

    if (Firebase.RTDB.setFloat(&fbdo, "test/float", 0.01 + random(0, 100))) { // כתיבת ערך נקודה צפה בנתיב "test/float"
      Serial.println("PASSED");
      Serial.println("PATH: " + fbdo.dataPath());
      Serial.println("TYPE: " + fbdo.dataType());
    } else {
      Serial.println("FAILED");
      Serial.println("REASON: " + fbdo.errorReason());
    }
  }
}