Inno Script: Client

#define AppName "World of Tanks Blitz"
#define MyAppName "World of Tanks Blitz Client"
#define AppVer "6.9"
#define OutName "NSC69"

[Setup]
AppName={#MyAppName}
AppVerName={#MyAppName} {#AppVer} by @vladi1603
AppVersion={#AppVer}
AppId=WoTBlitz\vladi1603
DefaultDirName={pf}\{#AppName}
DefaultGroupName={#AppName}
Compression=none
DiskSpanning=yes
DiskSliceSize=1500000000
OutputDir=C:\Users\vladi\Desktop
OutputBaseFilename={#OutName}
InfoBeforeFile=readme.rtf
SetupIconFile=game.ico
WizardSmallImageFile=install.bmp
DisableProgramGroupPage=yes
DisableFinishedPage=True
DisableReadyPage=True

[Languages]
;Язык по умолчанию интерфейса установщика
Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl"

[Icons]
;Создание ярлыка на рабочем столе после успешной установки приложения
Name: "{commondesktop}\World of Tanks Blitz"; Filename: "{app}\wotblitz.exe"

[UninstallDelete]
;Файлы\папки которые должны удалится при Удалении приложения
Type: filesandordirs; Name: "{userdocs}\DAVAProject"

[Registry]
;В реестр вносится строковый параметр с именем Version и значением 1.0 и так далее
Root: HKCU; Subkey: "Software\WoTBlitz"; ValueType: string; ValueName: "Version"; ValueData: "{#AppVer}"; Flags: createvalueifdoesntexist uninsdeletekey

[Files]
;Файлы приложения, установочный файл и вся его директория
Source: "C:\WoTBlitz\client\wotblitz.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\WoTBlitz\client\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs

;Файлы, Оформление окон
Source: "VclStylesinno.dll"; DestDir: {app}; Flags: dontcopy
Source: "SmokeyQuartzKamri.vsf"; DestDir: {app}; Flags: dontcopy

;Файлы, Splash
Source: "isgsg.dll"; DestDir: "{tmp}"; Flags: ignoreversion dontcopy nocompression
Source: "Splash.png"; DestDir: "{tmp}"; Flags: ignoreversion dontcopy nocompression

[Code]
//Процедура, Оформление окон
procedure LoadVCLStyle(VClStyleFile: String); external 'LoadVCLStyleW@files:VclStylesInno.dll stdcall';
procedure UnLoadVCLStyles; external 'UnLoadVCLStyles@files:VclStylesInno.dll stdcall';

//Процедура, Splash
procedure ShowSplashScreen(p1:HWND;p2:AnsiString;p3,p4,p5,p6,p7:integer;p8:boolean;p9:Cardinal;p10:integer);
external 'ShowSplashScreen@files:isgsg.dll stdcall delayload';

//Функция, Оформление окон
function InitializeSetup(): Boolean;
begin
  ExtractTemporaryFile('SmokeyQuartzKamri.vsf');
  LoadVCLStyle(ExpandConstant('{tmp}\SmokeyQuartzKamri.vsf'));
  Result := True;
end;
procedure DeinitializeSetup();
begin
  UnLoadVCLStyles;
end;

//Функция, Splash
procedure InitializeWizard();
begin
  ExtractTemporaryFile('Splash.png');
  ShowSplashScreen(WizardForm.Handle,ExpandConstant('{tmp}\Splash.png'),1000,3000,1000,0,255,True,$FFFFFF,10);
end;