¤ pokemon ¤

#pokemon on
on *:start:{ start_pdb }
on *:exit:{ close_pdb }
alias start_pdb {
  set %pdb $sqlite_open(txt/pokemon/pokemon.db3)
  hmake pokemon
  var %t = $tm(2) $tm(2) $tm(2) $tm(2) $tm(2) $tm(2)
  while ($p_loc(%x,%y).name == 0) { var %x = $rand(1,5), %y = $rand(1,5) }
  hadd pokemon p_attempt 1
  hadd pokemon p_salesman %x %y
  hadd pokemon p_mall $dupe(%t)
}
alias close_pdb {
  sqlite_close %pdb
  unset %pdb
  hfree pokemon
}
alias sql_esc { return $replace($1-,$chr(32),_32,$chr(39),_39,$chr(40),_40,$chr(41),_41,$chr(44),_44,$chr(45),_45,$chr(46),_46,$chr(91),_91,$chr(93),_93,$chr(94),_94,$chr(96),_96,$chr(124),_124) }
alias sql_re { return $regsubex($1-,/(_(\d{2,3}))/g,$chr( \2 )) }
on *:text:!catch:%chans:{
  if (%pdb) {
    var %a = $p_active($.nick), %status = $p_status($.nick)
    if (%status == none) {
      .notice $nick You don't have any pokemon yet, Please choose from the following by typing !choose <pokemon>
      .notice $nick Bulbasaur, Charmander, Squirtle, Pidgey, Weedle, Pichu, Machop, Abra, Geodude, Staryu, Chikorita, Cyndaquil, Totodile
      if (!$.nick($nick).check) { .notice $nick NOTE: You either aren't logged in or you don't have mode +x set. If you change your name it wont know who you are. Do not create a second account if you change nicks. }
    }
    elseif (%status == learn) { .notice $nick %a has too many moves! $+([,$sql_re($p_mark($.nick)),]) Type !forget <move> }
    elseif (%status == replace) {
      tokenize 9 $.nick $+ $chr(9) $+ $p_mark($.nick)
      .notice $nick You caught $gettok($2-,1,42) but you already have a $gettok($2-,1,42) $+ ! Do you want to !keep or !release the new one?
      .notice $nick Old: $p_statfmt($1,$p_stat($1,$gettok($2-,1,42)))
      .notice $nick New: $p_statfmt($1,$2-)
    }
    elseif (%status == choiceadv) { choiceadv $gettok($p_mark($.nick),2,42) }
    elseif ($hget(pokemon,$.nick)) { .notice $nick All the pokemon ran away, Try again later. ( $+ $v1 sec $+ ) }
    elseif (%status == ready) {
      if ($p_daycare($.nick) != none) { p_+daycare $.nick }
      hadd -z pokemon $.nick $iif($istok(%punish,$.nick,44),150,$iif($p_item($.nick,Bicycle),45,60))
      hinc pokemon p_attempt
      if ($calc($hget(pokemon,p_attempt) % 10) == 0) && ($rand(1,100) < 80) { hadd pokemon p_salesman $p_loc($hget(pokemon,p_salesman)).rand }
      if ($calc($hget(pokemon,p_attempt) % 100) == 0) {
        var %t = $tm(2) $tm(2) $tm(2) $tm(2) $tm(2) $tm(2)
        hadd pokemon p_mall $dupe(%t)
      }
      p_ps $.nick attempts
      var %x = $rand(0,100000) % 100, %q = $dupe($p_get(20)), %p = $gettok(%q,1,44), %lvl = $p_stat($.nick,%a).lvl, %loc = $p_loc($.nick).num
      if (%x != 0) && ($calc($rand(0,100000) % 100) <= $p_noncom(%loc)) {
        var %tf = txt/pokemon/nc $+ $ticks , %cadv, %a
        filter -ffg txt/pokemon/noncom.txt %tf /(\x09|\x2C)( %loc |\*)(\x09|\x2C)/x
        while (!%cadv) {
          var %a = $read(%tf)
          if (!$gettok(%a,3,9)) || ($rand(1,100) > $gettok(%a,3,9)) {
            %cadv = $gettok(%a,1,9)
            if (%cadv == 38) && ($p_loc($.nick).num != $hget(pokemon,p_salesman)) { %cadv = $null }
          }
        }
        choiceadv %cadv
        .remove %tf
      }
      else {
        :redo
        var %n = 1, %a, %c, %u, %r, %y = $rand(1,100), %catch, %npc, %npcvs, %vs, %cash
        while (%n <= $numtok(%q,44)) {
          %a = $regsubex($gettok(%q,%n,44),/(^\x20)/,)
          if ($read(txt/pokemon/rare.txt,r,/\x09( $regescape(%a) )$/xi)) { %r = $addtok(%r,%a,44) }
          elseif ($has_pokemon($.nick,%a) == has) { %c = $addtok(%c,%a,44) }
          else { %u = $addtok(%u,%a,44) }
          inc %n
        }
        var -s %n = $calc(100 / ($numtok(%q,44) / $numtok(%u,44)))
        if (%x == 0) {
          %p = $p_rare
          if (!%r) || (!$istok(%r,%p,44)) {
            msg $chan $nick $+ : You see a rare %p in the distance, but it's gone before you can get to it.
            see_pokemon $.nick %p
            return
          }
        }
        elseif (%n) && (%y <= %n) { var -s %p = $.rand(%u) }
        else { var -s %p = $.rand(%c) }
        if (!%p) {
          msg $chan Error: no pokemon selected.
          msg #flip c %c
          msg #flip u %u
          msg #flip r %r
          return
        }
        if ($p_uncom(%p)) {
          if ($rand(1,100) < 85) {
            %x = 1
            %q = $dupe($p_get(20))
            msg #flip %p rejected
            goto redo
          }
        }
        var %min = $floor($bottom($cap($calc(%lvl * .85 - 1),$calc($p_el(%p) * .85)),$p_ml(%p))), %max = $ceil($bottom($cap($cap($calc(%lvl * 1.20 + 1),$calc($p_el(%p) * $+(.,$rand(85,100)))),99),$calc($p_ml(%p) + 1))), %lvl = $rand(%min,%max)
        var %npc = $p_gen(%p,%lvl), %pv = $gettok(%npc,2,9)
        %npcvs = $pokemon($gettok(%npc,1,9)).type $+ $chr(9) $+ $gettok(%npc,12-17,9)
        %vs = $p_vs($p_stat($.nick,$p_active($.nick)).vs,%npcvs)
        %cash = $ceil($calc(%lvl ^ 1.7 + (%lvl + $rand(1,%lvl) - $rand(1,%lvl)) * 1.5 + (%lvl * 2)))
        if (%vs == 1) {
          var %cr = $calc($p_cr(%p) * $p_bmod($p_cug($.nick).ball)), %crp = $calc(100 - (100 / (256 / %cr) + $rand($calc(10 - (%cr ^ .7 ^ .5)),50) - $rand($sqrt(%cr),50))), %crr = $rand(1,100)
          if (%crr > %crp) { %catch = 1 }
          if (%catch) && ($p_item($.nick,Pokeball) > 0) {
            p_item $.nick Pokeball -1
            msg $chan $nick $+ : You encounter a $iif($p_rare(%p),rare,wild) $p_shiny($.nick,%pv) %p ( $+ %lvl $+ ) - After a long battle you are the victor. You just caught %p $+ ! (+$ $+ %cash cash) (+ $+ $bytes($p_mexp(%p,%lvl),b) Exp)
            if ($p_item($.nick,Pokeball) == 0) { .notice $nick You just used your last pokeball! You need to buy more or you wont be able to catch any more pokemon. }
            add_pokemon $.nick %npc
            p_item $.nick Cash + $+ %cash
          }
          else {
            msg $chan $nick $+ : You encounter a $iif($p_rare(%p),rare,wild) $p_shiny($.nick,%pv) %p ( $+ %lvl $+ ) - After a long battle you are the victor. $iif($p_item($.nick,Pokeball) < 1,You realize you are out of pokeballs so you can't catch %p $+ !) (+$ $+ %cash cash) (+ $+ $bytes($p_mexp(%p,%lvl),b) Exp)
            p_item $.nick Cash + $+ %cash
            if ($p_item($.nick,Pokeball) > 0) {
              if (!$has_pokemon($.nick,%p)) || ($has_pokemon($.nick,%p) == seen) {
                if (%catch) { p_item $.nick Pokeball -1 }
              }
              if ($p_item($.nick,Pokeball) == 0) { .notice $nick You just used your last pokeball! You need to buy more or you wont be able to catch any more pokemon. }
            }
            noop $p_+exp(%p,%lvl)
          }
        }
        else {
          msg $chan $nick $+ : You encounter a $iif($p_rare(%p),rare,wild) $p_shiny($.nick,%pv) %p ( $+ %lvl $+ ) - He was too strong for you, You lose.
          see_pokemon $.nick %p
        }
      }
    }
  }
}
alias choiceadv {
  var %x, %q = $dupe($p_get(20)), %p = $gettok(%q,1,44), %lvl = $p_stat($.nick,$p_active($.nick)).lvl, %loc = $p_loc($.nick).num
  if ($1 == 1) { msg $chan $nick $+ : You wander around, but don't really find anything of interest. }
  elseif ($1 == 2) {
    %x = $ceil($calc($rand(5,10) * $rand(10,50) * (%lvl ^ .4)))
    msg $chan $nick $+ : You get sidetracked while looking for pokemon, but you find some buried treasure, score! (+$ $+ %x cash)
    p_item $.nick cash + $+ %x
  }
  elseif ($1 == 3) {
    %x = $rand(1,10) $iif($rand(1,10) > 8, * 2)
    msg $chan $nick $+ : You don't have any luck looking for pokemon, but you stumble across a stash of $p_cug($.nick).ball $+ 's! (+ $+ %x $p_cug($.nick).ball $+ 's!)
    p_item $.nick pokeball + $+ %x
  }
  elseif ($1 == 4) {
    %x = $rand(1,25)
    if (%x == 25) {
      msg $chan $nick $+ : You chase after %p but it gets away, but you spot some Rare candy, sweet! (+1 Rare candy)
      p_item $.nick $sql_esc(Rare candy)
      see_pokemon $.nick %p
    }
    elseif (%x == 1) {
      msg $chan $nick $+ : You chase after %p but trip. You look back to see what it was and realize you tripped over a Gold nugget! (+1 Gold nugget)
      p_item $.nick $sql_esc(Gold nugget)
      see_pokemon $.nick %p
    }
    else {
      var %x = $rand(1,100), %t = $iif(%x <= 25,battle,hold), %x = $p_getitem(%t), %n = 1, %i = $p_item($.nick,%x)
      if (%t == hold) {
        while ($rand(1,100) < $calc(%i * 20)) && (%n <= 10) {
          var %x = $p_getitem(%t)
          var %i = $p_item($.nick,%x)
          inc %n
        }
      }
      if (*potion* iswm %x) { %x = $p_cug($.nick).potion }
      msg $chan $nick $+ : You start battling with %p $+ . It gets away, but it drops a %x $+ . (+1 %x $+ )
      p_item $.nick $sql_esc(%x)
      see_pokemon $.nick %p
    }
  }
  elseif ($1 == 5) {
    var %i1 = $p_getitem(hold), %i2 = $p_getitem(hold), %i3 = $p_getitem(hold)
    msg $chan $nick $+ : You find a stash of sweet loot! (+1 %i1 $+ , %i2 $+ , %i3 $+ )
    p_item $.nick $sql_esc(%i1)
    p_item $.nick $sql_esc(%i2)
    p_item $.nick $sql_esc(%i3)
  }
  elseif ($1 == 6) {
    msg $chan $nick $+ : %p spots you and attacks! You just got ownd, you need some time to rest before you can go out again.
    hadd -z pokemon $.nick 180
    see_pokemon $.nick %p
  }
  elseif ($1 isnum 7-10) {
    var %i = $gettok($read(txt/pokemon/noncom.txt,$1),4,9)
    msg $chan $nick $+ : You find a mysterious %i lying on the ground. (+1 %i $+ )
    p_item $.nick $sql_esc(%i) +1
  }
  elseif ($1 isnum 11-30) || ($1 isnum 36-37) {
    var %x = $read(txt/pokemon/noncom.txt,r,/^ $1 \x09/ix), %i = $gettok(%x,4,9), %c = $gettok(%x,5,9)
    msg $chan $nick $+ : You are exploring $p_loc($.nick).name when you meet a guy selling a %i $+ . ($ $+ $bytes(%c,b) $+ ) ( $+ You have $p_item($.nick,%i) $+ ) - [Buy] [Leave]
    p_status $.nick choiceadv
    p_mark $.nick $+(buy|leave*,$1,*,%i,*,%c)
  }
  elseif ($1 isnum 31-35) {
    var %x = $read(txt/pokemon/noncom.txt,r,/^ $1 \x09/ix), %i = $gettok(%x,4,9)
    msg $chan $nick $+ : You meet an old man, after a short talk he gives you a %i ( $+ $tm(%i) $+ ).
    p_item $.nick %i +1
  }
  elseif ($1 == 38) {
    var %1 = $tm(3), %2 = $tm(3), %3 = $tm(3)
    msg $chan $nick $+ : You meet a traveling salesman, he has a few TM's for sale. ($50,000) - $+([,%1,] [,%2,] [,%3,]) [Leave]
    p_status $.nick choiceadv
    p_mark $.nick $+(%1,|,%2,|,%3,*,$1,*,50000)
  }
  elseif ($1 isnum 39-44) {
    var %i = $gettok($read(txt/pokemon/noncom.txt,$1),4,9)
    msg $chan $nick $+ : You come across a tree with a %i $+ . (+1 %i $+ )
    p_item $.nick $sql_esc(%i) +1
  }
  elseif ($1 == daycare) {
    var %x = $addtok($p_team($.nick),leave,124)
    if ($p_daycare($.nick) == none) {
      .notice $nick Welcome to Pokemon daycare! Would you like to leave a pokemon with us? $+([,$replace(%x,|,] [),])
      p_status $.nick choiceadv
      p_mark $.nick $+(%x,*daycare)
    }
    else {
      var %dcl = $replace($p_player($.nick,dcl),none,0)
      .notice $nick Welcome to Pokemon daycare! $p_daycare($.nick) is currently staying with us $+ $iif(%dcl,$chr(44) and has gained $v1 levels) $+ . Would you like to take him with you? $ $+ $bytes($calc((%dcl + 1) * 1000),b) [Yes] [No]
      p_status $.nick choiceadv
      p_mark $.nick yes|no*daycare
    }
  }
}
on *:text:!visit*:#:{
  if ($p_status($.nick) == ready) {
    if (*pokemart* iswm $2-) {
      if (!$istok($p_loc($.nick).npc,Pokemart,44)) { .notice $nick There isn't a Pokemart close by! }
      else {
        var %b = $p_cug($.nick).ball, %p = $p_cug($.nick).potion
        .notice $nick Welcome to Pokemart! You currently have $ $+ $p_item($.nick,cash) $+ . Commands: !buy, !upgrade and !sell
        .notice $nick %b $+ : $ $+ $bytes($p_item(%b).cost,b) $iif($p_iug(%b),(Upgrade to $p_iug(%b) $+ : $ $+ $bytes($p_iug(%b).cost,b) +$ $+ $calc($p_item($p_iug(%b)).cost - $p_item(%b).cost) per %b $+ ) ) - %p $+ : $ $+ $bytes($p_item(%p).cost,b) $iif($p_iug(%P),(Upgrade to $p_iug(%p) $+ : $ $+ $bytes($p_iug(%p).cost,b) +$ $+ $calc($p_item($p_iug(%p)).cost - $p_item(%p).cost) per %p $+ ) )
        .notice $nick Revive: $!2,000 - Antidote: $!100 - Paralyze heal: $!200 -  Awakening: $!200 -  Burn heal: $!500 -  Ice heal: $!500 -  Full heal: $!1,000 -  Full restore: $!5,000
        if (!$p_item($.nick,Bicycle)) { .notice $nick Bicycle: $!100,000 }
      }
    }
    elseif (*pokecenter* iswm $2-) {
      if (!$istok($p_loc($.nick).npc,Pokecenter,44)) { .notice $nick There isn't a Pokecenter close by! }
      else {
        .notice $nick Welcome to the Pokecenter! Commands: !take and !leave to change pokemon in your team.
        .notice $nick $p_team($.nick) Current team: $replace($p_team($.nick),|,$chr(32) - $chr(32))
      }
    }
    elseif (*mall* iswm $2-) {
      if (!$istok($p_loc($.nick).npc,The mall,44)) { .notice $nick You aren't near The Mall! }
      else {
        .notice $nick Welcome to The Mall! You can buy TMs with he !buy command.
        var %f = txt/pokemon/mall $+ $ticks, %a
        filter -ffg txt/pokemon/tms.txt %f /\x09(1)$/x
        .fopen tm %f
        while ($fread(tm)) {
          %a = $addtok(%a,$+([,$gettok($v1,1,9),]),32)
          if ($numtok(%a,32) > 14) {
            .notice $nick TM's currently in stock ($20,000): %a
            %a = $null
          }
        }
        .fclose tm
        .remove %f
        .notice $nick Limited time only ($30,000): $+([,$replace($hget(pokemon,p_mall),$chr(32),] [),])
      }
    }
    elseif (*day*care* iswm $2-) { choiceadv daycare }
    else { .notice $nick That either isnt a place, or its not done yet, still working on this part }
  }
}
elseif (*move tutor* iswm $2-) { }
elseif (*treasure hunter* iswm $2-) { }
elseif (*trick master* iswm $2-) { }
elseif (*safari hunt* iswm $2-) { }
elseif (*bug c* iswm $2-) { }
elseif (*dojo* iswm $2-) { }
elseif (*gym* iswm $2-) { }

on *:text:!choose*:#:{
  var %a = $p_active($.nick), %p = $pokemon($2-).name, %status = $p_status($.nick)
  if (!%p) { .notice $nick Unrecognized pokemon }
  elseif ($2) {
    if (%status == none) {
      if ($istok(Bulbasaur Charmander Squirtle Pidgey Weedle Pichu Machop Abra Geodude Staryu Chikorita Cyndaquil Totodile Absol,%p,32)) {
        sqlite_begin %pdb
        sqlite_exec %pdb INSERT INTO p_inventory (name, cash, pokeball) VALUES (' $+ $sql_esc($.nick) $+ ', 500, 20)
        sqlite_exec %pdb INSERT INTO p_badges (name) VALUES (' $+ $sql_esc($.nick) $+ ')
        sqlite_exec %pdb INSERT INTO p_pokemon (name) VALUES (' $+ $sql_esc($.nick) $+ ')
        sqlite_exec %pdb INSERT INTO p_tm (name) VALUES (' $+ $sql_esc($.nick) $+ ')
        sqlite_exec %pdb INSERT INTO p_players VALUES (' $+ $sql_esc($.nick) $+ ', $rand(1,65535) , $rand(1,65535) , ' $+ 3 3 $+ ', ' $+ %p $+ ', ' $+ %p $+ ', ' $+ ready $+ ', 0, 0, 0, '', '', 0)
        sqlite_exec %pdb CREATE TABLE $sql_esc($.nick) (pokemon varchar(20), pv varchar(10), ability varchar(20), nature varchar(10), traded varchar(1), item varchar(20), m1 varchar(20), m2 varchar(20), m3 varchar(20), m4 varchar(20), lvl varchar(3), exp varchar(10), hp varchar(4), atk varchar(4), def varchar(4), spatk varchar(4), spdef varchar(4), spd varchar(4), ivhp varchar(2), ivatk varchar(2), ivdef varchar(2), ivspatk varchar(2), ivspdef varchar(2), ivspd varchar(2), evhp varchar(3), evatk varchar(3), evdef varchar(3), evspatk varchar(3), evspdef varchar(3), evspd varchar(3))
        sqlite_commit %pdb
        add_pokemon $.nick $p_gen(%p,1)
        hadd -z pokemon $+($.nick,.travel) 900
        .notice $nick Congrats! You are now a pokemon trainer. %p is now your active pokemon. As you catch more you can change them out with !choose
      }
      else { .notice $nick That isn't a valid option. }
    }
    elseif (%status == ready) {
      if (%a == %p) { .notice $nick %p is already your active pokemon! }
      elseif ($has_pokemon($.nick,%p) != has) { .notice $nick You don't have a %p }
      elseif ($p_stat($.nick,%p).lvl < $p_loc($.nick).lvl) { .notice $nick %p is too weak to be out here. }
      elseif (!$istok($p_team($.nick),%p,124)) { .notice $nick %p isn't in your team! You can change your team with !take and !leave when you are near a Pokecenter. }
      else {
        .notice $nick %p is now your active pokemon.
        p_active $.nick %p
      }
    }
  }
}
on *:text:!take*:#:{
  if ($p_status($.nick) == ready) {
    var %p = $pokemon($2).name, %t = $p_team($.nick)
    if (!%p) { .notice $nick Unrecognized pokemon! }
    elseif (!$istok($p_loc($.nick).npc,Pokecenter,44)) { .notice $nick There isnt a Pokecenter close by! }
    elseif ($numtok(%t,124) >= 6) { .notice $nick Your team is full! You need to !leave one first. }
    elseif ($has_pokemon($.nick,%p) != has) { .notice $nick You don't have a %p $+ ! }
    elseif ($istok(%t,%p,124)) { .notice $nick %p is already in your team! }
    elseif (%p == $p_daycare($.nick)) { .notice $nick %p is in Daycare! }
    else {
      %t = $addtok(%t,%p,124)
      .notice $nick You take %p with you. [Team: $replace(%t,|,$chr(32) - $chr(32)) $+ ]
      p_team $.nick %t
    }
  }
}
on *:text:!leave*:#:{
  if ($p_status($.nick) == ready) {
    var %p = $pokemon($2).name, %t = $p_team($.nick)
    if (!%p) { .notice $nick Unrecognized pokemon! }
    elseif (!$istok($p_loc($.nick).npc,Pokecenter,44)) { .notice $nick There isn't a Pokecenter close by! }
    elseif (!$istok(%t,%p,124)) { .notice $nick %p isn't in your team! }
    elseif (%p == $p_active($.nick)) { .notice $nick You can't leave your active pokemon! }
    else {
      %t = $remtok(%t,%p,1,124)
      .notice $nick You leave %p [Team: $replace(%t,|,$chr(32) - $chr(32)) $+ ]
      p_team $.nick %t
    }
  }
}
on *:text:!team:#:{
  if ($p_status($.nick)) {
    .notice $nick $replace($p_team($.nick),|,$chr(32) - $chr(32))
  }
}
on *:text:!give *:#:{
  if ($p_status($.nick) == ready) {
    var %p = $pokemon($iif($5,$2 $3,$2)).name, %i = $p_item($iif($5,$4-,$iif($p_item($3-).name,$3-,$4-))).name
    if (!%i) { .notice $nick That isn't an item! }
    elseif ($p_item(%i).type != hold) { .notice $nick You can't give that to him! }
    elseif (!%p) { .notice $nick I think you misspelled the pokemon name, or have the name and item in the wrong order. }
    elseif ($has_pokemon($.nick,%p) != has) { .notice $nick You don't have a %p }
    elseif (!$p_item($.nick,%i)) { .notice $nick You don't have a %i }
    else {
      set -l %sql SELECT item FROM $sql_esc($.nick) WHERE pokemon=' $+ $sql_esc(%p) $+ '
      set -l %query $sqlite_query(%pdb,%sql)
      set -l %fetch $sqlite_fetch_row(%query,pitem,$SQLITE_ASSOC)
      sqlite_exec %pdb UPDATE $sql_esc($.nick) SET item=' $+ $sql_esc(%i) $+ ' WHERE pokemon=' $+ $sql_esc(%p) $+ '
      p_item $.nick $sql_esc(%i) -1
      if ($hget(pitem,item)) {
        var %new = $v1
        .notice $nick You exchange %p $+ 's $sql_re(%new) for your %i
        p_item $.nick $sql_esc(%new)
      }
      else { .notice $nick You give the %i to %p }
    }
  }
  sqlite_free %query
}
on $*:text:/^!travel\s(north|south|east|west)/i:#:{
  if ($p_status($.nick) == ready) {
    tokenize 32 $($+($!p_loc($.nick),.,$2),2)
    if ($hget(pokemon,$+($.nick,.travel))) { .notice $nick You cant travel yet, You need to wait $duration($v1) }
    elseif ($p_stat($.nick,$p_active($.nick)).lvl < $p_loc($1,$2).lvl) { .notice $nick You should wait until you are stronger before going to $p_loc($1,$2).name ( $+ $p_loc($1,$2).lvl $+ ) }
    else {
      if ($p_loc($1,$2)) && ($p_loc($.nick) != $1 $2) {
        hadd -z pokemon $+($.nick,.,travel) $iif($p_item($.nick,bicycle),600,900)
        p_loc $.nick $1 $2
        .notice $nick You travel to $p_loc($.nick).name $+ . $iif($p_loc($.nick).npc,Points of interest: [ $+ $replace($v1,$chr(44),] - [) $+ ])
      }
      else { .notice $nick You cant travel there! }
    }
  }
}
on $*:text:/^!(location|map)/i:#:{
  if ($p_status($.nick) == ready) {
    .notice $nick $p_loc($.nick).map
    if ($p_loc($.nick).npc) { .notice $nick Points of interest: [ $+ $replace($p_loc($.nick).npc,$chr(44),] - [) $+ ] }
  }
}
alias p_loc {
  if ($isid) {
    if (!$2) { tokenize 32 $1 }
    if ($1 !isnum) {
      set -l %sql SELECT loc FROM p_players WHERE name=' $+ $sql_esc($1) $+ '
      set -l %query $sqlite_query(%pdb,%sql)
      set -l %fetch $sqlite_fetch_row(%query,loc,$SQLITE_ASSOC)
      sqlite_free %query
      tokenize 32 $hget(loc,loc)
      if ($hget(loc)) { hfree loc }
    }
    var %x = $iif(!$2,$1,$gettok($p_ini(loc,$1),$2,44)), %n = $iif($1 > 1,$gettok($p_ini(loc,$calc($1 - 1)),$2,44),0), %e = $iif($2 < 5,$gettok($p_ini(loc,$1),$calc($2 + 1),44),0), %s = $iif($1 < 5,$gettok($p_ini(loc,$calc($1 + 1)),$2,44),0), %w = $iif($2 > 1,$gettok($p_ini(loc,$1),$calc($2 - 1),44),0)
    if (!%x) { return 0 }
    if ($prop == npc) {
      var %tf = txt/pokemon/loc $+ $ticks, %a
      filter -ffg txt/pokemon/npc.txt %tf /(\x09|\x2C)( %x |\*)(\x09|\x2C)/x
      .fopen locnpc %tf
      while ($fread(locnpc)) { %a = $addtok(%a,$gettok($v1,3,9),44) }
      .fclose locnpc
      .remove %tf
      return %a
    }
    if ($prop == name) { return $p_ini(area,%x) }
    if ($prop == num) { return %x }
    if ($prop == map) { return [Current Location: $p_ini(area,%x) $+ ] $iif(%n,[North: $p_ini(area,%n) $+ ]) $iif(%e,[East: $p_ini(area,%e) $+ ]) $iif(%s,[South: $p_ini(area,%s) $+ ]) $iif(%w,[West: $p_ini(area,%w) $+ ])  }
    if ($prop == lvl) { return $p_ini(level,%x) }
    if ($prop == north) && (%n) { return $calc($1 - 1) $2 }
    if ($prop == east) && (%e) { return $1 $calc($2 + 1) }
    if ($prop == south) && (%s) { return $calc($1 + 1) $2 }
    if ($prop == west) && (%w) { return $1 $calc($2 - 1) }
    if ($prop == rand) {
      var %r = $1 $2 $iif(%n,$chr(44) $calc($1 - 1) $2) $iif(%e,$chr(44) $1 $calc($2 + 1)) $iif(%s,$chr(44) $calc($1 + 1) $2) $iif(%w,$chr(44) $1 $calc($2 - 1))
      return $.rand(%r)
    }
    return $1-
  }
  sqlite_exec %pdb UPDATE p_players SET loc=' $+ $2- $+ ' WHERE name=' $+ $sql_esc($1) $+ '
}
alias pokemon {
  if (!$1) {
    if ($prop) { return }
    return $gettok($read(txt/pokemon/pokemon.txt),2,9)
  }
  var %x = $read(txt/pokemon/pokemon.txt,r,/^\d{3}\x09[^\x09]* $replace($sql_re($1-),$chr(32),\s,$chr(40),.,$chr(41),.) .*\x09/ix)
  if ($prop == num) { return $gettok(%x,1,9) }
  if ($prop == name) { return $gettok(%x,2,9) }
  if ($prop == type) { return $gettok(%x,3,9) }
  if ($prop == hp) { return $gettok(%x,4,9) }
  if ($prop == atk) { return $gettok(%x,5,9) }
  if ($prop == def) { return $gettok(%x,6,9) }
  if ($prop == satk) { return $gettok(%x,7,9) }
  if ($prop == sdef) { return $gettok(%x,8,9) }
  if ($prop == spd) { return $gettok(%x,9,9) }
  if ($prop == total) { return $gettok(%x,10,9) }
  if ($prop == fmt) { return ( $+ $gettok(%x,1,9) $+ ) $gettok(%x,2,9) [Type: $gettok(%x,3,9) $+ ] }
  if (stat* iswm $prop) { return $gettok(%x,3-9,9) }
  else { return %x }
}
alias p_get {
  var %f = txt/pokemon/pget $+ $ticks, %a = $iif($2,$2,$p_loc($.nick).num), %m
  filter -ffg txt/pokemon/area.txt %f /(?<=^|\x2C)( %a )(?=\x2C|\x09)/ix
  var %m = $($str( $+ $!gettok( $+ $!read( $+ %f $+ ),2,9) $!+ $!chr(44) $chr(32) ,$iif($1,$1,1)),2)
  .remove %f
  return %m
}
alias p_rare {
  if ($1) {
    var %x = $pokemon($1-).name
    return $iif($read(txt/pokemon/rare.txt,r,/(\x09 $regescape(%x) )$/ix),$true,$false)
  }
  var %f = txt/pokemon/prare $+ $ticks, %a = $p_loc($.nick).num
  filter -ffg txt/pokemon/rare.txt %f /(?<=^|\x2C)( %a )(?=\x2C|\x09)/ix
  .timerrare 1 1 .remove %f
  return $gettok($read(%f),2,9)
}
alias p_uncom {
  if ($1) {
    var %x = $pokemon($1-).name
    return $iif($read(txt/pokemon/uncommon.txt,w,%x $+ *),$true,$false)
  }
}
alias p_traded {
  set -l %sql SELECT * FROM $sql_esc($1) WHERE pokemon=' $+ $2 $+ '
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,traded,$SQLITE_ASSOC)
  var %x = $iif($hget(traded,traded) == 1,$true,$false)
  sqlite_free %query
  if ($hget(traded)) { hfree traded }
  return %x
}
alias p_exp { return $ceil($calc((7 * $1 ^ 3) / 5)) }
alias p_mexp { return $ceil($calc($iif($p_traded($.nick,%p),1.5,1) * $p_bexp($1).exp * $2 / 7)) }
alias p_+exp {
  sqlite_begin %pdb
  if ($1 == rare candy) {
    var %p = $2, %exp = $calc($p_exp($calc($p_stat($.nick,%p).lvl + 1)) - $p_stat($.nick,%p).exp)
    sqlite_exec %pdb UPDATE $sql_esc($.nick) SET exp=exp+ %exp WHERE pokemon=' $+ $sql_esc(%p) $+ '
  }
  else {
    var %p = $p_active($.nick), %exp = $ceil($calc($iif($p_traded($.nick,%p),1.5,1) * $p_bexp($1).exp * $2 / 7))
    sqlite_exec %pdb UPDATE $sql_esc($.nick) SET exp=exp+ %exp , evhp=evhp+ $p_bexp($1).hp , evatk=evatk+ $p_bexp($1).atk , evdef=evdef+ $p_bexp($1).def , evspatk=evspatk+ $p_bexp($1).spatk , evspdef=evspdef+ $p_bexp($1).spdef , evspd=evspd+ $p_bexp($1).spd WHERE pokemon=' $+ $sql_esc(%p) $+ '
  }
  set -l %sql SELECT * FROM $sql_esc($.nick) WHERE pokemon=' $+ $sql_esc(%p) $+ '
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,pkexp,$SQLITE_ASSOC)
  if ($p_exp($calc($hget(pkexp,lvl) + 1)) <= $hget(pkexp,exp)) && ($hget(pkexp,lvl) < 99) {
    var %lvl = $hget(pkexp,lvl) + 1, %e = $p_path(%p), %n = $gettok(%e,$calc($findtok(%e,%p,1,9) + 1),9)
    if (%lvl >= $p_el(%p)) && (%lvl != 99) && ($has_pokemon($.nick,%n) != has) {
      if (| isin %n) {
        if (%p == Wurmple) { %n = $iif($calc($hget(pkexp,pv) % 10) < 5,Silcoon,Cascoon) }
        elseif ($regex(%p,/^(Silcoon|Cascoon)$/i)) { %n = $iif(%p == Silcoon,Beautifly,Dustox) }
        else {
          var %x = 1, %y = $numtok(%n,124), %a, %s
          while (%x <= %y) {
            var %a = $gettok(%n,%x,124)
            if ($sql_re($hget(pkexp,item)) == $p_ei(%a)) { %s = %a }
            inc %x
          }
          if (!%s) { goto level }
          else { %n = %s }
        }
      }
      elseif ($p_ei(%n)) {
        if ($sql_re($hget(pkexp,item)) != $p_ei(%n)) { goto level }
        else { sqlite_exec %pdb UPDATE $sql_esc($.nick) SET item=' $+ $null $+ ' WHERE pokemon=' $+ $sql_esc(%p) $+ ' }
      }
      var %pstat = $p_stat($.nick,%p), %pv = $hget(pkexp,pv), %ability = $gettok($read(txt/pokemon/abilitylist.txt,w,%n $+ *),2,9), %ability = $iif($numtok(%ability,44) == 2 && $odd(%pv),$gettok(%ability,2,44),$gettok(%ability,1,44))
      %pstat = $puttok(%pstat,%ability,3,9)
      msg $chan %p is Evolving! %p evolved in to %n
      p_team $.nick $reptok($p_team($.nick),%p,%n,1,124)
      sqlite_exec %pdb UPDATE $sql_esc($.nick) SET pokemon=' $+ $sql_esc(%n) $+ ', ability=' $+ $sql_esc(%ability) $+ ' WHERE pokemon=' $+ $sql_esc(%p) $+ '
      sqlite_exec %pdb UPDATE p_pokemon SET $sql_esc(%n) $+ ='1' WHERE name=' $+ $sql_esc($.nick) $+ '
      sqlite_exec %pdb DELETE * FROM $sql_esc($.nick) WHERE pokemon=' $+ $sql_esc(%p) $+ '
      lock_pokemon $.nick %p
      hadd pkexp pokemon %n
      if ($p_active($.nick) == %p) { p_active $.nick %n }
    }
    :level
    var %p = $hget(pkexp,pokemon), %n = $read(txt/pokemon/nature.txt,w,$hget(pkexp,nature) $+ *), %ps = $pokemon($hget(pkexp,pokemon)).stat, %hp = $gettok(%ps,2,9), %atk = $gettok(%ps,3,9), %def = $gettok(%ps,4,9), %spatk = $gettok(%ps,5,9), %spdef = $gettok(%ps,6,9), %spd = $gettok(%ps,7,9)
    var %hp = $iif(%p == Shedinja,1,$calc(($hget(pkexp,ivhp) + (2 * %hp) + ($hget(pkexp,evhp) / 4)) * (%lvl / 100) + 10 + %lvl)), %atk = $calc((($hget(pkexp,ivatk) + (2 * %atk) + ($hget(pkexp,evatk) / 4)) * (%lvl / 100) + 5)), %def = $calc((($hget(pkexp,ivdef) + (2 * %def) + ($hget(pkexp,evdef) / 4)) * (%lvl / 100) + 5)), %spatk = $calc((($hget(pkexp,ivspatk) + (2 * %spatk) + ($hget(pkexp,evspatk) / 4)) * (%lvl / 100) + 5)), %spdef = $calc((($hget(pkexp,ivspdef) + (2 * %spdef) + ($hget(pkexp,evspdef) / 4)) * (%lvl / 100) + 5)), %spd = $calc((($hget(pkexp,ivspd) + (2 * %spd) + ($hget(pkexp,evspd) / 4)) * (%lvl / 100) + 5))
    if ($gettok(%n,2,32)) {
      inc $gettok(%n,2,32) $calc($gettok(%n,2,32) * .1)
      dec $gettok(%n,3,32) $calc($gettok(%n,3,32) * .1)
    }
    msg $chan $sql_re(%p) gained a level ( $+ %lvl $+ ) $+([HP: +,$floor($calc(%hp - $hget(pkexp,hp))),]) $+([ATK: +,$floor($calc(%atk - $hget(pkexp,atk))),]) $+([DEF: +,$floor($calc(%def - $hget(pkexp,def))),]) $+([SP.ATK: +,$floor($calc(%spatk - $hget(pkexp,spatk))),]) $+([SP.DEF: +,$floor($calc(%spdef - $hget(pkexp,spdef))),]) $+([SPD: +,$floor($calc(%spd - $hget(pkexp,spd))),])
    sqlite_exec %pdb UPDATE $sql_esc($.nick) SET lvl=' $+ %lvl $+ ', hp=' $+ $floor(%hp) $+ ', atk=' $+ $floor(%atk) $+ ', def=' $+ $floor(%def) $+ ', spatk=' $+ $floor(%spatk) $+ ', spdef=' $+ $floor(%spdef) $+ ', spd=' $+ $floor(%spd) $+ ' WHERE pokemon=' $+ $sql_esc(%p) $+ '
    var %m1 = $hget(pkexp,m1), %m2 = $hget(pkexp,m2), %m3 = $hget(pkexp,m3), %m4 = $hget(pkexp,m4), %mlist = $+(%m1,$chr(44),%m2,$chr(44),%m3,$chr(44),%m4)
    if ($p_move(%p,%lvl)) {
      var %nm = $v1
      if ($numtok(%mlist,44) < 4) {
        msg $chan $sql_re(%p) learned %nm $+ !
        sqlite_exec %pdb UPDATE $sql_esc($.nick) SET $+(m,$calc($numtok(%mlist,44) + 1)) =' $+ $sql_esc(%nm) $+ ' WHERE pokemon=' $+ $sql_esc(%p) $+ '
      }
      else {
        msg $chan $sql_re(%p wants to learn %nm [Current moves: %m1 $+ $chr(44) %m2 $+ $chr(44) %m3 $+ $chr(44) %m4 $+ ] - Type !forget <name> and !pokemove <name> to see stats.)
        p_mark $.nick $+(%m1,$chr(44),%m2,$chr(44),%m3,$chr(44),%m4,$chr(44),%nm)
        p_status $.nick learn
      }
    }
  }
  sqlite_commit %pdb
  sqlite_free %query
  if ($hget(pkexp)) { hfree pkexp }
  return %exp
}
alias p_+daycare {
  var %p = $p_daycare($1), %cl = $p_stat($1,%p).lvl
  sqlite_exec %pdb UPDATE $sql_esc($1) SET exp=exp+ $cap($calc(%cl * 2),100) WHERE pokemon=' $+ $sql_esc(%p) $+ '
  set -l %sql SELECT * FROM $sql_esc($1) WHERE pokemon=' $+ $sql_esc(%p) $+ '
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,pkexp,$SQLITE_ASSOC)
  if ($p_exp($calc($hget(pkexp,lvl) + 1)) <= $hget(pkexp,exp)) && ($hget(pkexp,lvl) < 99) {
    var %lvl = $hget(pkexp,lvl) + 1, %p = $hget(pkexp,pokemon), %n = $read(txt/pokemon/nature.txt,w,$hget(pkexp,nature) $+ *), %ps = $pokemon($hget(pkexp,pokemon)).stat, %hp = $gettok(%ps,2,9), %atk = $gettok(%ps,3,9), %def = $gettok(%ps,4,9), %spatk = $gettok(%ps,5,9), %spdef = $gettok(%ps,6,9), %spd = $gettok(%ps,7,9)
    var %hp = $iif(%p == Shedinja,1,$calc(($hget(pkexp,ivhp) + (2 * %hp) + ($hget(pkexp,evhp) / 4)) * (%lvl / 100) + 10 + %lvl)), %atk = $calc((($hget(pkexp,ivatk) + (2 * %atk) + ($hget(pkexp,evatk) / 4)) * (%lvl / 100) + 5)), %def = $calc((($hget(pkexp,ivdef) + (2 * %def) + ($hget(pkexp,evdef) / 4)) * (%lvl / 100) + 5)), %spatk = $calc((($hget(pkexp,ivspatk) + (2 * %spatk) + ($hget(pkexp,evspatk) / 4)) * (%lvl / 100) + 5)), %spdef = $calc((($hget(pkexp,ivspdef) + (2 * %spdef) + ($hget(pkexp,evspdef) / 4)) * (%lvl / 100) + 5)), %spd = $calc((($hget(pkexp,ivspd) + (2 * %spd) + ($hget(pkexp,evspd) / 4)) * (%lvl / 100) + 5))
    if ($gettok(%n,2,32)) {
      inc $gettok(%n,2,32) $calc($gettok(%n,2,32) * .1)
      dec $gettok(%n,3,32) $calc($gettok(%n,3,32) * .1)
    }
    sqlite_exec %pdb UPDATE $sql_esc($1) SET lvl=' $+ %lvl $+ ', hp=' $+ $floor(%hp) $+ ', atk=' $+ $floor(%atk) $+ ', def=' $+ $floor(%def) $+ ', spatk=' $+ $floor(%spatk) $+ ', spdef=' $+ $floor(%spdef) $+ ', spd=' $+ $floor(%spd) $+ ' WHERE pokemon=' $+ $sql_esc(%p) $+ '
    p_ps $1 dcl
    if ($p_move(%p,%lvl)) {
      var %m1 = $hget(pkexp,m1), %m2 = $hget(pkexp,m2), %m3 = $hget(pkexp,m3), %m4 = $hget(pkexp,m4), %all = $+(%m1,$chr(9),%m2,$chr(9),%m3,$chr(9),%m4,$chr(9),$p_move(%p,%lvl))
      if ($numtok(%all,9) <= 4) { var %c = $numtok(%all,9), %m = %all $+ $str($chr(9),$calc(4 - %c)) }
      else {
        while ($numtok(%m,9) < 4) { %m = $addtok(%m,$p_movesel($1,%all),9) }
      }
      sqlite_exec %pdb UPDATE $sql_esc($1) SET m1=' $+ $gettok(%m,1,9) $+ ' m2=' $+ $gettok(%m,2,9) $+ ' m3=' $+ $gettok(%m,3,9) $+ ' m4=' $+ $gettok(%m,4,9) $+ ' WHERE pokemon=' $+ $sql_esc(%p) $+ '
    }
  }
  sqlite_commit %pdb
  sqlite_free %query
  if ($hget(pkexp)) { hfree pkexp }
}
on *:text:!forget*:#:{
  if ($p_status($.nick) == learn) || ($p_status($.nick) == tm) {
    var %m = $p_mark($.nick), %x = $iif($p_status($.nick) == tm,$gettok(%m,2,124),$p_mark($.nick)), %p = $iif($p_status($.nick) == tm,$gettok(%m,1,124),$p_active($.nick))
    if ($istok(%x,$pokemove($2-).name,44)) { %x = $remtok(%x,$pokemove($2-).name,1,44)
      .notice $nick %p forgot $pokemove($2-).name $+ . $+([,$gettok(%x,1,44),$chr(44) , $gettok(%x,2,44),$chr(44) , $gettok(%x,3,44),$chr(44) , $gettok(%x,4,44),])
      sqlite_exec %pdb UPDATE $sql_esc($.nick) SET m1=' $+ $sql_esc($gettok(%x,1,44)) $+ ', m2=' $+ $sql_esc($gettok(%x,2,44)) $+ ', m3=' $+ $sql_esc($+ $gettok(%x,3,44)) $+ ', m4=' $+ $sql_esc($gettok(%x,4,44)) $+ ' WHERE pokemon=' $+ %p $+ '
      p_status $.nick ready
    }
    else { .notice $nick That isn't a valid option. }
  }
}
alias p_bexp {
  tokenize 9 $read(txt/pokemon/ev.txt,r,/\x09 $replace($pokemon($1-).name,$chr(32),\s,$chr(40),.,$chr(41),.) \s\x09/xi)
  if ($prop == exp) { return $3 }
  if ($prop == hp) { return $4 }
  if ($prop == atk) { return $5 }
  if ($prop == def) { return $6 }
  if ($prop == spatk) { return $7 }
  if ($prop == spdef) { return $8 }
  if ($prop == spd) { return $9 }
}
alias p_cr {
  var %x = $read(txt/pokemon/cr.txt,w,$pokemon($1).name $+ *)
  return $gettok(%x,2,9)
}
alias p_el {
  if ($1) {
    var %x = $read(txt/pokemon/level.txt,w,$pokemon($1).name $+ *)
    return $iif(%x,$calc($gettok(%x,2,9) + 1),$null)
  }
}
alias p_path {
  var %p = $pokemon($1).name, %x = $read(txt/pokemon/path.txt,w,* $+ %p $+ *), %t = $calc($findtok(%x,%p,1,9) $prop 1)
  if ($prop) { return $gettok(%x,%t,9) }
  return %x
}
alias p_ml {
  if ($1) {
    var %x = $pokemon($1).name, %p = $p_path(%x), %t = $findtok(%p,%x,1,9) - 1
    if (!%p) { return 1 }
    return $iif(%t,$p_el($gettok(%p,%t,9)),1)
  }
}
alias p_ei {
  if ($1) {
    var %x = $pokemon($1).name
    if %x { %x = $read(txt/pokemon/evolve.item.txt,w,%x $+ *) }
    return $iif(%x,$gettok(%x,2,9),$null)
  }
}
alias p_ep {
  var %p = $read(txt/pokemon/path.txt,w,* $+ $pokemon($1).name $+ * )
  return $($regsubex(%p,/([^\|]+?)(\x09)/g,\1->( $!+ $!p_el( $+ \1 $+ ) $!+ $!iif( $!+ $!read(txt/pokemon/evolve.item.txt,w,* $!+ $!p_path( $+ \1 $+ ).+ $!+ *) $!+ ,*) $!+ )->),3)
}
alias p_vs {
  var %x = 1, %a1, %d1, %dam1, %a2, %d2, %dam2, %h, %m, %hp1, %hp2
  var %apm1 = $ceil($calc(($gettok($1,7,9) + 1) ^ .6 + 3)), %apm2 = $ceil($calc(($gettok($2,7,9) + 1) ^ .6 + 3)), %mod1 = $p_type($gettok($1,1,9),$gettok($2,1,9)), %mod2 = $p_type($gettok($2,1,9),$gettok($1,1,9))
  while (%x <= %apm1) {
    var %h = $rand(1,20), %m = $rand(1,20)
    if (%m > %h) || (%h < 3) { dec %apm1 }
    elseif (%h == 20) { inc %apm1 }
    inc %x
  }
  %a1 = $calc($bottom($floor($calc(1 $($str( $!chr(32) + $!chr(32) $!chr(40) $!+ $!gettok($1, $!.rand(3,5).str ,9) ^ . $!+ $!.rand(6,8) $!+ $!chr(41) $!chr(32) ,%apm1),2))),1) * %mod1)
  %d1 = $bottom($floor($calc(1 $($str( $!chr(32) + $!chr(32) $!chr(40) $!+ $!gettok($2, $!.rand(4,6).str ,9) ^ . $!+ $!.rand(2,4) $!+ $!chr(41) $!chr(32) ,%apm1),2))),1)
  %x = 1
  while (%x <= %apm2) {
    var %h = $rand(1,20), %m = $rand(1,20)
    if (%m > %h) || (%h < 3) { dec %apm2 }
    elseif (%h == 20) { inc %apm2 }
    inc %x
  }
  var %a2 = $calc($bottom($floor($calc(1 $($str( $!chr(32) + $!chr(32) $!chr(40) $!+ $!gettok($2, $!.rand(3,5).str ,9) ^ . $!+ $!.rand(6,8) $!+ $!chr(41) $!chr(32) ,%apm2),2))),1) * %mod2)
  var %d2 = $bottom($floor($calc(1 $($str( $!chr(32) + $!chr(32) $!chr(40) $!+ $!gettok($1, $!.rand(4,6).str ,9) ^ . $!+ $!.rand(2,4) $!+ $!chr(41) $!chr(32) ,%apm2),2))),1)
  var %dam1 = $bottom($calc(%a1 - %d1),1), %dam2 = $bottom($calc(%a2 - %d2),1), %hp1 = $calc($gettok($1,2,9) - %dam2), %hp2 = $calc($gettok($2,2,9) - %dam1)
  return $iif(%hp1 > %hp2,1,2)
}
alias p_gen {
  var %x, %y = $lines(txt/pokemon/ev.txt), %p = $pokemon($1).stat, %l = 1, %exp = 1, %pv = $rand(0,4294967295)
  var %hp = $gettok(%p,2,9), %atk = $gettok(%p,3,9), %def = $gettok(%p,4,9), %spatk = $gettok(%p,5,9), %spdef = $gettok(%p,6,9), %spd = $gettok(%p,7,9), %ivhp = $rand(1,32), %ivatk = $rand(1,32), %ivdef = $rand(1,32), %ivspatk = $rand(1,32), %ivspdef = $rand(1,32), %ivspd = $rand(1,32), %evhp = 0, %evatk = 0, %evdef = 0, %evspatk = 0, %evspdef = 0, %evspd = 0
  var %ability = $gettok($read(txt/pokemon/abilitylist.txt,w,$1 $+ *),2,9), %ability = $iif($numtok(%ability,44) == 2 && $odd(%pv),$gettok(%ability,2,44),$gettok(%ability,1,44)), %nature = $read(txt/pokemon/nature.txt,s,$calc(%pv % 25)), %n = $read(txt/pokemon/nature.txt,nw,%nature $+ *)
  .fopen npc txt/pokemon/ev.txt
  while (%l < $2) {
    .fseek -l npc $rand(1,%y)
    %x = $fread(npc)
    inc %exp $floor($calc($gettok(%x,3,9) * %l / 7))
    inc %evhp $gettok(%x,4,9)
    inc %evatk $gettok(%x,5,9)
    inc %evdef $gettok(%x,6,9)
    inc %evspatk $gettok(%x,7,9)
    inc %evspdef $gettok(%x,8,9)
    inc %evspd $gettok(%x,9,9)
    while (%exp > $p_exp($calc(%l + 1))) { inc %l }
  }
  set -l %sql SELECT * FROM p_learnset WHERE name LIKE $+('%,$sql_esc($1),$(%',0))
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,npcmove,$SQLITE_ASSOC)
  var %n = 1, %m, %physical, %status, %special, %all
  while (%n <= $2) {
    if ($hget(npcmove,$+(l,%n))) {
      %m = $hget(npcmove,$+(l,%n))
      %all = $addtok(%all,%m,9)
      var % $+ $pokemove(%m).cat $addtok($($+(%,$pokemove(%m).cat),2),%m,9)
    }
    inc %n
  }
  var %m
  if ($numtok(%all,9) <= 4) { var %c = $numtok(%all,9), %m = %all $+ $str($chr(9),$calc(4 - %c)) }
  else {
    while ($numtok(%m,9) < 4) { %m = $addtok(%m,$p_movesel($1,%all),9) }
  }
  var %hp = $iif($1 == Shedinja,1,$calc((%ivhp + (2 * %hp) + (%evhp / 4)) * (%l / 100) + 10 + %l)), %atk = $calc(((%ivatk + (2 * %atk) + (%evatk / 4)) * (%l / 100) + 5)), %def = $calc(((%ivdef + (2 * %def) + (%evdef / 4)) * (%l / 100) + 5)), %spatk = $calc(((%ivspatk + (2 * %spatk) + (%evspatk / 4)) * (%l / 100) + 5)), %spdef = $calc(((%ivspdef + (2 * %spdef) + (%evspdef / 4)) * (%l / 100) + 5)), %spd = $calc(((%ivspd + (2 * %spd) + (%evspd / 4)) * (%l / 100) + 5))
  if ($gettok(%n,2,32)) {
    inc $gettok(%n,2,32) $calc($gettok(%n,2,32) * .1)
    dec $gettok(%n,3,32) $calc($gettok(%n,3,32) * .1)
  }
  .fclose npc
  sqlite_free %query
  if ($hget(npcmove)) { hfree npcmove }
  return $+($1,$chr(9),%pv,$chr(9),%ability,$chr(9),%nature,$chr(9),0,$chr(9),,$chr(9),%m,$chr(9),%l,$chr(9),%exp,$chr(9),$floor(%hp),$chr(9),$floor(%atk),$chr(9),$floor(%def),$chr(9),$floor(%spatk),$chr(9),$floor(%spdef),$chr(9),$floor(%spd),$chr(9),%ivhp,$chr(9),%ivatk,$chr(9),%ivdef,$chr(9),%ivspatk,$chr(9),%ivspdef,$chr(9),%ivspd,$chr(9),%evhp,$chr(9),%evatk,$chr(9),%evdef,$chr(9),%evspatk,$chr(9),%evspdef,$chr(9),%evspd)
}
alias p_move {
  set -l %sql SELECT l $+ $2 FROM p_learnset WHERE name LIKE $+('%,$sql_esc($1),$(%',0))
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,pkmove,$SQLITE_ASSOC)
  var %x = $hget(pkmove,l $+ $2)
  sqlite_free %query
  if ($hget(pkmove)) { hfree pkmove }
  return $iif(%x,$v1,$null)
}
alias add_pokemon {
  var %x = $replace($sql_esc($2-),$chr(9),' $+ $chr(44) $+ '), %e = $read(txt/pokemon/path.txt,r,/ $gettok($2,1,9) /ix), %n = $findtok(%e,$gettok($2,1,9),1,9), %a = 1, %p
  sqlite_begin %pdb
  if ($has_pokemon($1,$gettok($2-,1,9)) == has) {
    .notice $nick You caught $gettok($2-,1,9) but you already have a $gettok($2-,1,9) $+ ! Do you want to !keep or !release the new one?
    .notice $nick Old: $p_statfmt($1,$p_stat($1,$gettok($2-,1,9)))
    .notice $nick New: $p_statfmt($1,$2-)
    p_mark $1 $replace($2-,$chr(9),*)
    p_status $1 replace
    return
  }
  var %t = $p_team($1)
  if ($numtok(%t,124) < 6) {
    p_team $1 $addtok(%t,$gettok($2,1,9),124)
  }
  noop $p_+exp($gettok($2-,1,9),$gettok($filltok($2-,-,9),11,9))
  sqlite_exec %pdb UPDATE p_pokemon SET $sql_esc($gettok($2-,1,9)) $+ ='1' WHERE name=' $+ $sql_esc($1) $+ '
  sqlite_exec %pdb INSERT INTO $sql_esc($1) VALUES (' $+ %x $+ ')
  sqlite_commit %pdb
}
on *:text:!keep:#:{
  if ($p_status($.nick) == replace) {
    var %x = $p_mark($.nick), %p = $gettok(%x,1,42)
    .notice $nick You keep the new %p and set your old one free.
    p_status $.nick ready
    replace_pokemon $.nick %x
    noop $p_+exp(%p,$gettok($filltok(%x,-,42),11,42))
  }
}
on *:text:!release:#:{
  if ($p_status($.nick) == replace) {
    var %x = $p_mark($.nick), %p = $gettok(%x,1,42)
    .notice $nick You keep your %p and let the new one go.
    p_status $.nick ready
    noop $p_+exp(%p,$gettok($filltok(%x,-,42),11,42))
  }
}
alias replace_pokemon {
  var %p = $gettok($2-,1,42), %x = $replace($sql_esc($2-),$chr(42),' $+ $chr(44) $+ ')
  sqlite_exec %pdb DELETE FROM $sql_esc($1) WHERE pokemon=' $+ $sql_esc(%p) $+ '
  sqlite_exec %pdb INSERT INTO $sql_esc($1) VALUES (' $+ %x $+ ')
}
alias see_pokemon {
  if (!$has_pokemon($1,$2)) {
    sqlite_exec %pdb UPDATE p_pokemon SET $sql_esc($pokemon($2).name) $+ ='s' WHERE name=' $+ $sql_esc($1) $+ '
  }
}
alias lock_pokemon {
  sqlite_exec %pdb UPDATE p_pokemon SET $sql_esc($pokemon($2).name) $+ ='x' WHERE name=' $+ $sql_esc($1) $+ '
}
alias has_pokemon {
  set -l %sql SELECT $sql_esc($2) FROM p_pokemon WHERE name=' $+ $sql_esc($1) $+ '
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,haspkm,$SQLITE_ASSOC)
  sqlite_free %query
  var %x = $replacex($hget(haspkm,$sql_esc($2)),1,has,x,had,s,seen)
  if ($hget(haspkm)) { hfree haspkm }
  return %x
}
alias trade_pokemon { }

