# kk23_AspectAegis ============================================================
Begin kk23_AspectAegis

if ( GetDisabled )
	return
endif

if ( GetChameleon < 50 )
	ModChameleon 50
endif

if ( OnDeath )
	Player->AddItem "kk23_Soul_Husk" 1
	Player->AddSpell "kk23 AegisSpell"
	PlaceAtMe sprigganup 1 1 1 ; Visual effect
	Disable
endif

if ( GetJournalIndex "kk23_Zete" > 10 )
	disable
endif

end

# kk23_AspectAtrophy ==========================================================
Begin kk23_AspectAtrophy

if ( GetDisabled )
	return
endif

if ( GetChameleon < 50 )
	ModChameleon 50
endif

if ( OnDeath )
	Player->AddItem "kk23_Soul_Husk" 1
	Player->AddSpell "kk23 AtrophySpell"
	PlaceAtMe sprigganup 1 1 1 ; Visual effect
	Disable
endif

if ( GetJournalIndex "kk23_Zete" > 10 )
	disable
endif

end

# kk23_AspectDecay ============================================================
Begin kk23_AspectDecay

if ( GetDisabled )
	return
endif

if ( GetChameleon < 50 )
	ModChameleon 50
endif

if ( OnDeath )
	Player->AddItem "kk23_Soul_Husk" 1
	Player->AddSpell "kk23 DecaySpell"
	PlaceAtMe sprigganup 1 1 1 ; Visual effect
	Disable
endif

if ( GetJournalIndex "kk23_Zete" > 10 )
	disable
endif

end

# kk23_AspectEvanesce =========================================================
Begin kk23_AspectEvanesce

if ( GetDisabled )
	return
endif

if ( GetChameleon < 50 )
	ModChameleon 50
endif

if ( OnDeath )
	Player->AddItem "kk23_Soul_Husk" 1
	Player->AddSpell "kk23 EvanesceSpell"
	PlaceAtMe sprigganup 1 1 1 ; Visual effect
	Disable
endif

if ( GetJournalIndex "kk23_Zete" > 10 )
	disable
endif

end

# kk23_AspectWilt =============================================================
Begin kk23_AspectWilt

if ( GetDisabled )
	return
endif

if ( GetChameleon < 50 )
	ModChameleon 50
endif

if ( OnDeath )
	Player->AddItem "kk23_Soul_Husk" 1
	Player->AddSpell "kk23 WiltSpell"
	PlaceAtMe sprigganup 1 1 1 ; Visual effect
	Disable
endif

if ( GetJournalIndex "kk23_Zete" > 10 )
	disable
endif

end

# kk23_CurseDoorScr ===========================================================
Begin kk23_CurseDoorScr

if ( GetDisabled )
	return
endif

if ( GetJournalIndex "kk23_Zete" >= 50 )
	Disable
endif

end

# kk23_DoorScr ================================================================
Begin kk23_DoorScr

if ( MenuMode )
	return
endif

if ( GetDisabled )
	if ( GetJournalIndex "kk23_Zete" >= 50 )
		enable
	endif
	return
endif

if ( GetJournalIndex "kk23_Zete" < 50 )
	Disable
endif

end

# kk23_SGS_Scr ================================================================
begin kk23_SGS_Scr

short charged

if ( OnActivate )
else
	return
endif

if ( Charged )
	if ( player->getItemCount "Misc_SoulGem_Grand" )
		MessageBox "Day gives way to night, death becomes new life."
		PlaySound "Conjuration Cast"
		player->additem "AB_Misc_SoulGemBlack" 1
		player->removeitem "Misc_SoulGem_Grand" 1
		return
	endif
	Messagebox "You need a grand soul gem to create a black soul gem."
	return
endif

if ( player->getItemCount "kk23_Soul_Husk" >= 3 )
	player->removeitem "kk23_Soul_Husk" 3
	PlaySound "Conjuration Cast"
	set charged to 1
	return
endif
MessageBox "Gather three fragments of the asunder spirit and cast its husk into the fire."

end

# kk23_SGSDummyScr ============================================================
Begin kk23_SGSDummyScr

If ( OnActivate )
	messagebox "Purge the asunder spirit and lift the shroud of darkness that suffocates my flame."
endif

end

# kk23_SpiderTrap =============================================================
begin kk23_SpiderTrap

short done

if ( OnActivate )
	if ( done )
	else
		Set done to 1
		PlaceAtPC "AB_Fau_SpiderBlack" 1 200 1
	endif
	Activate
endif

end

# kk23_TeleportRing_Script ====================================================
Begin kk23_TeleportRing_Script

short button
short messageOn
short OnPcEquip

if ( OnPCEquip )
	set OnPCEquip to 0
	set messageOn to 1
	MessageBox "Would you like to return to Tel Amur?" "Yes" "No"
	return
endif

if ( messageOn )
	set button to GetButtonPressed
	if ( button < 0 )
		return
	endif
	set messageOn to 0
	if ( button )
		return
	endif
	Player->PositionCell 3941 6160 13420 180 "Tel Amur, Grand Hall"
endif

End

# Kk23_TelRootRetracting_s ====================================================
Begin Kk23_TelRootRetracting_s

short state
Short animStart
Short stayOpen
Float timer

; Root retracts when the player approaches and opens back up when the player is further away.

