*= $2d00
;```````````````````````````````````````
         jmp start
         .text "+erol+"
reset    jsr $fd15
         jsr $fda3
         jsr $ff5b
         jsr $e453
         jmp $e3bf
iset     stx $0314
         sty $0315
         sta $d012
         inc $d019
         rts
irex     jsr iset
         jmp $ea81
;```````````````````````````````````````
start    jsr reset
         lda #$0f
         jsr $e536
         dex
         stx $d011
         stx $d020
         stx $2bdf
         stx cnt2+1
         stx f0+1
         stx f2+1
         stx pf+1
s0       lda $2140,x
         sta $32c0,x
         lda $2240,x
         sta $33c0,x
         lda $2340,x
         sta $34c0,x
         lda $2440,x
         sta $35c0,x
         lda $2540,x
         sta $36c0,x
         lda $2640,x
         sta $37c0,x
         lda $2740,x
         sta $38c0,x
         lda $2838,x
         sta $39b8,x
         lda #$00
         sta $0b00,x
         sta $0c00,x
         sta $0c80,x
         lda $2a00,x
         sta $0428,x
         sta $0658,x
         lda $2af0,x
         sta $d828,x
         sta $da58,x
         inx
         bne s0
s4       txa
         clc
         adc #$60
         sta $05e0,x
         clc
         adc #40
         sta $0590,x
         lda #$00
         sta $0518,x
         sta $0748,x
         sta $02a7,x
         inx
         cpx #$28
         bne s4
         ldx #$3f
s3       lda #$ff
         sta $02c0,x
         lda #$55
         sta $32c0,x
         sta $3300,x
         dex
         bpl s3
         jsr plfrs
         jsr screset
         lda #$00
         ldx #$00
         ldy #$00
         jsr $1000
         sei
         lda #$00
         ldx #<irq
         ldy #>irq
         jsr iset
         dec $dc0e
         inc $d01a
         ldx #<linker
         ldy #>linker
         stx $0318
         sty $0319
         cli
w        lda $02
         beq w
         lda #$00
         sta $02
         lda $dc01
         cmp #$ef
         bne qq
         jmp linker
qq
on       jsr pfls
         lda on
         cmp #$20
         beq w
         inc f0+1
f0       lda #$00
         cmp #$06
         bne w
f2       ldx #$00
         lda col,x
         ldy #$27
f1       sta $d990,y
         dey
         bpl f1
         iny
         sty f0+1
         inc f2+1
         lda f2+1
         cmp #$20
         bne w
         ldx #$00
         stx f2+1
         txa
q15      sta $0c40,x
         sta $0ce0,x
         inx
         cpx #$a0
         bne q15
         lda #$20
         sta on
q14      jmp w
irq      jsr $1003
         jsr mlx
         jsr mly
         jsr scroll
         inc $02
         inc $d019
         jmp $ea81
;```````````````````````````````````````
;prop.font centre line show routine
ptext    = $2be0;          text (@-end)
;0pg $26-$29 mem $07e8-$07f7 font $0800
;```````````````````````````````````````
pfls
pf       lda #$00
         bne pfl0
         ldy #$00
         sty $26
         sty $27
         sty $29
pfl9     jsr pflr2
         beq pfl11
         tax
         lda pfdat,x
         clc
         adc $26
         bcc pfl10
         inc $27
pfl10    sta $26
         iny
         bne pfl9
pfl11    lda #$40
         sec
         sbc $26
         sta $26
         lda #$01
         sbc $27
         sta $27
         lsr $27
         ror $26
         lda $26
         and #$07
         sta $29
         lda $26
         sec
         sbc $29
         clc
         adc #$40
         sta $26
         lda $27
         adc #$0c
         sta $27
         lda #$01
         sta pf+1
pfl0     jsr pflr
         cmp #$ff
         beq pflrs
         cmp #$00
         bne pfl1
pf5      lda #$00
         sta pf+1
         lda #$2c
         sta on
pf4      jmp pf3
pflrs    jsr plfrs
         bne pf5
