AKA FIX for Mr_Me v1.0

ON *:START: {
  hmake trackusers 1000

  if ($file(trackusers.dat)) { hload trackusers trackusers.dat }
}

ON *:EXIT: {
  if ($hget(trackusers)) { hsave trackusers trackusers.dat }
}

ON !*:OPEN:?: {
  echo $color(topic) -t $nick * Now talking to: $address at $date $+ .

  var %n = $hget(trackusers,$address($nick,2))

  if (%n) {
    if ($istok(%n,$nick,32)) { var %d = $deltok(%n,$findtok(%n,$nick,1,32),32) }
    else { var %d = %n }

    echo $color(topic) -t $nick # * Also known with nick $+ $iif($numtok(%d,32) > 1,s:,:) %d

    return
  }

  if (-sBNC !== $nick) { echo $color(topic) -t $nick # * $nick doesn't have any other nicknames! }
}

ON !*:JOIN:#: {
  var %n = $hget(trackusers,$address($nick,2))

  if (%n) {
    if ($istok(%n,$nick,32)) { var %d = $deltok(%n,$findtok(%n,$nick,1,32),32) }
    else { var %d = %n }

    echo $colour(join) -ti2 $chan * $nick 7has also known with nick $+ $iif($numtok(%d,32) > 1,s:,:) %d

    if (!$istok(%n,$nick,32)) {
      if ($numtok(%n,32) >= 15) { var %n = $gettok(%n,-14--1,32) }

      hadd trackusers $address($nick,2) %n $nick
    }

    return
  }

  hadd trackusers $address($nick,2) $nick
}

ON *:NICK: {
  var %n = $hget(trackusers,$address($newnick,2))

  if (%n) {
    if (!$istok(%n,$newnick,32)) {
      if ($numtok(%n,32) >= 15) { var %n = $gettok(%n,-14--1,32) }

      hadd trackusers $address($newnick,2) %n $newnick
    }

    return
  }

  hadd trackusers $address($nick,2) $newnick
}

menu Nicklist {
  Track Users
  .View Other Nicknames: {
    if (!$address($$1,2)) { echo $colour(info) -ti2 # * IAL not updated for $$1 $+ , performing userhost lookup.. | userhost $$1 | return }

    var %n = $hget(trackusers,$address($$1,2))

    if (%n) {
      if ($istok(%n,$$1,32)) { var %d = $deltok(%n,$findtok(%n,$$1,1,32),32) }
      else { var %d = %n }

      echo $colour(join) -ti2 # * $$1 8has also known with nick $+ $iif($numtok(%d,32) > 1,s:,:) %d

      return
    }

    echo $colour(join) -ti2 # * $$1 has not been known by any other nickname
  }
  .-
  .Reset
  ..OK:hdel trackusers $address($$1,2)
}