/IPL - IP Lookup addon for JuanAM (v2.0)

alias ipl {
  if (!$1) { echo -a 10 You must enter the IP address to find, in this format 12 $+ /ip 111.111.111.111 | return }
  if ($remove($1,.) !isnum) { echo -a Error: Your IP address is not correct, try again! | return }
  var %s = InfoIP_ $+ $ticks $+ _ $+ $rand(1,10000000)
  if ($sock(%s)) { sockclose %s }
  echo -a ***** Searching informations for IP:  $+ $1 $+  *****
  sockopen %s geoip.flagfox.net 80
  sockmark %s $1
}

ON *:SOCKOPEN:InfoIP_*: {
  if ($sockerr) { echo -a ERROR: Connection problem, Could not connect to the page! | sockclose $sockname | return }
  sockwrite -nt $sockname GET /?ip= $+ $sock($sockname).mark HTTP/1.1
  sockwrite -nt $sockname User-Agent: Mozilla/5.0 (Windows NT 6.3; WOW64; rv:33.0) Gecko/20100101 Firefox/33.0
  sockwrite -nt $sockname Accept-Language: *
  sockwrite -nt $sockname Host: $sock($sockname).addr
  sockwrite -nt $sockname Connection: close
  sockwrite -nt $sockname $crlf
}

ON *:SOCKREAD:InfoIP_*: {
  if ($sockerr) { echo -a ERROR: Connection reading problem, Could not read from the page! | sockclose $sockname | return }
  var %r
  sockread %r
  var %r = $remove(%r,$chr(9),$chr(10),$chr(13))
  ; echo -a READ: %r
  if ($sockbr == 0) { return }
  if (*<a href="http://en.wikipedia.org/wiki/* iswm %r) && ($left(%r,2) == <a) && (*target="_blank" title="Wikipedia entry for* iswm %r) { echo -a 12Continent:1 $httpstrip(%r) $+  }
  if (*<span style="white-space: nowrap"><a href="http://en.wikipedia.org/wiki/* iswm %r) && (*target="_blank" title="* iswm %r) { echo -a 12Country:1 $httpstrip(%r) $+  }
  if (*var myLatLng* iswm %r) {
    echo -a 12Latitude & Longitude:1 $remove($gettok(%r,2,40),$chr(41),;) $+ 
  }
  if ($left(%r,8) == content:) && (*<br>* iswm %r) {
    echo -a 12Hostname:1 $gettok($gettok(%r,2,39),1,60) $+ 
    var %city = $remove($gettok($gettok(%r,2,39),3,60),br>)
    if ($chr(44) isin %city) { var %city = $gettok(%city,1,44) }
    echo -a 12City:1 %city $+ 
  }
  if (*<span style="white-space: nowrap">* iswm %r) && (*</span></td>* iswm %r) {
    echo -a 12Metropolis Area:1 $httpstrip(%r) $+ 
  }
  if (%time_ [ $+ [ $sockname ] ]) && (<td align="left" >* iswm %r) { return }
  if (%time_ [ $+ [ $sockname ] ]) { echo -a 12Local Time:1 $httpstrip(%r) $+  | unset %time_ [ $+ [ $sockname ] ] }
  if ($left(%r,5) == Local) && (*</td>* iswm %r) { set -e %time_ [ $+ [ $sockname ] ] 1 }


  if (%code_ [ $+ [ $sockname ] ]) && (<td align="left" >* iswm %r) { return }
  if (%code_ [ $+ [ $sockname ] ]) { echo -a 12Country Code:1 $httpstrip(%r) $+  | unset %code_ [ $+ [ $sockname ] ] }
  if (*<td align="left">Country Code</td>* iswm %r) { set -e %code_ [ $+ [ $sockname ] ] 1 }

  if (%reg_ [ $+ [ $sockname ] ]) && (<td align="left" >* iswm %r) { return }
  if (%reg_ [ $+ [ $sockname ] ]) { echo -a 12Region:1 $httpstrip(%r) $+  | unset %reg_ [ $+ [ $sockname ] ] }
  if (*<td align="left">Region</td>* iswm %r) { set -e %reg_ [ $+ [ $sockname ] ] 1 }

  if (%post_ [ $+ [ $sockname ] ]) && (<td align="left" >* iswm %r) { return }
  if (%post_ [ $+ [ $sockname ] ]) { echo -a 12Postal Code:1 $httpstrip(%r) $+  | unset %post_ [ $+ [ $sockname ] ] }
  if (*<td align="left">Postal Code</td>* iswm %r) { set -e %post_ [ $+ [ $sockname ] ] 1 }

  if (%isp_ [ $+ [ $sockname ] ]) { echo -a 12ISP:1 $httpstrip(%r) $+  | unset %isp_ [ $+ [ $sockname ] ] }
  if (*<td align="left" width="33%">* iswm %r) { set -e %isp_ [ $+ [ $sockname ] ] 1 }
}

ON *:SOCKCLOSE:InfoIP_*: { echo -a ***** End of  $+ $sock($sockname).mark $+  IP lookup ***** }

alias httpstrip {
  var %xx = $replace($1-,&#x26;,$chr(38),$chr(124),-,$chr(125),-,&#125;,-,&#124;,-,&quot;,$chr(34),&amp;,&,&lt;,<,&gt;,>,&nbsp;,$chr(32),&#x26;#039;,$chr(39),$chr(13),$chr(32))
  var %x = $remove(%xx,<![CDATA[,]]>,$chr(2),$chr(4),$chr(9),$chr(31),$chr(22),$chr(29),$chr(10),$chr(13))
  var %i = $regsub(%x,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x)
  return %x
}