plfrs    ldx #$df
         ldy #$2b
         stx $14
         sty $15
         rts
pfl1     tax
         ldy pfdat,x
         sty $28
         tay
         asl a
         asl a
         asl a
         sta pfl2+1
         tya
         lsr a
         lsr a
         lsr a
         lsr a
         lsr a
         clc
         adc #$08
         sta pfl2+2
         ldx #$07
pfl2     lda $0800,x
         sta $02b0,x
         dex
         bpl pfl2
         lda $29
         beq pfl4
         tax
pfl3     clc
         ror $02b0
         ror $02b8
         ror $02b1
         ror $02b9
         ror $02b2
         ror $02ba
         ror $02b3
         ror $02bb
         ror $02b4
         ror $02bc
         ror $02b5
         ror $02bd
         ror $02b6
         ror $02be
         ror $02b7
         ror $02bf
         dex
         bne pfl3
pfl4     ldy #$0f
pfl5     lda $02b0,y
         ora ($26),y
         sta ($26),y
         dey
         bpl pfl5
         lda $29
         clc
         adc $28
         sta $29
         cmp #$08
         bcc pfl6
         and #$07
         sta $29
         lda $26
         clc
         adc #$08
         bcc pfl7
         inc $27
pfl7     sta $26
pfl6     ldx #$0f
         lda #$00
pfl8     sta $02b0,x
         dex
         bpl pfl8
pf3      inc $14
         bne pfl12
         inc $15
pfl12    rts
pflr     ldy #$00
pflr2    lda ($14),y
         rts
scroll   ldx #$00
sc00     clc
         rol $0c38,x
         rol $0c30,x
         rol $0c28,x
         rol $0c20,x
         rol $0c18,x
         rol $0c10,x
         rol $0c08,x
         rol $0c00,x
         rol $0bf8,x
         rol $0bf0,x
         rol $0be8,x
         rol $0be0,x
         rol $0bd8,x
         rol $0bd0,x
         rol $0bc8,x
         rol $0bc0,x
         rol $0bb8,x
         rol $0bb0,x
         rol $0ba8,x
         rol $0ba0,x
         rol $0b98,x
         rol $0b90,x
         rol $0b88,x
         rol $0b80,x
         rol $0b78,x
         rol $0b70,x
         rol $0b68,x
         rol $0b60,x
         rol $0b58,x
         rol $0b50,x
         rol $0b48,x
         rol $0b40,x
         rol $0b38,x
         rol $0b30,x
         rol $0b28,x
         rol $0b20,x
         rol $0b18,x
         rol $0b10,x
         rol $0b08,x
         rol $0b00,x
         inx
         cpx #$06
         beq sc0
         jmp sc00
sc0      inc cnt2+1
cnt2     lda #$00
sc4      cmp #$08
         beq sc5
         rts
sc5      lda #$00
         sta cnt2+1
sc3      lda $0b00
         bne sc2
screset  ldx #$80
         ldy #$0d
         stx sc3+1
         sty sc3+2
         rts
sc2      tax
         lda pfdat,x
         sta sc4+1
         txa
         asl a
         asl a
         asl a
         sta sc1+1
         txa
         lsr a
         lsr a
         lsr a
         lsr a
         lsr a
         clc
         adc #$08
         sta sc1+2
         ldy #$05
sc1      lda $0800,y
         sta $0c38,y
         dey
         bpl sc1
         inc sc3+1
         bne scx
         inc sc3+2
scx      rts
;```````````````````````````````````````
;$7f bytes linker by erol/tempest 1996 ;
;```````````````````````````````````````
linker   sei
         jsr reset
         inc $d018
         lda #$0f
         jsr $e536
         dex
         stx $d020
         stx $d021
         lda #<ltext
         ldy #>ltext
         jsr $ab1e
         ldx #$27
lnk2     lda lnk,x
         sta $02d8,x
         dex
         bpl lnk2
         jmp $02d8
lnk      sei
         inc $01
