PONK 512

*= $0801
.word (+), 2013   ;pointer, line number
.null $9e, ^start ;will be sys 2081
+   .word 0       ;basic line end


sprites=$38
sprdata=(sprites*$40)

vars=$f9
vx=$fa
vy=$fb
score1=$fc
time=$fd
score2=$fe

start
        jsr reball
        LDA #$00
        STA $D020
        STA $D021
        STA vx
        STA vy
        STA score1
        STA score2

        LDA #$20
        STA $D000
        STA $D002
        LDA #$82
        STA $D001
        STA $D003




        LDA #$32
        STA $D007

        LDX #sprites
        STx $07FB
        inx
        STx $07F8
        STx $07F9
        INX
        STx $07FA


        LDA #$0F
        STA $D017
        STA $D015
        STA $D01D
        STA $D418


        LDA #$01
        ldx #05
-       STA $D026,x
        dex
        bne -






        lda #147
        jsr $FFD2


        lsr $D011
        LDX #$C0
-       LDY #$00
-       JSR bleep
        INY
        BNE -
        INC $D020
        INX
        BNE --
        asl $D011


        LDA #$00
        LDX #$c0
-       STA sprdata,X
        dex
        BNE -
        LDA #$18
        STA sprdata+$A
        ;STA sprdata+$d
        sta sprdata+$81
        sta sprdata+$84
        lda #$bd
        ldx #$00
-       sta sprdata+$41,x
        inx
        inx
        inx
        cpx #$3f
        bcc -
        lda #$ff
        sta sprdata+$41
        sta sprdata+$7d
        lda #$81
        sta sprdata+$44
        sta sprdata+$7a
        sei

main    inc time
        LDX #$02  ; JOY
        LDY #$01
-       LDA $DC00,y
        AND #$02
        BNE +
        INC $D001,x
+       LDA $DC00,y
        AND #$01
        BNE +
        DEC $D001,x
+       LDA $D001,X
        CMP #$32
        BCS +
        LDA #$32
        STA $D001,X
+       LDA $D001,X
        CMP #$CF
        BCC +
        LDA #$CF
        STA $D001,X
+       DEX
        DEX
        DEY
        BEQ -
        LDA $DC00
        EOR $DC01
        AND #$10
        bne +
        asl time
        asl time
+       lda time
        and #$3
        bne slow
+       LDA vx
        BEQ +
        INC $D004
        JMP ++
+       DEC $D004
+       LDA vy
        BEQ +
        INC $D005
        JMP ++
+       DEC $D005
+       LDA $D004
        LDX vx
        BEQ +
        EOR #$FF
+       AND #$FF
        BNE +
        lda $d004
        eor #$ff
        sta $d004
        LDA $D010
        EOR #$04
        STA $D010
+       LDY #$20
        LDA $D005
        CMP #$32
        BCS +
        LDA #$01
        STA vy
        JSR bleep
+       LDA $D005
        CMP #$F8
        BCC slow
        lsr vy
        JSR bleep
slow    lda $d012
        and #$cf
        bne slow

        LDA $D010 ; GOAL
        AND #$04
        BNE ++
        LDA $D004
        CMP #$08
        BCS +
        INC score2
        JSR reball
+       jmp ++
+       LDA $D004
        CMP #$38
        BCC +
        INC score1
        JSR reball

+       ldy #02
        JSR score
        ldy #00
        JSR score

        ldx #02
-       LDA score1,x
        CMP #$0A
        BCC +
        JMP start
+       dex
        dex
        beq -

+       LDY #$40
        LDA $D01E
        TAX
        AND #$01
        BEQ +
        LDA #$01
        STA vx
        JSR bleep
+       TXA
        AND #$02
        BEQ +
        lsr vx
        JSR bleep
+       jmp main

bleep   STY $D401
        LDA #$F4
        STA $D406
        LDA #$11
        STA $D404
        LDA #$10
        STA $D404
        RTS

score   ;sei
        lda #$33
        sta $01
        LDA score1,y
        AND #$0F
        ASL
        ASL
        ASL
        TAX
        LDA #$08
        STA $ff
-       LDA $d180,X
        STA sprdata,Y
        INX
        INY
        INY
        INY
        DEC $ff
        BNE -
        lda #$37
        sta $01
        rts

reball  LDA #$A0
        STA $D004
        STA $D006
        LDA #$8A
        STA $D005
        LDA #$02
        STA $D010
        LDA vx
        EOR #$01
        STA vx
        LDY #$10
        JSR bleep
        RTS