startnet.cmd

@echo off
rem Created in 2024 by Gelip
title WinXP SP2 64-bit UEFI on GPT or MBR
cls

powercfg /s 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c >nul

echo:
echo Searching CD\DVD\USB drive letter
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist "%%i:\sources\*.wim" set drive=%%i:
echo:
echo I found on %drive%

echo:
echo Menu Choices
echo:
echo 1 Setup on clean disk
echo 2 Setup next to another OS
echo 3 Exit to CMD
echo:
choice /m "Select option:" /n /c:123
if %errorlevel% equ 3 echo:&cmd /k
if %errorlevel% equ 2 goto together
if %errorlevel% equ 1 goto clean

:clean

echo Making partitions EFI, OS and one of the remaining space
:disks
cls
(
echo list disk
)>list.txt
diskpart /s list.txt
echo:
set /p disk=Please enter the disk number:
if [%disk%]==[] (goto disks)
cls
(
echo sel disk %disk%
echo clean
echo list disk
)>sel.txt
diskpart /s sel.txt
if %errorlevel% neq 0 echo:&&pause&&goto disks
for /f "tokens=6,7 delims= " %%a in ('echo list disk ^| diskpart ^| find "Disk %disk%"') do set mb=%%a&&set un=%%b
if "%un%"=="GB" set /a mb=%mb%*1024&&set un=%un:GB=MB%

:parts
echo:
set part=0
set /p part=Enter size OS partition in MB (min. 2100 MB, max. %mb% %un%):
set /a p=%part%
if %p% gtr %mb% echo:&&echo The size %part% MB is large than %mb% MB&&goto parts
if %p% equ 0 echo:&&echo Please enter digit (not zero)&&goto parts
if %p% lss 2100 echo:&&echo The size %part% MB is small than 2100 MB&&goto parts

echo:
set /p mode=Disk GPT or MBR?
if %mode%==gpt (
set type=efi
)
if %mode%==mbr (
set type=pri
)
echo:
echo Disk %mode%, partition %type%

(
echo sel disk %disk%
echo convert %mode% noerr
echo create par %type% size=100
echo format fs=fat32 label="EFI"
echo assign letter u
echo create par pri size=%part%
echo format fs=ntfs quick label="OS"
echo assign letter c
echo create par pri
)>prep.txt
diskpart /s prep.txt
rem if %errorlevel% neq 0 echo:&&pause&&goto parts

echo:
echo Copying EFI folder from %drive%\sources to EFI partition
echo:
xcopy %drive%\sources\EFI U:\EFI /e /h /c /i

echo:
wimlib-imagex apply %drive%\sources\install.wim C:

if %mode%==mbr goto manual

echo:
echo Moving BCC to BCD then fix, wait...
move U:\EFI\Microsoft\Boot\BCC U:\EFI\Microsoft\Boot\BCD
bcdedit /set {bootmgr} device partition=U: >nul
bcdedit /set {ntldr} device partition=C: >nul
bcdedit /set {ntldr} custom:21000001 partition=C: >nul
bcdedit /set {9eb8f329-85ae-4953-aba6-2c7d803aa4fe} device partition=C: >nul
bcdedit /set {9eb8f329-85ae-4953-aba6-2c7d803aa4fe} custom:21000001 partition=C: >nul
bcdedit /set {0ef2423f-74c2-4688-b906-99c3dc77d8ba} device partition=C: >nul
bcdedit /set {0ef2423f-74c2-4688-b906-99c3dc77d8ba} custom:21000001 partition=C: >nul

echo:
echo Adding WinXP Boot Manager to NVRAM boot menu, wait...
echo:
bcdedit /set {fwbootmgr} displayorder {bootmgr} /addfirst

echo:
echo Moving BCD to BCC
move U:\EFI\Microsoft\Boot\BCD U:\EFI\Microsoft\Boot\BCC

echo:
pause
wpeutil reboot

:manual

(
echo sel disk %disk%
echo sel par 1
echo set id=1b
echo sel par 2
echo active
)>hid.txt
diskpart /s hid.txt

echo:
echo Mounting and searching 100MB FAT32 partition
C:\WINDOWS\mountstor -ng
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist "%%i:\EFI\Microsoft\Boot\bootxp64.efi" set efi=%%i:
echo I found 100MB FAT32 at %efi%

echo:
echo Fix BCC, wait...
set stor=%efi%\EFI\Microsoft\Boot\BCC
bcdedit /store %stor% /set {bootmgr} device partition=%efi% >nul
bcdedit /store %stor% /set {ntldr} device partition=C: >nul
bcdedit /store %stor% /set {ntldr} custom:21000001 partition=C: >nul
bcdedit /store %stor% /set {9eb8f329-85ae-4953-aba6-2c7d803aa4fe} device partition=C: >nul
bcdedit /store %stor% /set {9eb8f329-85ae-4953-aba6-2c7d803aa4fe} custom:21000001 partition=C: >nul
bcdedit /store %stor% /set {0ef2423f-74c2-4688-b906-99c3dc77d8ba} device partition=C: >nul
bcdedit /store %stor% /set {0ef2423f-74c2-4688-b906-99c3dc77d8ba} custom:21000001 partition=C: >nul

