stock ShowMobileBank(playerid)
{
    #if defined VICECITY
        if (vicecity_SetupPlayerBankPin(playerid)) return 1;
    #endif

    if(!BankMenu:CheckPlayerHaveCard(playerid)) {
        return 1;
    }

    PI[playerid][pKlogin] = 1;

    if(PI[playerid][pView]>0) return SendClientMessage(playerid,COLOR_LIGHTRED,"[Ошибка] {FFFFFF}Вы не можете использовать мобильный банкинг в психушке!");

    new bankstr[1000];
    new count = 0;

    PlayerDialogListItem[playerid][count++] = 0;
    PlayerDialogListItem[playerid][count++] = 1;
    PlayerDialogListItem[playerid][count++] = 2;
    PlayerDialogListItem[playerid][count++] = 3;

    bankstr = "{FFFFFF}\
        1. Состояние основного счета\n\
        2. Состояние {DBEF2A}личных {FFFFFF}счетов\n\
        3. Перевести деньги с основного счета\n\
        4. Пополнить счет {DBEF2A}SIM{FFFFFF}\n";

    if(IsPlayerVipAddition(playerid)) {

        if(PI[playerid][pFMember] != -1)
        {
            if(GetFamilyBest(PI[playerid][pFMember], 10) == 1)
            {
                strcat(bankstr, "{ffff00}Оплата всех налогов{FFFFFF}\n"); // BANK_MENU_ITEM_ALL_NALOG_PAY
                PlayerDialogListItem[playerid][count++] = 4;
            }
        }

        strcat(bankstr, "{73B461}Оплатить налог на транспорт{FFFFFF}\n"); // BANK_MENU_ITEM_CAR_NALOG_PAY
        PlayerDialogListItem[playerid][count++] = 5;

        strcat(bankstr, "{73B461}Оплатить штраф за восстановление транспорта{FFFFFF}\n"); // BANK_MENU_ITEM_CAR_TICKET_PAY
        PlayerDialogListItem[playerid][count++] = 6;

        strcat(bankstr, "{73B461}Оплатить судебный штраф{FFFFFF}\n"); // BANK_MENU_ITEM_COURT_FINE_PAY
        PlayerDialogListItem[playerid][count++] = 13;

        if(IsPlayerHouse(playerid))
        {
            strcat(bankstr, "{73B461}Оплатить коммуналку{FFFFFF}\n"); // BANK_MENU_ITEM_HOUSE_MED_PAY
            PlayerDialogListItem[playerid][count++] = 7;

            strcat(bankstr, "{73B461}Оплатить налоги на дом{FFFFFF}\n"); // BANK_MENU_ITEM_HOUSE_TAX_PAY
            PlayerDialogListItem[playerid][count++] = 8;

            strcat(bankstr, "{73B461}Пополнить счёт на электричество{FFFFFF}\n"); // BANK_MENU_ITEM_HOUSE_ELECTRO
            PlayerDialogListItem[playerid][count++] = 9;
        }
        if(GetPlayerBiz(playerid)!=-1)
        {
            strcat(bankstr, "{73B461}Оплатить налоги на бизнес{FFFFFF}\n"); // BANK_MENU_ITEM_BIZ_TAX_PAY
            PlayerDialogListItem[playerid][count++] = 10;
        }

        if (!IsViceCityServer())
        {
            if (PI[playerid][pFarmID] != -1 || PI[playerid][pFarmID2] != -1)
            {
                strcat(bankstr, "{73B461}Оплатить налоги на ферму{FFFFFF}\n"); // BANK_MENU_ITEM_FARM_TAX_PAY
                PlayerDialogListItem[playerid][count++] = 11;
            }
        }

        if(PI[playerid][pHotelID] != -1) {
            strcat(bankstr, "{73B461}Продлить аренду номера в отеле{FFFFFF}\n"); // BANK_MENU_ITEM_HOTEL_PAYMENT
            PlayerDialogListItem[playerid][count++] = 12;
        }

    }

    ShowPlayerDialog(playerid, DID_NUMBER_6565,2,"",bankstr,"Принять","Отмена");
    return 1;
}