; Idle Closed
; Idle2 Opening
; Idle3 Open
; Idle4 Closing

if ( state == 0 )
	if ( player->HasItemEquipped kk23_glaive_of_guises )
		set state to 1
	endif
endif

if ( state != 1 )
	Return
endif

if ( CellChanged )
	; Close the roots
	set stayOpen to 0
	PlayGroup Idle
endif

if ( stayOpen == 1 )
	PlayGroup Idle3
elseif ( stayOpen == -1 )
	set stayOpen to 0
	LoopGroup Idle4 0 1
endif

if ( GetDistance "player" <= 900 )
	if ( stayOpen == 0 )
		; slightly randomize the start time if multiple roots are used
		set animStart to Random 20
		set timer to ( animStart / 10 )
		set timer to ( timer - GetSecondsPassed )
		if ( timer < 0 )
			LoopGroup Idle2 0 1
			set stayOpen to 1
			Return
		endif
	endif
	return
endif

if ( stayOpen == 1 )
	set stayOpen to -1
endif

End

# kk23_ZeteCurseRingScr =======================================================
Begin kk23_ZeteCurseRingScr

short OnPCEquip

if ( MenuMode )
	return
endif

if ( OnPCEquip )
	if ( GetJournalIndex kk23_Zete == 10 )
		EnableTeleporting
		EnableLevitation
		Player->PositionCell 6592 1472 13421 180 "Tel Amur"
		journal kk23_Zete 20
	endif
	return
endif

if ( GetJournalIndex kk23_Zete >= 20 )
	if ( GetJournalIndex kk23_Zete < 50 )
		Player->Equip "kk23_Zete_Ring_Curse"
		messagebox "The ring tightens its grip."
		player->ModCurrentHealth -5
	endif
endif

End


# kk23_ZeteFyrScr =============================================================
Begin kk23_ZeteFyrScr

Short DoOnce
short Aegis
short Atro
short Decay
short Evan
short Wilt
short FullPower

if ( GetPCCell "Maw of Tel Amur" )
	if ( GetHealth < 100 )
		ModCurrentHealth 100
	endif
endif

if ( Aegis == 0 )
	if ( player->GetSpell "kk23 AegisSpell" )
		AddSpell "kk23 AegisSpell"
		AddSpell "kk23 Aegis2"
		Player->RemoveSpell "kk23 AegisSpell"
		ModCurrentMagicka 300
		set Aegis to 1
	endif
endif

if ( Atro == 0 )
	if ( player->GetSpell "kk23 AtrophySpell" )
		AddSpell "kk23 AtrophySpell"
		AddSpell "kk23 Atrophy2"
		Player->RemoveSpell "kk23 AtrophySpell"
		ModCurrentMagicka 300
		set Atro to 1
	endif
endif

if ( Decay == 0 )
	if ( player->GetSpell, "kk23 DecaySpell" )
		AddSpell "kk23 DecaySpell"
		AddSpell "kk23 Decay2"
		Player->RemoveSpell "kk23 DecaySpell"
		ModCurrentMagicka 300
		set Decay to 1
	endif
endif

if ( Evan == 0 )
	if ( player->GetSpell, "kk23 EvanesceSpell" )
		AddSpell "kk23 EvanesceSpell"
		AddSpell "kk23 Evanesce2"
		Player->RemoveSpell "kk23 EvanesceSpell"
		ModCurrentMagicka 300
		set Evan to 1
	endif
endif

if ( Wilt == 0 )
	if ( player->GetSpell, "kk23 WiltSpell" )
		AddSpell "kk23 WiltSpell"
		AddSpell "kk23 Wilt2"
		Player->RemoveSpell "kk23 WiltSpell"
		ModCurrentMagicka 300
		set Wilt to 1
	endif
endif

if ( Aegis == 1 )
	if ( Atro == 1 )
		if ( Decay == 1 )
			if ( Evan == 1 )
				if ( Wilt == 1 )
					if ( FullPower == 0 )
						set FullPower to 1
					endif
				endif
			endif
		endif
	endif
endif

if ( FullPower == 1 )
	if ( GetMagicka < 100 )
		ModCurrentMagicka 100
	endif
endif

if ( DoOnce == 0 )
	if ( GetDistance Player <= 500 )
		set DoOnce to 1
		FadeOut 1
		StartScript kk23_ZeteTeleportScr ; global script is automatically targeted on local script reference /abot
		PlaySound blackoutin
	endif
endif

if ( GetPCCell "Zete Fyr's Pocket Realm" )
	if ( DoOnce == 1 )
		FadeIn 1
		set DoOnce to 2
	endif
	DisableTeleporting
	DisableLevitation
endif

if ( OnDeath )
	if ( DoOnce == 2 )
		Journal "kk23_Zete", 10
		AddItem "kk23_Zete_Ring_Curse" 1
		set DoOnce to 3
	endif
endif

end

# kk23_ZeteTeleportScr ========================================================
Begin kk23_ZeteTeleportScr

Player->PositionCell 0 700 -3 180 "Zete Fyr's Pocket Realm"
PositionCell 0 0 -3 180 "Zete Fyr's Pocket Realm"
StopScript kk23_ZeteTeleportScr ; remember to stop global scripts when done! /abot
ForceGreeting

end