lnk0     ldy #$00
lnk1     lda $3b00,y
         sta $0801,y
         iny
         bne lnk1
         inc $02e2
         inc $02df
         bne lnk0
         dec $01
         sty $0800
         cli
         jsr $a659
stjmp    jmp $a7ae
ltext    .text "Logo & idea:Cupid"
         .byte 13
         .text "Code & font:Erol"
         .byte 13
         .text "Music      :Kristian "
         .text "Rostoen"
         .byte 0
;```````````````````````````````````````
         *= $1dad
mlx      lda #$40-$08
mlx1     cmp $d012
         bne mlx1
         lda $d012
         and #$07
         ora #$78
         sta $d011
         ldy #$19
mlx2     dey
         bne mlx2
         bit $24
         nop
         jsr mlxr1
         lda #$18
         sta $d018
         sta $d016
         lda #$44-$08
mlx3     cmp $d012
         bne mlx3
mlx4     lda #$17
         sta $d016
         lda #$1f
         sta $d015
         ldy #$44-$08
         jsr yco
mlx5     lda #$11
         sta $d000
         clc
         adc #$18
         sta $d002
         clc
         adc #$18
         sta $d004
         clc
         adc #$18
         sta $d006
         clc
         adc #$18
         sta $d008
mlx6     lda #$00
         sta $d010
         lda #$0b
         sta $07f8
         sta $07f9
         sta $07fa
         sta $07fb
         sta $07fc
         lda #$00
         sta $d027
         sta $d028
         sta $d029
         sta $d02a
         sta $d02b
         lda #$4a-$08
mlx0     cmp $d012
         bne mlx0
         lda #$06
         ldx #$3b
         ldy #$06
mlx00    dey
         bpl mlx00
         sta $d021
         stx $d011
         lda #$58-$08
mlxx     cmp $d012
         bne mlxx
         ldy #$59-$08
         jsr yco
         lda #$6d-$08
mlx7     cmp $d012
         bne mlx7
         ldy #$6e-$08
         jsr yco
         lda #$7a-$08
mlxz     cmp $d012
         bne mlxz
         ldy #$09
mlz      dey
         bne mlz
         lda #$7b
         sta $d011
         sty $d021
         lda #$88-$08
mlx9     cmp $d012
         bne mlx9
         lda $d012
         and #$07
         ora #$78
         sta $d011
         ldy #$16
mlx10    dey
         bne mlx10
         jsr mlxr2
         sty $d016
         lda #$12
         sta $d018
         ldy #$54
mlx11    dey
         bne mlx11
         lda #$1b
         sta $d011
mlxr     lda $2980
         tax
         lsr a
         lsr a
         lsr a
         sta mlr1+1
         tay
         txa
         and #$07
         eor #$17
         sta mlx4+1
         lda mlyd1,y
         sta mlx5+1
         lda mlyd2,y
         sta mlx6+1
         inc mlxr+1
         bne c1
         lda #$80
         sta mlxr+1
c1       rts
yco      sty $d001
         sty $d003
         sty $d005
         sty $d007
         sty $d009
         rts
mly      lda #$40+$70
mly1     cmp $d012
         bne mly1
         lda $d012
         and #$07
         ora #$18
         sta $d011
         ldy #$18
mly2     dey
         bne mly2
         bit $2c2c
         bit $2c2c
         nop
         jsr mlyr1
         lda #$18
         sta $d018
         sta $d016
         lda #$44+$70
mly3     cmp $d012
         bne mly3
mly4     lda #$17
         sta $d016
         ldy #$44+$70
         jsr yco
mly5     lda #$11
         sta $d000
         clc
         adc #$18
         sta $d002
         clc
         adc #$18
         sta $d004
         clc
         adc #$18
         sta $d006
         clc
         adc #$18
         sta $d008
mly6     lda #$00
         sta $d010
         lda #$4a+$70
mly0     cmp $d012
         bne mly0
         lda #$06
on2      ldx #$3b
         ldy #$08
mly00    dey
         bpl mly00
         stx $d011
         sta $d021
         lda #$58+$70
mlyt     cmp $d012
         bne mlyt
         ldy #$59+$70
         jsr yco
         lda #$6d+$70
mly7     cmp $d012
         bne mly7
         ldy #$6e+$70
         jsr yco
         lda #$7a+$70
mlys     cmp $d012
         bne mlys
         ldy #$08
mlyp     dey
         bne mlyp
         lda #$7b
         sta $d011
         bit $2c2c
         lda #$88+$70
mly9     cmp $d012
         bne mly9
         lda $d012
         and #$07
         ora #$78
         ldy #$07
mlyy     dey
         bne mlyy
         sta $d011
         ldy #$16
mly10    dey
         bne mly10
         jsr mlyr2
         sty $d016
         lda #$15
         sta $d018
         ldy #$54
mly11    dey
         bne mly11
         lda #$1b
         sta $d011
         sty $d021
mlyr     lda $29c0
         tax
         lsr a
         lsr a
         lsr a
         sta mlp1+1
         tay
         txa
         and #$07
         eor #$17
         sta mly4+1
         lda mlyd1,y
         sta mly5+1
         lda mlyd2,y
         sta mly6+1
         inc mlyr+1
         bne c2
         lda #$80
         sta mlyr+1
c2       rts
mlyr1    ldx #$7b  ; round address no
         clc
mlp1     bcc mlp2
mlp2     lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         bit $ea
         stx $d011
         rts
mlyr2    lda #$20
         sec
         sbc mlp1+1
         sta mlp3+1
         ldx #$7b
         clc
mlp3     bcc mlp4
mlp4     lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         bit $ea
         stx $d011
         rts
mlxr1    ldx #$7b  ; round address no
         clc
mlr1     bcc mlr2
mlr2     lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         bit $ea
         stx $d011
         rts
mlxr2    lda #$20
         sec
         sbc mlr1+1
         sta mlr3+1
         ldx #$7b
         clc
mlr3     bcc mlr4
mlr4     lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         lda #$a9
         bit $ea
         stx $d011
         rts
mlyd1    .byte $11,$09,$01,$f9,$f1,$e9
         .byte $e1,$d9,$d1,$c9,$c1,$b9
         .byte $b1,$a9,$a1,$58,$50,$48
         .byte $40,$38,$30,$28,$20,$18
         .byte $10,$08,$00,$f8,$f0,$e8
         .byte $e0,$d8
mlyd2    .byte $00,$00,$00,$01,$01,$01
         .byte $03,$03,$03,$07,$07,$07
         .byte $0f,$0f,$0f,$1f,$1f,$1f
         .byte $1f,$1f,$1f,$1f,$1f,$1f
         .byte $1f,$1f,$1f,$1e,$1e,$1e
         .byte $1c,$1c
pfdat    .byte $00,$08,$07,$08,$08,$08
         .byte $06,$07,$07,$05,$07,$07
         .byte $06,$08,$07,$07,$07,$07
         .byte $05,$08,$07,$08,$07,$08
         .byte $07,$07,$08,$05,$07,$05
         .byte $07,$08,$04,$04,$06,$08
         .byte $07,$08,$08,$04,$05,$05
         .byte $08,$07,$04,$07,$03,$08
         .byte $07,$05,$08,$08,$08,$08
         .byte $07,$07,$07,$08,$03,$04
         .byte $05,$07,$05,$07,$07,$07
         .byte $07,$08,$07,$08,$06,$08
         .byte $07,$05,$07,$07,$08,$08
         .byte $07,$07,$07,$08,$07,$08
         .byte $07,$07,$07,$08,$07,$07
         .byte $08,$09,$08,$09,$07,$08
col      .byte 0,0,9,2,8,10
         .byte 15,15,15,15,15,15,15,15
         .byte 15,15,15,15,15,15,15,15
         .byte 15,15,15,15
         .byte 10,8,2,9,0,0
;```````````````````````````````````````