API tools faq
paste
Advertisement
RuiViana

Untitled

RuiViana
Jun 4th, 2015
360
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 23.27 KB | None | 0 0
raw download clone embed print report
  1. /*
  2. // http://pastebin.com/P4C00ESE
  3.  
  4. Modbus serial - RTU Slave Arduino Sketch
  5.  
  6. Marcos Daniel Wiechert wiechertdaniel@yahoo.com.br
  7.  
  8. Baseado na biblioteca de Juan Pablo Zometa : jpmzometa@gmail.com
  9. http://sites.google.com/site/jpmzometa/
  10. and Samuel Marco: sammarcoarmengol@gmail.com
  11. and Andras Tucsni.
  12.  
  13. As funções do protocolo MODBUS implementadas neste código:
  14. 3 - Read holding registers;
  15. 6 - Preset single register;
  16. 16 - Preset multiple registers.
  17.  
  18. This program is free software; you can redistribute it and/or modify
  19. it under the terms of the GNU General Public License as published by
  20. the Free Software Foundation; either version 2 of the License, or
  21. (at your option) any later version.
  22.  
  23. This program is distributed in the hope that it will be useful,
  24. but WITHOUT ANY WARRANTY; without even the implied warranty of
  25. MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  26. GNU General Public License for more details.
  27.  
  28. You should have received a copy of the GNU General Public License
  29. along with this program; if not, write to the Free Software
  30. Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  31.  
  32. The functions included here have been derived from the
  33. Modicon Modbus Protocol Reference Guide
  34. which can be obtained from Schneider at www.schneiderautomation.com.
  35.  
  36. This code has its origins with
  37. paul@pmcrae.freeserve.co.uk (http://www.pmcrae.freeserve.co.uk)
  38. who wrote a small program to read 100 registers from a modbus slave.
  39.  
  40. */
  41.  
  42.  
  43. /*
  44. * configure_mb_slave(baud, parity, tx_en_pin)
  45. *
  46. * configuração dos parametros da porta serial.
  47. *
  48. * baud: taxa de transmissão em bps (valores típicos entre 9600, 19200... 115200)
  49. * parity: seta o modo de paridade:
  50. * 'n' sem paridade (8N1); 'e' paridede impar (8E1), 'o' paridade par (8O1).
  51. * tx_en_pin: pino do arduino que controla a transmissão/recepção em uma linha RS485.
  52. * 0 or 1 desliga esta função (para rede RS232)
  53. * >2 para uma rede multiponto.
  54. */
  55. void configure_mb_slave(long baud, char parity, char txenpin);
  56.  
  57. /*
  58. * update_mb_slave(slave_id, holding_regs_array, number_of_regs)
  59. *
  60. * verifica se há qualquer pedido válido do mestre modbus. Se houver,
  61. * executa a ação solicitada
  62. *
  63. * slave: endereço do escravo (arduino) (1 to 127)
  64. * regs: uma matriz com os holding registers. Eles começam no endereço 1 (mestre ponto de vista)
  65. * Regs_size: número total de holding registers.
  66. * Retorna: 0 se não houver pedido do mestre,
  67. * NO_REPLY (-1) se nenhuma resposta é enviada para o mestre
  68. * Caso um código de exceção (1 a 4) em algumas exceções de modbus
  69. * O número de bytes enviados como resposta (> 4) se OK.
  70. */
  71.  
  72. // onewire---------------------------- // onewire----------------------------
  73. #include <Wire.h>
  74. #include <OneWire.h>
  75. #include <DallasTemperature.h>
  76. #define ONE_WIRE_BUS 10
  77.  
  78. OneWire oneWire(ONE_WIRE_BUS);
  79. DallasTemperature sensors(&oneWire);
  80. DeviceAddress Sensor_1 = { 0x10, 0x8E, 0x23, 0x35, 0x02, 0x08, 0x00, 0x44 };
  81. float tempC;
  82. // onewire---------------------------- // onewire----------------------------
  83.  
  84. int update_mb_slave(unsigned char slave, int *regs,
  85. unsigned int regs_size);
  86.  
  87. /* Aqui começa o código do exemplo */
  88.  
  89. /* Parâmetros Modbus RTU de comunicação, o Mestre e os escravos devem usar os mesmos parâmetros */
  90. enum {
  91. COMM_BPS = 9600, /* baud rate */
  92. MB_SLAVE = 1, /* endereço do escravo modbus */
  93. PARITY = 'n' /* paridade */
  94. };
  95.  
  96. /* registros do escravo (holding registers)
  97. *
  98. * Aqui ficam ordenados todos os registros de leitura e escrita
  99. * da comunicação entre o mestre e o escravo (SCADA e arduino)
  100. *
  101. */
  102.  
  103. enum {
  104. MB_PINO_10, /* Controle do Led no pino 3 (desliga=0 liga=1) */
  105.  
  106.  
  107.  
  108. MB_REGS /* número total de registros do escravo */
  109. };
  110.  
  111. int regs[MB_REGS];
  112. int ledPin10 = 10;
  113. //ds(ledPin10);
  114.  
  115. unsigned long wdog = 0; /* watchdog */
  116. unsigned long tprev = 0; /* tempo anterior do último comando*/
  117. unsigned long tanalogprev = 0; /* tempo anterior da leitura dos pinos analogicos*/
  118.  
  119. void setup()
  120. {
  121. /* configura cominicação modbus
  122. * 9600 bps, 8N1, RS485 network */
  123. configure_mb_slave(COMM_BPS, PARITY, 2);
  124. // onewire---------------------------- // onewire----------------------------
  125. Wire.begin();
  126. delay (1000);
  127. sensors.begin();
  128. sensors.setResolution(Sensor_1, 10);
  129. // onewire---------------------------- // onewire----------------------------
  130.  
  131. }
  132. void loop()
  133. {
  134. /* verifica se há solicitações do mestre */
  135. update_mb_slave(MB_SLAVE, regs, MB_REGS);
  136.  
  137. // onewire---------------------------- // onewire----------------------------
  138. sensors.requestTemperatures();
  139. tempC = sensors.getTempC(Sensor_1);
  140. Serial.println(tempC);
  141. delay(1000);
  142. // onewire---------------------------- // onewire----------------------------
  143. }
  144.  
  145. /****************************************************************************
  146. * INICIO DAS FUNÇÕES ESCRAVO Modbus RTU
  147. ****************************************************************************/
  148.  
  149. /* variaveis globais */
  150. unsigned int Txenpin = 2; /*Definir o pino usado para colocar o driver
  151. RS485 em modo de transmissão, utilizado
  152. somente em redes RS485 quando colocar em 0
  153. ou 1 para redes RS232 */
  154.  
  155.  
  156. /* Lista de códigos de função modbus suportados. Se você implementar um novo, colocar o seu código de função aqui! */
  157. enum {
  158. FC_READ_REGS = 0x03, //Read contiguous block of holding register (Ler um bloco contíguo de registos)
  159. FC_WRITE_REG = 0x06, //Write single holding register (Escrever em um único registro)
  160. FC_WRITE_REGS = 0x10 //Write block of contiguous registers (Escrever em um bloco contíguo de registos)
  161. };
  162.  
  163. /* Funções suportadas. Se você implementar um novo, colocar seu código em função nessa matriz! */
  164. const unsigned char fsupported[] = { FC_READ_REGS, FC_WRITE_REG, FC_WRITE_REGS };
  165.  
  166. /* constantes */
  167. enum {
  168. MAX_READ_REGS = 0x7D,
  169. MAX_WRITE_REGS = 0x7B,
  170. MAX_MESSAGE_LENGTH = 256
  171. };
  172.  
  173.  
  174. enum {
  175. RESPONSE_SIZE = 6,
  176. EXCEPTION_SIZE = 3,
  177. CHECKSUM_SIZE = 2
  178. };
  179.  
  180. /* código de exceções */
  181. enum {
  182. NO_REPLY = -1,
  183. EXC_FUNC_CODE = 1,
  184. EXC_ADDR_RANGE = 2,
  185. EXC_REGS_QUANT = 3,
  186. EXC_EXECUTE = 4
  187. };
  188.  
  189. /* posições dentro da matriz de consulta / resposta */
  190. enum {
  191. SLAVE = 0,
  192. FUNC,
  193. START_H,
  194. START_L,
  195. REGS_H,
  196. REGS_L,
  197. BYTE_CNT
  198. };
  199.  
  200.  
  201. /*
  202. CRC
  203.  
  204. INPUTS:
  205. buf -> Matriz contendo a mensagem a ser enviada para o controlador mestre.
  206. start -> Início do loop no crc do contador, normalmente 0.
  207. cnt -> Quantidade de bytes na mensagem a ser enviada para o controlador mestre
  208. OUTPUTS:
  209. temp -> Retorna byte crc para a mensagem.
  210. COMMENTÁRIOS:
  211. Esta rotina calcula o byte crc alto e baixo de uma mensagem.
  212. Note que este CRC é usado somente para Modbus, não em Modbus PLUS ou TCP.
  213. ****************************************************************************/
  214.  
  215. unsigned int crc(unsigned char *buf, unsigned char start,
  216. unsigned char cnt)
  217. {
  218. unsigned char i, j;
  219. unsigned temp, temp2, flag;
  220.  
  221. temp = 0xFFFF;
  222.  
  223. for (i = start; i < cnt; i++) {
  224. temp = temp ^ buf[i];
  225.  
  226. for (j = 1; j <= 8; j++) {
  227. flag = temp & 0x0001;
  228. temp = temp >> 1;
  229. if (flag)
  230. temp = temp ^ 0xA001;
  231. }
  232. }
  233.  
  234. /* Inverter a ordem dos bytes. */
  235. temp2 = temp >> 8;
  236. temp = (temp << 8) | temp2;
  237. temp &= 0xFFFF;
  238.  
  239. return (temp);
  240. }
  241.  
  242.  
  243.  
  244.  
  245. /***********************************************************************
  246. *
  247. * As seguintes funções constroem o frame de
  248. * um pacote de consulta modbus.
  249. *
  250. ***********************************************************************/
  251.  
  252. /*
  253. * Início do pacote de uma resposta read_holding_register
  254. */
  255. void build_read_packet(unsigned char slave, unsigned char function,
  256. unsigned char count, unsigned char *packet)
  257. {
  258. packet[SLAVE] = slave;
  259. packet[FUNC] = function;
  260. packet[2] = count * 2;
  261. }
  262.  
  263. /*
  264. * Início do pacote de uma resposta preset_multiple_register
  265. */
  266. void build_write_packet(unsigned char slave, unsigned char function,
  267. unsigned int start_addr,
  268. unsigned char count,
  269. unsigned char *packet)
  270. {
  271. packet[SLAVE] = slave;
  272. packet[FUNC] = function;
  273. packet[START_H] = start_addr >> 8;
  274. packet[START_L] = start_addr & 0x00ff;
  275. packet[REGS_H] = 0x00;
  276. packet[REGS_L] = count;
  277. }
  278.  
  279. /*
  280. * Início do pacote de uma resposta write_single_register
  281. */
  282. void build_write_single_packet(unsigned char slave, unsigned char function,
  283. unsigned int write_addr, unsigned int reg_val, unsigned char* packet)
  284. {
  285. packet[SLAVE] = slave;
  286. packet[FUNC] = function;
  287. packet[START_H] = write_addr >> 8;
  288. packet[START_L] = write_addr & 0x00ff;
  289. packet[REGS_H] = reg_val >> 8;
  290. packet[REGS_L] = reg_val & 0x00ff;
  291. }
  292.  
  293.  
  294. /*
  295. * Início do pacote de uma resposta excepção
  296. */
  297. void build_error_packet(unsigned char slave, unsigned char function,
  298. unsigned char exception, unsigned char *packet)
  299. {
  300. packet[SLAVE] = slave;
  301. packet[FUNC] = function + 0x80;
  302. packet[2] = exception;
  303. }
  304.  
  305.  
  306. /*************************************************************************
  307. *
  308. * modbus_query( packet, length)
  309. *
  310. * Função para adicionar uma soma de verificação para o fim de um pacote.
  311. * Por favor, note que a matriz pacote deve ser de pelo menos 2 campos mais do que
  312. * String_length.
  313. **************************************************************************/
  314.  
  315. void modbus_reply(unsigned char *packet, unsigned char string_length)
  316. {
  317. int temp_crc;
  318.  
  319. temp_crc = crc(packet, 0, string_length);
  320. packet[string_length] = temp_crc >> 8;
  321. string_length++;
  322. packet[string_length] = temp_crc & 0x00FF;
  323. }
  324.  
  325.  
  326.  
  327. /***********************************************************************
  328. *
  329. * send_reply( query_string, query_length )
  330. *
  331. * Função para enviar uma resposta a um mestre Modbus.
  332. * Retorna: o número total de caracteres enviados
  333. ************************************************************************/
  334.  
  335. int send_reply(unsigned char *query, unsigned char string_length)
  336. {
  337. unsigned char i;
  338.  
  339. if (Txenpin > 1) { // coloca o MAX485 no modo de transmissão
  340. UCSR0A=UCSR0A |(1 << TXC0);
  341. digitalWrite( Txenpin, HIGH);
  342. delayMicroseconds(3640); // aguarda silencio de 3.5 caracteres em 9600bps
  343. }
  344.  
  345. modbus_reply(query, string_length);
  346. string_length += 2;
  347.  
  348. for (i = 0; i < string_length; i++) {
  349. Serial.write(byte(query[i]));
  350. // Serial.print(query[i], BYTE);
  351. }
  352.  
  353. if (Txenpin > 1) {// coloca o MAX485 no modo de recepção
  354. while (!(UCSR0A & (1 << TXC0)));
  355. digitalWrite( Txenpin, LOW);
  356. }
  357.  
  358. return i; /* isso não significa que a gravação foi bem sucedida */
  359. }
  360.  
  361. /***********************************************************************
  362. *
  363. * receive_request( array_for_data )
  364. *
  365. * Função para monitorar um pedido do mestre modbus.
  366. *
  367. * Retorna: Número total de caracteres recebidos se OK
  368. * 0 se não houver nenhum pedido
  369. * Um código de erro negativo em caso de falha
  370. ***********************************************************************/
  371.  
  372. int receive_request(unsigned char *received_string)
  373. {
  374. int bytes_received = 0;
  375.  
  376. /* FIXME: não Serial.available esperar 1.5T ou 3.5T antes de sair do loop? */
  377. while (Serial.available()) {
  378. received_string[bytes_received] = Serial.read();
  379. bytes_received++;
  380. if (bytes_received >= MAX_MESSAGE_LENGTH)
  381. return NO_REPLY; /* erro de porta */
  382. }
  383.  
  384. return (bytes_received);
  385. }
  386.  
  387.  
  388. /*********************************************************************
  389. *
  390. * modbus_request(slave_id, request_data_array)
  391. *
  392. * Função que é retornada quando o pedido está correto
  393. * e a soma de verificação está correto.
  394. * Retorna: string_length se OK
  395. * 0 se não
  396. * Menos de 0 para erros de exceção
  397. *
  398. * Nota: Todas as funções usadas para enviar ou receber dados via
  399. * Modbus devolver esses valores de retorno.
  400. *
  401. **********************************************************************/
  402.  
  403. int modbus_request(unsigned char slave, unsigned char *data)
  404. {
  405. int response_length;
  406. unsigned int crc_calc = 0;
  407. unsigned int crc_received = 0;
  408. unsigned char recv_crc_hi;
  409. unsigned char recv_crc_lo;
  410.  
  411. response_length = receive_request(data);
  412.  
  413. if (response_length > 0) {
  414. crc_calc = crc(data, 0, response_length - 2);
  415. recv_crc_hi = (unsigned) data[response_length - 2];
  416. recv_crc_lo = (unsigned) data[response_length - 1];
  417. crc_received = data[response_length - 2];
  418. crc_received = (unsigned) crc_received << 8;
  419. crc_received =
  420. crc_received | (unsigned) data[response_length - 1];
  421.  
  422. /*********** verificar CRC da resposta ************/
  423. if (crc_calc != crc_received) {
  424. return NO_REPLY;
  425. }
  426.  
  427. /* verificar a ID do escravo */
  428. if (slave != data[SLAVE]) {
  429. return NO_REPLY;
  430. }
  431. }
  432. return (response_length);
  433. }
  434.  
  435. /*********************************************************************
  436. *
  437. * validate_request(request_data_array, request_length, available_regs)
  438. *
  439. * Função para verificar se o pedido pode ser processado pelo escravo.
  440. *
  441. * Retorna: 0 se OK
  442. * Um código de exceção negativa em caso de erro
  443. *
  444. **********************************************************************/
  445.  
  446. int validate_request(unsigned char *data, unsigned char length,
  447. unsigned int regs_size)
  448. {
  449. int i, fcnt = 0;
  450. unsigned int regs_num = 0;
  451. unsigned int start_addr = 0;
  452. unsigned char max_regs_num;
  453.  
  454. /* verificar o código de função */
  455. for (i = 0; i < sizeof(fsupported); i++) {
  456. if (fsupported[i] == data[FUNC]) {
  457. fcnt = 1;
  458. break;
  459. }
  460. }
  461. if (0 == fcnt)
  462. return EXC_FUNC_CODE;
  463.  
  464. if (FC_WRITE_REG == data[FUNC]) {
  465. /* Para a função de escrever um reg único, este é o registro alvo.*/
  466. regs_num = ((int) data[START_H] << 8) + (int) data[START_L];
  467. if (regs_num >= regs_size)
  468. return EXC_ADDR_RANGE;
  469. return 0;
  470. }
  471.  
  472. /* Para as funções de leitura / escrita de registros, este é o intervalo. */
  473. regs_num = ((int) data[REGS_H] << 8) + (int) data[REGS_L];
  474.  
  475. /* verifica a quantidade de registros */
  476. if (FC_READ_REGS == data[FUNC])
  477. max_regs_num = MAX_READ_REGS;
  478. else if (FC_WRITE_REGS == data[FUNC])
  479. max_regs_num = MAX_WRITE_REGS;
  480.  
  481. if ((regs_num < 1) || (regs_num > max_regs_num))
  482. return EXC_REGS_QUANT;
  483.  
  484. /* verificará a quantidade de registros, endereço inicial é 0 */
  485. start_addr = ((int) data[START_H] << 8) + (int) data[START_L];
  486. if ((start_addr + regs_num) > regs_size)
  487. return EXC_ADDR_RANGE;
  488.  
  489. return 0; /* OK, sem exceção */
  490. }
  491.  
  492.  
  493.  
  494. /************************************************************************
  495. *
  496. * write_regs(first_register, data_array, registers_array)
  497. *
  498. * escreve nos registradores do escravo os dados em consulta,
  499. * A partir de start_addr.
  500. *
  501. * Retorna: o número de registros escritos
  502. ************************************************************************/
  503.  
  504. int write_regs(unsigned int start_addr, unsigned char *query, int *regs)
  505. {
  506. int temp;
  507. unsigned int i;
  508.  
  509. for (i = 0; i < query[REGS_L]; i++) {
  510. /* mudar reg hi_byte para temp */
  511. temp = (int) query[(BYTE_CNT + 1) + i * 2] << 8;
  512. /* OR com lo_byte */
  513. temp = temp | (int) query[(BYTE_CNT + 2) + i * 2];
  514.  
  515. regs[start_addr + i] = temp;
  516. }
  517. return i;
  518. }
  519.  
  520. /************************************************************************
  521. *
  522. * preset_multiple_registers(slave_id, first_register, number_of_registers,
  523. * data_array, registers_array)
  524. *
  525. * Escreva os dados na matriz dos registos do escravo.
  526. *
  527. *************************************************************************/
  528.  
  529. int preset_multiple_registers(unsigned char slave,
  530. unsigned int start_addr,
  531. unsigned char count,
  532. unsigned char *query,
  533. int *regs)
  534. {
  535. unsigned char function = FC_WRITE_REGS; /* Escrever em múltiplos registros */
  536. int status = 0;
  537. unsigned char packet[RESPONSE_SIZE + CHECKSUM_SIZE];
  538.  
  539. build_write_packet(slave, function, start_addr, count, packet);
  540.  
  541. if (write_regs(start_addr, query, regs)) {
  542. status = send_reply(packet, RESPONSE_SIZE);
  543. }
  544.  
  545. return (status);
  546. }
  547.  
  548.  
  549. /************************************************************************
  550. *
  551. * write_single_register(slave_id, write_addr, data_array, registers_array)
  552. *
  553. * Escrever um único valor inteiro em um único registo do escravo.
  554. *
  555. *************************************************************************/
  556.  
  557. int write_single_register(unsigned char slave,
  558. unsigned int write_addr, unsigned char *query, int *regs)
  559. {
  560. unsigned char function = FC_WRITE_REG; /* Função: Write Single Register */
  561. int status = 0;
  562. unsigned int reg_val;
  563. unsigned char packet[RESPONSE_SIZE + CHECKSUM_SIZE];
  564.  
  565. reg_val = query[REGS_H] << 8 | query[REGS_L];
  566. build_write_single_packet(slave, function, write_addr, reg_val, packet);
  567. regs[write_addr] = (int) reg_val;
  568. /*
  569. written.start_addr=write_addr;
  570. written.num_regs=1;
  571. */
  572. status = send_reply(packet, RESPONSE_SIZE);
  573.  
  574. return (status);
  575. }
  576.  
  577.  
  578. /************************************************************************
  579. *
  580. * read_holding_registers(slave_id, first_register, number_of_registers,
  581. * registers_array)
  582. *
  583. * lê os registros do escravo e envia para o mestre Modbus
  584. *
  585. *************************************************************************/
  586.  
  587. int read_holding_registers(unsigned char slave, unsigned int start_addr,
  588.  
  589. unsigned char reg_count, int *regs)
  590. {
  591. unsigned char function = 0x03; /* Função 03: Read Holding Registers */
  592. int packet_size = 3;
  593. int status;
  594. unsigned int i;
  595. unsigned char packet[MAX_MESSAGE_LENGTH];
  596.  
  597. build_read_packet(slave, function, reg_count, packet);
  598.  
  599. for (i = start_addr; i < (start_addr + (unsigned int) reg_count);
  600. i++) {
  601. packet[packet_size] = regs[i] >> 8;
  602. packet_size++;
  603. packet[packet_size] = regs[i] & 0x00FF;
  604. packet_size++;
  605. }
  606.  
  607. status = send_reply(packet, packet_size);
  608.  
  609. return (status);
  610. }
  611.  
  612.  
  613. void configure_mb_slave(long baud, char parity, char txenpin)
  614. {
  615. Serial.begin(baud);
  616.  
  617. switch (parity) {
  618. case 'e': // 8E1
  619. UCSR0C |= ((1<<UPM01) | (1<<UCSZ01) | (1<<UCSZ00));
  620. // UCSR0C &= ~((1<<UPM00) | (1<<UCSZ02) | (1<<USBS0));
  621. break;
  622. case 'o': // 8O1
  623. UCSR0C |= ((1<<UPM01) | (1<<UPM00) | (1<<UCSZ01) | (1<<UCSZ00));
  624. // UCSR0C &= ~((1<<UCSZ02) | (1<<USBS0));
  625. break;
  626. case 'n': // 8N1
  627. UCSR0C |= ((1<<UCSZ01) | (1<<UCSZ00));
  628. // UCSR0C &= ~((1<<UPM01) | (1<<UPM00) | (1<<UCSZ02) | (1<<USBS0));
  629. break;
  630. default:
  631. break;
  632. }
  633.  
  634. if (txenpin > 1) { // pino 0 & pino 1 são reservados para RX/TX
  635. Txenpin = txenpin; /* definir variável global */
  636. pinMode(Txenpin, OUTPUT);
  637. digitalWrite(Txenpin, LOW);
  638. }
  639.  
  640. return;
  641. }
  642.  
  643. /*
  644. * update_mb_slave(slave_id, holding_regs_array, number_of_regs)
  645. *
  646. * verifica se há qualquer pedido válido do mestre modbus. Se houver,
  647. * executa a ação solicitada
  648. */
  649.  
  650. unsigned long Nowdt = 0;
  651. unsigned int lastBytesReceived;
  652. const unsigned long T35 = 5;
  653.  
  654. int update_mb_slave(unsigned char slave, int *regs,
  655. unsigned int regs_size)
  656. {
  657. unsigned char query[MAX_MESSAGE_LENGTH];
  658. unsigned char errpacket[EXCEPTION_SIZE + CHECKSUM_SIZE];
  659. unsigned int start_addr;
  660. int exception;
  661. int length = Serial.available();
  662. unsigned long now = millis();
  663.  
  664. if (length == 0) {
  665. lastBytesReceived = 0;
  666. return 0;
  667. }
  668.  
  669. if (lastBytesReceived != length) {
  670. lastBytesReceived = length;
  671. Nowdt = now + T35;
  672. return 0;
  673. }
  674. if (now < Nowdt)
  675. return 0;
  676.  
  677. lastBytesReceived = 0;
  678.  
  679. length = modbus_request(slave, query);
  680. if (length < 1)
  681. return length;
  682.  
  683.  
  684. exception = validate_request(query, length, regs_size);
  685. if (exception) {
  686. build_error_packet(slave, query[FUNC], exception,
  687. errpacket);
  688. send_reply(errpacket, EXCEPTION_SIZE);
  689. return (exception);
  690. }
  691.  
  692.  
  693. start_addr = ((int) query[START_H] << 8) +
  694. (int) query[START_L];
  695. switch (query[FUNC]) {
  696. case FC_READ_REGS:
  697. return read_holding_registers(slave,
  698. start_addr,
  699. query[REGS_L],
  700. regs);
  701. break;
  702. case FC_WRITE_REGS:
  703. return preset_multiple_registers(slave,
  704. start_addr,
  705. query[REGS_L],
  706. query,
  707. regs);
  708. break;
  709. case FC_WRITE_REG:
  710. write_single_register(slave,
  711. start_addr,
  712. query,
  713. regs);
  714. break;
  715. }
  716. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!