on *:text:!buy*:#:{
  if ($p_status($.nick) == ready) {
    var %t = $iif($2 isnum,$3-,$2-), %c
    if (TM* iswm %t) {
      if (!$istok($p_loc($.nick).npc,The Mall,44)) { .notice $nick You aren't near The Mall! }
      else {
        if ($tm(%t).r == 1) {
          %c = $iif($2 isnum,$2,1)
          if ($p_item($.nick,cash) >= $calc(%c * 20000)) {
            .notice $nick You buy $iif($2 isnum,$2 $upper(%t) $+ s,a $upper(%t))
            p_item $.nick %t + $+ %c
            p_item $.nick cash - $+ $calc(20000 * %c)
          }
          else { .notice $nick You don't have enough cash! }
        }
        elseif ($tm(%t).r == 2) {
          var %m = $hget(pokemon,p_mall)
          if (!$istok(%m,$2,32)) { .notice $nick That isn't for sale! }
          elseif ($2 isnum) { .notice $nick We only have 1 $upper($3) in stock. }
          else {
            if ($p_item($.nick,cash) >= 30000) {
              .notice $nick You buy a $upper(%t) $+ .
              p_item $.nick %t +1
              p_item $.nick cash -30000
              %m = $replace(%m,$2,$tm(2))
              hadd pokemon p_mall $dupe(%m)
            }
          }
        }
        else { .notice $nick That isn't for sale! }
      }
    }
    else {
      if (!$istok($p_loc($.nick).npc,Pokemart,44)) { .notice $nick There isn't a Pokemart close by! }
      else {
        if ($regex($2-,/((poke|great|ultra)?\s?ball|revive|(super|hyper|max)?\s?potion|full\srestore|antidote|paralyze\sheal|awakening|burn\sheal|ice\sheal|full\sheal|bicycle)\s?/i)) {
          if (*ball* iswm %t) { %t = $p_cug($.nick).ball }
          if (*potion* iswm %t) { %t = $p_cug($.nick).potion }
          %c = $iif($2 isnum,$calc($p_item(%t).cost * $2),$p_item(%t).cost)
          if ($p_item($.nick,cash) >= %c) {
            if (%t == bicycle) && ($p_item($.nick,bicycle)) { .notice $nick You already have a Bicycle! }
            else {
              .notice $nick You buy $iif($2 isnum,$2 %t $+ s,a %t)
              if (*ball* iswm %t) { p_item $.nick Pokeball $iif($2 isnum,+ $+ $2) }
              elseif (*potion* iswm %t) { p_item $.nick Potion $iif($2 isnum,+ $+ $2) }
              else { p_item $.nick $sql_esc($p_item(%t).name) $iif($2 isnum,+ $+ $2) }
              p_item $.nick cash - $+ %c
            }
          }
          else { .notice $nick You don't have enough cash! ($ $+ $bytes(%c,b) - You have $ $+ $bytes($p_item($.nick,cash),b) $+ ) }
        }
        else { .notice $nick You can't buy that! }
      }
    }
  }
}
on $*:text:/^!upgrade\s(.*)(ball|potion)(.*)/:#:{
  if ($p_status($.nick) == ready) {
    if (!$istok($p_loc($.nick).npc,Pokemart,44)) { .notice $nick There isn't a Pokemart close by! }
    else {
      var %x, %c
      if (*ball* iswm $2) { %x = $p_cug($.nick).ball }
      elseif (*potion* iswm $2) { %x = $p_cug($.nick).potion }
      %c = $calc($p_iug(%x).cost + $p_item($.nick,$iif(*ball* iswm $2,pokeball,potion)) * $p_item($iif(*ball* iswm $2,pokeball,potion)).cost)
      if ($p_iug(%x)) {
        if ($p_item($.nick,cash) >= %c) {
          p_item $.nick $sql_esc($p_iug(%x))
          p_item $.nick cash - $+ %c
          .notice $nick You upgrade your %x to $p_iug(%x)
        }
        else { .notice $nick you don't have enough cash! ($ $+ $bytes(%c,b) - You have $ $+ $bytes($p_item($.nick,cash),b) $+ ) }
      }
      else { .notice $nick You can't upgrade that! }
    }
  }
}
on *:text:!sell*:#:{
  if ($p_status($.nick) == ready) {
    if (!$istok($p_loc($.nick).npc,Pokemart,44)) { .notice $nick There isn't a Pokemart close by! }
    else {
      var %i = $p_item($iif($2 isnum,$3-,$2-)).name, %n = $iif($2 isnum,$2,1), %c = $calc(($p_item(%i).cost * $iif(TM* iswm %i,5000,.1)) * %n)
      if (!%i) || (!%c) { notice $nick You can't sell that! }
      elseif ($p_item($.nick,%i) >= %n) {
        .notice $nick You sell %n %i $+ $iif(%n > 1,$+ 's) for $ $+ %c $+ .
        p_item $.nick $sql_esc(%i) - $+ %n
        p_item $.nick cash + $+ %c
      }
      else { .notice $nick You don't have that many! }
    }
  }
}
on *:text:!inventory*:#:{
  if ($p_status($.nick) == ready) {
    if ($regex($2,/(T|H)Ms?/i)) {
      set -l %sql SELECT * FROM p_tm WHERE name=' $+ $sql_esc($.nick) $+ '
      set -l %query $sqlite_query(%pdb,%sql)
      set -l %fetch $sqlite_fetch_row(%query,pinv,$SQLITE_ASSOC)
      sqlite_free %query
      var %x = 1, %y = $hget(pinv,0).item, %m, %t
      while (%x <= %y) {
        if ($hget(pinv,%x).item != name) && ($hget(pinv,$hget(pinv,%x).item)) { %m = $addtok(%m,$chr(32) $hget(pinv,%x).item ( $+ $v1 $+ ) $chr(32),45) }
        if ($numtok(%m,45) > 9) {
          .notice $nick $sql_re(%m)
          %m = $null
          inc %t
        }
        inc %x
      }
      if (%m) { .notice $nick $sql_re(%m) }
      elseif (!%t) { .notice $nick You don't have any TM's. }
    }
    else {
      set -l %sql SELECT * FROM p_inventory WHERE name=' $+ $sql_esc($.nick) $+ '
      set -l %query $sqlite_query(%pdb,%sql)
      set -l %fetch $sqlite_fetch_row(%query,pinv,$SQLITE_ASSOC)
      sqlite_free %query
      if (!$2) {
        .notice $nick Cash $ $+ $bytes($hget(pinv,cash),b) - $p_cug($.nick).ball ( $+ $hget(pinv,pokeball) $+ ) - $p_cug($.nick).potion ( $+ $hget(pinv,potion) $+ )
        .notice $nick Revive ( $+ $hget(pinv,Revive) $+ ) - Antidote ( $+ $hget(pinv,Antidote) $+ ) - Paralyze heal ( $+ $hget(pinv,Paralyze_32heal) $+ ) - Awakening ( $+ $hget(pinv,Awakening) $+ ) - Burn heal ( $+ $hget(pinv,Burn_32heal) $+ ) - Ice heal ( $+ $hget(pinv,Ice_32heal) $+ ) - Full heal ( $+ $hget(pinv,Full_32heal) $+ ) - Full restore ( $+ $hget(pinv,Full_32restore) $+ )
        var %m = $iif($hget(pinv,bicycle),Bicycle ( $+ $v1 $+ ) ) $iif($hget(pinv,Masterball),Masterball ( $+ $v1 $+ ) ) $iif($hget(pinv,Rare_32candy),Rare Candy ( $+ $v1 $+ ) ) $iif($hget(pinv,Gold_32Nugget),Gold Nugget ( $+ $v1 $+ ) )
        if (%m) { .notice $nick $regsubex(%m,/(\x29)\s(.)/g,\1 - \2) }
      }
      else {
        var %x = 1, %n, %m, %i
        if (*ball* iswm $2) { %i = Pokeball,Masterball }
        if (* $+ $2 $+ * iswm *equipment*hold*) { %i = Thunder_32stone,Fire_32stone,Water_32stone,Leaf_32stone,Sun_32stone,Moon_32stone,Oval_32stone,Dusk_32stone,Dawn_32stone,Shiny_32stone,Dragon_32scale,Metal_32coat,King_39s_32Rock,Attack_32up,Defense_32up,Special_32up,Black_32belt,BlackGlasses,Magnet,Spell_32tag,Poison_32Barb,Sharp_32beak,Silk_32Scarf,SilverPowder,Soft_32Sand,TwistedSpoon,NeverMeltIce,Hard_32Stone,Leftovers,Shell_32Bell,Muscle_32band,Scope_32lens,Wide_32lens,Wise_32Glasses,Quick_32claw,Amulet_32Coin }
        elseif (spec* iswm $2) { %i = Bicycle,Rare_32candy,Gold_32nugget,Blue_32shard,Red_32shard,Yellow_32shard,Green_32shard,Black_32Apricorn,White_32Apricorn,Blue_32Apricorn,Green_32Apricorn,Yellow_32Apricorn,Red_32Apricorn }
        while (%x <= $numtok(%i,44)) {
          %n = $gettok(%i,%x,44)
          if ($hget(pinv,%n)) { %m = $addtok(%m,$chr(32) $iif(%n == Pokeball,$p_cug($.nick).ball,%n) ( $+ $hget(pinv,%n) $+ ) $chr(32),45) }
          if ($numtok(%m,45) > 7) {
            .notice $nick $sql_re(%m)
            %m = $null
          }
          inc %x
        }
        if (%m) { .notice $nick $sql_re(%m) }
      }
    }
  }
}
on *:text:!use*:#:{
  if ($p_status($.nick) == ready) {
    var %p = $pokemon($iif($4,$4-,$3-)).name, %i = $p_item($iif($4,$iif($p_item($2 $3).name,$2 $3,$2),$2)).name
    if (!%p) { .notice $nick That isn't a pokemon! }
    elseif (!%i) { .notice $nick That isn't an item! }
    elseif ($p_item($.nick,%i) < 1) { .notice $nick You don't have a %i $+ ! }
    elseif ($has_pokemon($.nick,%p) != has) { .notice $nick You don't have a %p $+ ! }
    else {
      if (%i == rare candy) {
        noop $p_+exp(rare candy,%p)
        p_item $.nick Rare_32candy -1
      }
      elseif ($regex($2,/(T|H)M\d\d/i)) {
        if (%i !isin $read(txt/pokemon/tmcom.txt,w,%p $+ *)) { .notice $nick %p can't learn that! }
        else {
          set -l %sql SELECT * FROM $sql_esc($.nick) WHERE pokemon=' $+ $sql_esc(%p) $+ '
          set -l %query $sqlite_query(%pdb,%sql)
          set -l %fetch $sqlite_fetch_row(%query,pkexp,$SQLITE_ASSOC)
          var %m1 = $hget(pkexp,m1), %m2 = $hget(pkexp,m2), %m3 = $hget(pkexp,m3), %m4 = $hget(pkexp,m4), %mlist = $+(%m1,$chr(44),%m2,$chr(44),%m3,$chr(44),%m4)
          var %nm = $tm(%i)
          if ($istok($sql_re(%mlist),%nm,44)) { .notice $nick %p already knows that move! }
          else {
            p_item $.nick %i -1
            if ($numtok(%mlist,44) < 4) {
              msg $chan $sql_re(%p) learned %nm $+ !
              sqlite_exec %pdb UPDATE $sql_esc($.nick) SET $+(m,$calc($numtok(%mlist,44) + 1)) =' $+ $sql_esc(%nm) $+ ' WHERE pokemon=' $+ $sql_esc(%p) $+ '
            }
            else {
              msg $chan $sql_re(%p wants to learn %nm [Current moves: %m1 $+ $chr(44) %m2 $+ $chr(44) %m3 $+ $chr(44) %m4 $+ ] - Type !forget <name> and !pokemove <name> to see stats.)
              p_mark $.nick $+(%p,|,%m1,$chr(44),%m2,$chr(44),%m3,$chr(44),%m4,$chr(44),%nm)
              p_status $.nick tm
            }
          }
        }
      }
      else { .notice $nick That doesn't do anything }
    }
  }
}
on *:text:!pokeitem*:#:{
  if ($p_item($2-).name) {
    tokenize 9 $p_item($2-).desc
    msg $chan $1 [Type: $2 $+ ] $6
  }
}
alias p_getitem {
  set -l %sql SELECT name FROM p_items WHERE type LIKE $+('%,$1,$(%',0)) ORDER BY RANDOM() LIMIT 1
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,pgitem,$SQLITE_ASSOC)
  sqlite_free %query
  var %x = $sql_re($hget(pgitem,name))
  if ($hget(pgitem)) { hfree pgitem }
  return %x
}
alias p_item {
  var %t = $iif($regex($2,/^(T|H)M/i),p_tm,p_inventory), %f = $iif($regex($1,/^(T|H)M/i),txt/pokemon/tms.txt,txt/pokemon/items.txt)
  if ($isid) {
    if ($prop == name) { return $gettok($read(%f,w,* $+ $1 $+ *),1,9) }
    if ($prop == type) { return $gettok($read(txt/pokemon/items.txt,w,* $+ $1 $+ *),2,9) }
    if ($prop == cost) { return $gettok($read(%f,w,* $+ $1 $+ *),3,9) }
    if ($prop == desc) { return $read(txt/pokemon/items.txt,w,* $+ $1 $+ *) }
    set -l %sql SELECT $sql_esc($2) FROM %t WHERE name=' $+ $sql_esc($1) $+ '
    set -l %query $sqlite_query(%pdb,%sql)
    set -l %fetch $sqlite_fetch_row(%query,pitem,$SQLITE_ASSOC)
    sqlite_free %query
    var %x = $hget(pitem,$sql_esc($2))
    if ($hget(pitem)) { hfree pitem }
    return %x
  }
  sqlite_exec %pdb UPDATE %t SET $sql_esc($2) $+ = $sql_esc($2) $iif($3,$3,+1) WHERE name=' $+ $sql_esc($1) $+ '
}
alias p_iug {
  if ($prop == cost) { var %x = $replacex($1,Pokeball,10000,Greatball,20000,Potion,5000,Super Potion,25000,Hyper Potion,50000) }
  else { var %x = $replacex($1,Pokeball,Greatball,Greatball,Ultraball,Ultraball,$null,Potion,Super Potion,Super Potion,Hyper Potion,Hyper Potion,Max Potion,Max Potion,$null) }
  return %x
}
alias p_cug {
  set -l %sql SELECT * FROM p_inventory WHERE name=' $+ $sql_esc($1) $+ '
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,pcug,$SQLITE_ASSOC)
  var %x = $iif($prop == ball,Pokeball,Potion)
  while ($hget(pcug,$sql_esc($p_iug(%x)))) { %x = $p_iug(%x) }
  if ($hget(pcug)) { hfree pcug }
  sqlite_free %query
  return %x
}
alias p_bmod {
  set -l %sql SELECT mod FROM p_items WHERE name=" $+ $sql_esc($1) $+ "
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,pbmod,$SQLITE_ASSOC)
  var %x = $hget(pbmod,mod)
  if ($hget(pcug)) { hfree pcug }
  sqlite_free %quest
  return %x
}
alias p_type {
  if (/ isin $1) { return $max($p_typex($gettok($1,1,47),$2),$p_typex($gettok($1,2,47),$2)) }
  else { return $p_typex($1,$2) }
}
alias p_typex {
  set -l %sql SELECT * FROM p_types WHERE type=' $+ $1 $+ ' COLLATE NOCASE
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_row(%query,ptype,$SQLITE_ASSOC)
  sqlite_free %query
  tokenize 47 $2
  if ($2) {
    var %x = $calc($hget(ptype,$1) + $hget(ptype,$2))
    return $replacex(%x,2,0,3,0,5,0,9,0,4,.25,6,.5,10,1,8,1,12,2,16,4)
  }
  else { return $replacex($hget(ptype,$1),1,0,2,.5,4,1,8,2)  }
}
on *:text:!pokemon*:#:{
  var %a
  if ($2 isnum) { set -l %sql SELECT pokemon, lvl, pv FROM $sql_esc($.nick) WHERE lvl BETWEEN $2 AND 99 ORDER BY lvl ASC }
  else { set -l %sql SELECT pokemon, lvl, pv FROM $sql_esc($.nick) ORDER BY lvl ASC }
  set -l %query $sqlite_query(%pdb,%sql)
  while ($sqlite_fetch_row(%query,listp,$SQLITE_ASSOC)) {
    whilefix
    if ($2 isnum) {
      if ($hget(listp,lvl) > 9) {  %a = $addtok(%a,$p_shiny($.nick,$hget(listp,pv)) $sql_re($hget(listp,pokemon) $iif($p_rare($hget(listp,pokemon)),[Rare]) $+ $iif($p_uncom($hget(listp,pokemon)),[Uncommon]) ( $+ $hget(listp,lvl) $+ )),44) }
    }
    else { %a = $addtok(%a,$p_shiny($.nick,$hget(listp,pv)) $sql_re($hget(listp,pokemon) $iif($p_rare($hget(listp,pokemon)),[Rare]) $+ $iif($p_uncom($hget(listp,pokemon)),[Uncommon]) ( $+ $hget(listp,lvl) $+ )),44) }
    if ($numtok(%a,44) > 24) {
      .notice $nick %a
      %a = $null
    }
  }
  if (%a) { .notice $nick %a }
  sqlite_free %query
}
on $*:text:/^!(poke)?dex(stat)?\s/i:#:{
  var %x = $pokemon($2-), %a = $replace($gettok($read(txt/pokemon/abilitylist.txt,w,$pokemon($2-).name $+ *),2,9),$chr(44),/), %e = $p_ep($pokemon($2-).name), %l = $regsubex($($regsubex($gettok($read(txt/pokemon/area.txt,w,* $+ $pokemon($2-).name),1,9),/(\d+)/g,$!p_loc( $+ \1 $+ ).name $!+ $!chr(44)),2),/(\x2C$)/,)
  if (%x) {
    msg $chan $iif($p_rare($2-),[Rare]) $iif($p_uncom($2-),[Uncommon]) $pokemon($2-).fmt [Height: $p_height($2-) $+ ] [Weight: $p_weight($2-) $+ ] [Ability: %a $+ ] [Evolution: $iif(%e,%e,Does not evolve) $+ ] $iif($has_pokemon($.nick,$2-),[Locations: %l $+ ])
    if (*stat* iswm $1) { msg $chan $pokemon($2-).name Base stats - [HP: $gettok(%x,4,9) Atk: $gettok(%x,5,9) Def: $gettok(%x,6,9) Sp.Atk: $gettok(%x,7,9) Sp.Def: $gettok(%x,8,9) Spd: $gettok(%x,9,9) $+ ]  }
  }
}
on *:text:!pokestat*:#:{
  if ($p_status($.nick)) {
    if ($2) && ($has_pokemon($.nick,$2-) != has) { .notice $nick You don't have a $2- $+ , $.nick $+ . }
    else { msg $chan $p_statfmt($.nick,$p_stat($.nick,$iif($2-,$pokemon($2-).name,$p_active($.nick)))) }
  }
}
alias p_statfmt {
  tokenize 9 $1 $+ $chr(9) $+ $sql_re($filltok($replace($2,*,$chr(9)),-,9))
  return $p_shiny($1,$3) $2 ( $+ $12 $+ ) $iif($p_gender($2,$3),$+([,$v1,])) [Exp: $13 $+ / $+ $p_exp($calc($12 + 1)) $+ ] [Type: $pokemon($2).type $+ ] [Nature: $5 $+ ] [Ability: $4 $+ ] [HP: $14 $+ ] [Atk: $15 $+ ] [Def: $16 $+ ] [Sp.Atk: $17 $+ ] [Sp.Def: $18 $+ ] [Spd: $19 $+ ] [Attacks: $8 $+ $iif($9 != -,$chr(44) $9) $+ $iif($10 != -,$chr(44) $10,) $+ $iif($11 != -,$chr(44) $11) $+ ] $iif($7 != -,[Holding: $sql_re($7) $+ ])
}
alias p_stat {
  var %x = $pokemon($2).name, %t = txt/pokemon/pstat $+ $ticks
  set -l %sql SELECT * FROM $sql_esc($1) WHERE pokemon=' $+ $sql_esc(%x) $+ '
  set -l %query $sqlite_query(%pdb,%sql)
  set -l %fetch $sqlite_fetch_all(%query,%t)
  if (!%fetch) { return error %sqlite_errstr }
  sqlite_free %query
  .timer 1 1 .remove %t
  %x = $filltok($read(%t,1),-,9)
  if ($prop == lvl) { return $gettok(%x,11,9) }
  if ($prop == exp) { return $gettok(%x,12,9) }
  if ($prop == vs) { return $pokemon($gettok(%x,1,9)).type $+ $chr(9) $+ $gettok(%x,13-18,9) }
  return %x
}
on *:text:!pokemove*:#:{
  tokenize 44 $replace($regsubex($2-,/\x2C(\s)/x,$chr(44)),*,.+?)
  if ($len($1) >= 3) {
    filter -cffg txt/pokemon/attacks.txt txt/pokemon/temp.txt /^[^\x09]*( $regsubex($1,/(\s)/g,.*) )(.+?)/ix
    if ($len($2) >= 3) { filter -ffg txt/pokemon/attacks.txt txt/pokemon/temp.txt /^[^\x09]*( $regsubex($2,/(\s)/g,.*) )(.+?)/ix }
    if ($len($3) >= 3) { filter -ffg txt/pokemon/attacks.txt txt/pokemon/temp.txt /^[^\x09]*( $regsubex($3,/(\s)/g,.*) )(.+?)/ix }
    if ($len($4) >= 3) { filter -ffg txt/pokemon/attacks.txt txt/pokemon/temp.txt /^[^\x09]*( $regsubex($4,/(\s)/g,.*) )(.+?)/ix }
    .fopen pmove txt/pokemon/temp.txt
    while ($fread(pmove)) {
      var %x = $v1
      msg $chan $iif($read(txt/pokemon/tms.txt,w,* $+ $gettok(%x,1,9) $+ *),( $+ $gettok($v1,1,9) $+ ) ) $pokemove(%x)
    }
    .fclose pmove
  }
}
alias pokemove {
  if ($2) { var %t = $2 }
  if ($prop == priority) { return $iif($read(txt/pokemon/priority.txt,r,/(^ $replace($1,$chr(32),\s) \x09)/ix),$gettok($v1,2,9),0) }
  if ($prop == stats) { return $read(txt/pokemon/attacks.txt,w,$sql_re($1) $+ *) }
  tokenize 9 $read(txt/pokemon/attacks.txt,w,$sql_re($1) $+ *)
  if ($prop == name) { return $1 }
  if ($prop == type) { return $2 }
  if (cat* iswm $prop) { return $3 }
  if ($prop == power) { return $4 }
  if (acc* iswm $prop) { return $5 }
  if ($prop == pp) { return $6 }
  if ($prop == effect) { return $7 }
  if (prob* iswm $prop) { return $8 }
  if ($prop == rating) {
    return $calc(((3 + $rand(1,3) - $rand(1,3)) + ($replace($3,status,1,physical,1.5,special,2) * $+(1.,$rand(0,5))) + (((50 - $6) * .1) + $rand(1,5) - $rand(1,5)) $iif($4 != -,+ ($+(.,$rand(1,2)) * $4)) $iif($5 != -,+ ($+(.,$rand(1,15)) * $5)) $iif($8 != -,+ ($8 * .1))) $iif($2 isin %t,* 1.5))
  }
  if ($1) {
    return $1 [Type: $2 $+ ] [Category: $3 $+ ] $iif($4 != -,[Power: $4 $+ ]) $iif($5 != -,[Accuracy: $5 $+ ]) [PP: $6 $+ ] $iif($7 != -,[Effect: $iif($8 != -,$8 $+ % chance -) $7 $+ ])
  }
}
alias p_movesel {
  var %x = 1, %y = $numtok($2-,9), %t = $pokemon($1).type, %a, %cr, %m, %r = 0
  while (%x <= %y) {
    %a = $gettok($2-,%x,9)
    %cr = $pokemove(%a,%t).rating
    if (%cr > %r) { var %m = %a, %r = %cr }
    inc %x
  }
  return %m
}
on $*:text:/^!((T|H)M\d\d)(\slist)?$/i:#:{
  if ($2 == list) {
    var %a
    filter -cff txt/pokemon/tmcom.txt txt/pokemon/temp.txt * $+ $regml(1) $+ *
    .fopen tmcom txt/pokemon/temp.txt
    while ($fread(tmcom)) {
      %a = $addtok(%a,$gettok($v1,1,9),44)
      if ($numtok(%a,44) > 14) {
        msg $chan %a
        %a = $null
      }
    }
    .fclose tmcom
    if (%a) { msg $chan %a }
  }
  else { msg $chan ( $+ $upper($regml(1)) $+ ) $pokemove($tm($regml(1))) }
}
alias tm {
  if ($1 isnum 1-3) {
    var %f = txt/pokemon/tm $+ $ticks, %a
    filter -ffg txt/pokemon/tms.txt %f /\x09( $1 )$/x
    %a = $read(%f)
    .remove %f
    return $gettok(%a,1,9)
  }
  tokenize 9 $read(txt/pokemon/tms.txt,w,$1 $+ *)
  if ($prop == r) { return $3 }
  if ($1) { return $2 }
}
on *:text:!ability*:#:{
  tokenize 9 $read(txt/pokemon/ability.txt,w,$2- $+ *)
  if ($1) { msg $chan $1 $+ : $2 }
}
on *:text:!nature*:#:{
  var %x = $replace($read(txt/pokemon/nature.txt,wn,$2- $+ *),%,$null)
  if (%x) {
    tokenize 32 %x
    msg $chan $1 $+ : $iif($2,+ $+ $2 - $+ $3,No effect)
  }
  else {
    var %a, %n = $2
    filter -cffg txt/pokemon/nature.txt txt/pokemon/temp.txt /\s% $2 \s/ix
    .fopen nature txt/pokemon/temp.txt
    while ($fread(nature)) {
      tokenize 32 $remove($v1,%)
      %a = $addtok(%a,$chr(32) $1 $+ : - $+ $3,44)
    }
    .fclose nature
    msg $chan + $+ $upper($2) natures: %a
  }
}
alias p_shiny {
  if (!$3) {
    set -l %sql SELECT id, sid FROM p_players WHERE name=" $+ $sql_esc($1) $+ "
    set -l %query $sqlite_query(%pdb,%sql)
    set -l %fetch $sqlite_fetch_row(%query,pshiny,$SQLITE_ASSOC)
    tokenize 32 $hget(pshiny,id) $hget(pshiny,sid) $2
  }
  var %x = $xor($xor($1,$2),$xor($base($left($base($3,10,2),16),2,10),$base($right($base($3,10,2),16),2,10)))
  if (%x < 8) { msg #Flip shiny! }
  return $iif(%x < 8,Shiny)
}
alias p_gender {
  var %x = $right($base($2,10,2),8), %t = $gettok($read(txt/pokemon/gender.txt,w,$1 $+ *),2,9)
  if (%t != 11111111) { return $iif(%x >= %t,Male,Female) }
}
alias p_height {
  noop $read(txt/pokemon/height.txt,w,* $+ $1- $+ *)
  return $gettok($read(txt/pokemon/height.txt,$readn),1,9)
}
alias p_weight { return $gettok($read(txt/pokemon/weight.txt,w,$1- $+ *),2,9) }
alias p_active {
  if ($isid) { return $p_player($1,active) }
  sqlite_exec %pdb UPDATE p_players SET active=' $+ $sql_esc($2-) $+ ' WHERE name=' $+ $sql_esc($1) $+ '
}
alias p_team {
  if ($isid) { return $p_player($1,team) }
  sqlite_exec %pdb UPDATE p_players SET team=' $+ $sql_esc($2-) $+ ' WHERE name=' $+ $sql_esc($1) $+ '
}
alias p_status {
  if ($isid) { return $p_player($1,status) }
  sqlite_exec %pdb UPDATE p_players SET status=' $+ $sql_esc($2) $+ ' WHERE name=' $+ $sql_esc($1) $+ '
}
alias p_mark {
  if ($isid) { return $p_player($1,mark) }
  sqlite_exec %pdb UPDATE p_players SET mark=' $+ $sql_esc($2-) $+ ' WHERE name=' $+ $sql_esc($1) $+ '
}
alias p_daycare {
  if ($isid) { return $p_player($1,daycare) }
  sqlite_exec %pdb UPDATE p_players SET daycare=' $+ $sql_esc($2-) $+ ' WHERE name=' $+ $sql_esc($1) $+ '
}
alias p_ps {
  if ($isid) { return $p_player($1,$2) }
  sqlite_exec %pdb UPDATE p_players SET $2 = $2 + 1 WHERE name=' $+ $sql_esc($1) $+ '
}
alias p_player {
  if ($isid) {
    set -l %sql SELECT $2 FROM p_players WHERE name=' $+ $sql_esc($1) $+ '
    set -l %query $sqlite_query(%pdb,%sql)
    set -l %fetch $sqlite_fetch_row(%query,player,$SQLITE_ASSOC)
    var %x = $iif($sql_re($hget(player,$2)),$v1,none)
    sqlite_free %query
    if ($hget(player)) { hfree player }
    return %x
  }
  else { sqlite_exec %pdb UPDATE p_players SET $2 =' $+ $sql_esc($3) $+ ' WHERE name=' $+ $sql_esc($1) $+ ' }
}
alias p_noncom { return $p_ini(cr,$1) }
alias p_ini {
  if ($isid) { return $readini(txt/pokemon/pokemon.ini,$1,$2) }
  else { writeini txt/pokemon/pokemon.ini $1 $2 $3 }
}
on *:text:*:#:{
  if ($p_status($.nick) == choiceadv) && ($regex($1-,/^( $gettok($p_mark($.nick),1,42) )$/ix)) {
    var %m = $p_mark($.nick), %adv = $gettok(%m,2,42)
    if ($1 == leave) {
      msg $chan $nick $+ : You decide to leave and continue exploring.
      p_status $.nick ready
    }
    elseif (%adv isnum 11-30) || (%adv isnum 36-37) {
      var %i = $gettok(%m,3,42), %c = $gettok(%m,4,42)
      if ($1 == buy) {
        if ($p_item($.nick,cash) >= %c) {
          msg $chan $nick $+ : You buy the %i and continue on your journey.
          p_item $.nick $sql_esc(%i) +1
          p_item $.nick cash - $+ %c
          p_status $.nick ready
        }
        else { msg $chan $nick $+ : You don't have enough cash, so you continue on your journey. }
        p_status $.nick ready
      }
    }
    elseif (%adv == 38) {
      var %c = $gettok(%m,3,42)
      if ($p_item($.nick,cash) > %c) {
        msg $chan $nick $+ : You buy the $upper($1) and continue on your journey.
        p_item $.nick $upper($1) +1
        p_item $.nick cash - $+ %c
      }
      else { msg $chan $nick $+ : You don't have enough cash, so you continue on your journey. }
      p_status $.nick ready
    }
    elseif (%adv == daycare) {
      var %t = $p_team($.nick)
      if ($1 == yes) {
        if ($numtok(%t,124) < 6) {
          var %dcl = $calc($p_player($.nick,dcl) * 1000)
          if ($p_item($.nick,cash) < %dcl) { .notice $nick You don't have enough to pay The Daycare lady! }
          else {
            .notice $nick You take $p_daycare($.nick) with you.
            p_team $.nick $addtok(%t,$p_daycare($.nick),124)
            p_player $.nick dcl 0
            p_item $.nick cash - $+ %dcl
            p_daycare $.nick
          }
        }
        else { .notice $nick You don't have room in your team! }
      }
      elseif ($1 == no) { .notice $nick You leave The Daycare lady's house. }
      else {
        .notice $nick You let $1 stay with The daycare lady.
        p_team $.nick $remtok(%t,$1,1,124)
        p_daycare $.nick $pokemon($1).name
        if ($1 == $p_active($.nick)) { p_active $.nick $gettok($p_team($.nick),1,124) }
      }
      p_status $.nick ready
    }
  }
}
#pokemon end
alias p_reset {
  var %x = $iif($.nick($1).check,$.nick($1),$1)
  sqlite_exec %pdb DELETE FROM p_pokemon WHERE name=' $+ $sql_esc(%x) $+ '
  sqlite_exec %pdb DELETE FROM p_players WHERE name=' $+ $sql_esc(%x) $+ '
  sqlite_exec %pdb DELETE FROM p_inventory WHERE name=' $+ $sql_esc(%x) $+ '
  sqlite_exec %pdb DELETE FROM p_badges WHERE name=' $+ $sql_esc(%x) $+ '
  sqlite_exec %pdb DROP TABLE $sql_esc(%x)
  msg $chan %x reset
}
alias db_additem {
  var %a = $read(txt/pokemon/items.txt,w,$1- $+ *)
  sqlite_exec %pdb ALTER TABLE p_inventory ADD $sql_esc($1-) varchar(3) default 0
  sqlite_exec %pdb INSERT INTO p_items VALUES (' $+ $replace($filltok($sql_esc(%a),-,9),$chr(9),' $+ $chr(44) $+ ') $+ ')
}
alias db_flushitems {
  sqlite_exec %pdb DROP TABLE p_items
  sqlite_exec %pdb CREATE TABLE p_items (name varchar(20), type varchar(20), cost varchar(10), mod varchar(10), effect varchar(15), desc varchar(200))
  var %x = 1, %y = $lines(txt/pokemon/items.txt), %a
  while (%x <= %y) {
    %a = $read(txt/pokemon/items.txt,%x)
    sqlite_exec %pdb INSERT INTO p_items VALUES (' $+ $replace($filltok($sql_esc(%a),-,9),$chr(9),' $+ $chr(44) $+ ') $+ ')
    inc %x
  }
}
alias _pdb {
  sqlite_exec %pdb CREATE TABLE p_types (type varchar(8),Normal varchar(2),Fighting varchar(2),Flying varchar(2),Poison varchar(2),Ground varchar(2),Rock varchar(2),Bug varchar(2),Ghost varchar(2),Steel varchar(2),Fire varchar(2),Water varchar(2),Grass varchar(2),Electric varchar(2),Psychic varchar(2),Ice varchar(2),Dragon varchar(2),Dark varchar(2))
  var %x = 2, %y = $lines(txt/pokemon/resource/chart.txt), %a
  while (%x <= %y) {
    var -s %a = $replace($read(txt/pokemon/resource/chart.txt,%x),;,' $+ $chr(44) $+ ')
    sqlite_exec %pdb INSERT INTO p_types VALUES (' $+ %a $+ ')
    inc %x
  }

}
alias gendb {
  var %sql.db = $sqlite_open(txt/pokemon/pokemon.new.db3)
  sqlite_begin %sql.db
  sqlite_exec %sql.db CREATE TABLE p_players (name varchar(20), id varcahr(6), sid varchar(6), loc varchar(5), active varchar(20), team varchar(150), status varchar(10), attempts varchar(7), battles varchar(3), wins varchar(7), mark varchar(250), daycare varchar(20))
  sqlite_exec %sql.db CREATE TABLE p_badges (name varchar(20))
  sqlite_exec %sql.db CREATE TABLE p_pokemon (name varchar(20))
  var %x = 1, %y = $lines(txt/pokemon/pokemon.txt), %a
  while (%x <= %y) {
    %a = $gettok($read(txt/pokemon/pokemon.txt,%x),2,9)
    sqlite_exec %sql.db ALTER TABLE p_pokemon ADD $sql_esc(%a) char(1)
    inc %x
  }
  sqlite_exec %sql.db CREATE TABLE p_types (type varchar(8),Normal varchar(2),Fighting varchar(2),Flying varchar(2),Poison varchar(2),Ground varchar(2),Rock varchar(2),Bug varchar(2),Ghost varchar(2),Steel varchar(2),Fire varchar(2),Water varchar(2),Grass varchar(2),Electric varchar(2),Psychic varchar(2),Ice varchar(2),Dragon varchar(2),Dark varchar(2))
  var %x = 2, %y = $lines(txt/pokemon/resource/chart.txt), %a
  while (%x <= %y) {
    %a = $replace($read(txt/pokemon/resource/chart.txt,%x),;,' $+ $chr(44) $+ ')
    sqlite_exec %sql.db INSERT INTO p_types (type,Bug,Fighting,Flying,Ghost,Ground,Normal,Poison,Rock,Steel,Dark,Dragon,Electric,Fire,Grass,Ice,Psychic,Water) VALUES (' $+ %a $+ ')
    inc %x
  }
  sqlite_exec %sql.db CREATE TABLE p_inventory (name varchar(20), Cash varchar(20))
  sqlite_exec %sql.db CREATE TABLE p_items (name varchar(20), type varchar(20), cost varchar(10), mod varchar(10), effect varchar(15), desc varchar(200))
  var %x = 1, %y = $lines(txt/pokemon/items.txt), %a
  while (%x <= %y) {
    %a = $read(txt/pokemon/items.txt,%x)
    sqlite_exec %sql.db ALTER TABLE p_inventory ADD $sql_esc($gettok(%a,1,9)) varchar(3) default 0
    sqlite_exec %sql.db INSERT INTO p_items VALUES (' $+ $replace($filltok($sql_esc(%a),-,9),$chr(9),' $+ $chr(44) $+ ') $+ ')
    inc %x
  }
  var %x = 1, %y = $lines(txt/pokemon/tms.txt), %a
  sqlite_exec %sql.db CREATE TABLE p_tm (name varchar(20))
  while (%x <= %y) {
    %a = $gettok($read(txt/pokemon/tms.txt,%x),1,9)
    sqlite_exec %sql.db ALTER TABLE p_tm ADD %a varchar(3) default 0
    inc %x
  }
  sqlite_exec %sql.db CREATE TABLE p_learnset (name varchar(50))
  %x = 1
  while (%x <= 99) {
    sqlite_exec %sql.db ALTER TABLE p_learnset ADD l $+ %x varchar(20)
    inc %x
  }
  var %x = 1, %y = $lines(txt/pokemon/learnset.txt), %a, %n, %t
  while (%x <= %y) {
    %a = $read(txt/pokemon/learnset.txt,%x)
    tokenize 9 %a
    %n = 1
    %t = $numtok($2,44)
    sqlite_exec %sql.db INSERT INTO p_learnset (name) VALUES (' $+ $replace($sql_esc($1),_44,*) $+ ')
    while (%n <= %t) {
      sqlite_exec %sql.db UPDATE p_learnset SET l $+ $replace($gettok($2,%n,44),|,=') $+ ' WHERE name=' $+ $replace($sql_esc($1),_44,*) $+ '
      inc %n
    }
    inc %x
  }
  sqlite_commit %sql.db
  sqlite_close %sql.db
}