stock TaxiPlayerTimer(playerid) {
    if(PlayerTaxiNotOrder[playerid] != -1) {
        new driverid = PlayerTaxiNotOrder[playerid];

        if(PlayerTaxiDriver[driverid][tdriver_notorder_playerid] == playerid
            && PlayerTaxiDriver[driverid][tdriver_duty]
            && PlayerTaxiDriver[driverid][tdriver_tariff] > 0
            && PlayerTaxiDriver[driverid][tdriver_order] == -1) {
            new carid = GetPlayerVehicleID(playerid);
            if(carid == PlayerTaxiDriver[driverid][tdriver_vehicleid]) {

                TaxiDistance[playerid] += GetPlayerVehicleSpeed(driverid);

                if(TaxiDistance[playerid] >= 1000) {
                    TaxiAllDistance[playerid] += TaxiDistance[playerid];
                    TaxiDistance[playerid] = 0;

                    TaxiPrice[playerid] += PlayerTaxiDriver[driverid][tdriver_tariff];

                    if(GetMoney(playerid) < TaxiPrice[playerid] && PI[playerid][pLevel] >= 5) {
                        format(mainString, 144, "[Предупреждение] У вашего клиента %s уже не хватает средств для оплаты проезда.", Name(playerid));
                        SendClientMessage(driverid, COLOR_LIGHTRED, mainString);

                        SendClientMessage(playerid, COLOR_LIGHTRED, "[Предупреждение] Сумма на таксометре превышает сумму ваших наличных, вам не хватит на полную оплату за проезд.");
                    }
                }

                PlayerTaxiDriver[driverid][tdriver_notorder_time]++;

                UpdateTaxiTimerCountTD(driverid, -1);
                UpdateTaxiTimerCountTD(playerid, -1);
            }
        }
    }
}