echo:
echo Now please add WinXP Boot Manager to NVRAM boot menu in BOOTICE v1.3.3 x64:
echo:
echo - Click UEFI tab, Edit boot entries, Add
echo - Select %efi%\EFI\Microsoft\Boot\bootxp64.efi file and click OK
echo - Click Up so many times to move the entry to the first place on the list
echo - Change name in Menu title: to WinXP Boot Manager
echo - Click Save current boot entry, OK, Close and Exit
C:\WINDOWS\bootice

echo:
pause
wpeutil reboot

:together

echo Making OS partition
:diskst
cls
(
echo list disk
)>list.txt
diskpart /s list.txt
echo:
set /p disk=Please enter the disk number:
if [%disk%]==[] (goto diskst)
(
echo sel disk %disk%
echo list par
)>sel.txt
diskpart /s sel.txt
if %errorlevel% neq 0 echo:&&pause&&goto diskst

:numb
echo:
set pnum=0
set /p pnum=Select partition number for shrink (best last):
set /a pn=%pnum%
if %pn% equ 0 echo:&&echo Please enter digit (not zero)&&goto numb

:partst
echo:
set part=0
set /p part=Enter shrink size for OS partition in MB (min. 2100 MB):
set /a p=%part%
if %p% equ 0 echo:&&echo Please enter digit (not zero)&&goto partst
if %p% lss 2100 echo:&&echo The size %part% MB is small than 2100 MB&&goto partst
(
echo sel disk %disk%
echo sel par %pnum%
echo shrink desired=%part%
echo create par pri
echo format fs=ntfs quick label="OS"
echo assign letter z
)>prep.txt
diskpart /s prep.txt
if %errorlevel% neq 0 (goto partst)

echo:
wimlib-imagex apply %drive%\sources\install.wim Z:

echo:
echo MountedDevices key fix
reg load HKLM\TEMPSYSTEM "Z:\WINDOWS\system32\config\system" >nul
reg copy "HKLM\SYSTEM\MountedDevices" "HKLM\TEMPSYSTEM\MountedDevices" /f >nul

reg delete "HKLM\TEMPSYSTEM\MountedDevices" /v "\DosDevices\X:" /f >nul

for /f "skip=2 tokens=3 delims= " %%c in ('"reg query "HKLM\TEMPSYSTEM\MountedDevices" /v "\DosDevices\Z:""') do (
    reg delete "HKLM\TEMPSYSTEM\MountedDevices" /v "\DosDevices\Z:" /f >nul
    reg add "HKLM\TEMPSYSTEM\MountedDevices" /v "\DosDevices\C:" /t REG_BINARY /d "%%c" /f >nul
)
reg unload HKLM\TEMPSYSTEM >nul

echo:
set efi=U:
mountvol %efi% /s
echo EFI partition is on %efi%

echo:
echo Copying files to EFI partition without Fonts\wgl4_boot.ttf
xcopy %drive%\sources\EFI\Boot\*.* %efi%\EFI\Boot\*.* /y >nul
xcopy %drive%\sources\EFI\Microsoft\Boot\*.* %efi%\EFI\Microsoft\Boot\*.* /y >nul

echo:
echo Moving current BCD to BCD.bak and BCC to BCD for edit
move %efi%\EFI\Microsoft\Boot\BCD %efi%\EFI\Microsoft\Boot\BCD.bak
move %efi%\EFI\Microsoft\Boot\BCC %efi%\EFI\Microsoft\Boot\BCD

echo:
echo Fix BCD (BCC)
bcdedit /set {bootmgr} device partition=%efi% >nul
bcdedit /set {ntldr} device partition=Z: >nul
bcdedit /set {ntldr} custom:21000001 partition=Z: >nul
bcdedit /set {9eb8f329-85ae-4953-aba6-2c7d803aa4fe} device partition=Z: >nul
bcdedit /set {9eb8f329-85ae-4953-aba6-2c7d803aa4fe} custom:21000001 partition=Z: >nul
bcdedit /set {0ef2423f-74c2-4688-b906-99c3dc77d8ba} device partition=Z: >nul
bcdedit /set {0ef2423f-74c2-4688-b906-99c3dc77d8ba} custom:21000001 partition=Z: >nul

echo:
echo Adding WinXP Boot Manager to NVRAM boot menu as first
bcdedit /set {fwbootmgr} displayorder {bootmgr} /addfirst

echo:
echo Moving edited BCD to BCC and BCD.bak to BCD
move %efi%\EFI\Microsoft\Boot\BCD %efi%\EFI\Microsoft\Boot\BCC
move %efi%\EFI\Microsoft\Boot\BCD.bak %efi%\EFI\Microsoft\Boot\BCD

echo:
pause
wpeutil reboot