; $1 = XVal ; $2 = YVal
alias Mandel_Pixel {
  var %J 1 , %M = 0 , %R = $1 , %I = $2
  while (%J < 128) {

    inc %J
    %M = $calc((%R *%R)-(%I *%I))
    %I = $calc((2*(%R *%I)) + $2)
    %R = %M + $1
    ;if $abs(%M) > 3 return %J

    inc %J
    %M = $calc((%R *%R)-(%I *%I))
    %I = $calc((2*(%R *%I)) + $2)
    %R = %M + $1
    ;if $abs(%M) > 3 return %J

    inc %J
    %M = $calc((%R *%R)-(%I *%I))
    %I = $calc((2*(%R *%I)) + $2)
    %R = %M + $1
    if $abs(%M) > 3 return %J

  }
  return %J
}

alias Mandel_Row {
  if (!$window(@Mandel)) {
    .timerMandel off
    unset %m_Y
    unset %m_Start
    halt
  }
  var %X = 0
  while ( %X < 256 ) {
    var %I = $Mandel_Pixel( $calc( %X / 25600 - 1.378 ) , $calc( %m_Y / 19200 - .09 ) )
    if ( %I > 85 ) { %I = 85 }
    drawdot -nr @Mandel $rgb( %I , $calc(%I *2) , $calc(%I *3) ) 1 %X %m_Y
    inc %X
  }
  drawdot @Mandel
  dec %m_Y
  if (!%m_Y) {
    echo > $calc( ($ticks - %m_Start) / 500 ) $+ s
    unset %m_Y
    unset %m_Start
  }
}

alias Mandel_Calc {
  window -daCp @Mandel 0 0 256 224
  set %m_Start $ticks
  set %m_Y 191
  .timerMandel -m %m_Y 1 Mandel_Row
}