Mic Mute Script with Settings AutoHotkey2.0

#Requires AutoHotkey v2.0
#SingleInstance force
A_IconTip := "Microphone Status: Mic not Found"
TraySetIcon "%systemroot%\System32\comres.dll", 11


;#### Settings Start ####

Hotkey "F1", MicMuteToggle
Hotkey "F2", PushToMute
MicName := "Microphone (2- BEACN Studio)" ;### Example on how to find your mic name: https://imgur.com/a/mic-name-example-mute-script-BWqvtQJ
MouseTooltip := 1 ;Set this 0 for OFF and 1 for ON

;#### Settings End ####


;### Setting Starting icon depending on mic status Red X for Muted and Green Check for Live
if (SoundGetMute( , MicName) = 0) { ;### What to do if mic is Live
A_IconTip := "Microphone Status: Live"
TraySetIcon "%systemroot%\System32\comres.dll", 9 ;# Icon for Live Mic
    }
    else if (SoundGetMute( , MicName) = 1) { ;### What to do if mic is Muted
A_IconTip := "Microphone Status: Muted"
TraySetIcon "%systemroot%\System32\comres.dll", 11 ;# Icon for Muted Mic
}


MicMuteToggle(ThisHotkey)
{
SoundSetMute -1, , MicName ;###Toggles the mic Mute
    if (SoundGetMute( , MicName) = 0) { ;### What todo if mic is Live
        A_IconTip := "Microphone Status: Live"
        if (MouseTooltip = 1) { ;### Makes a tooltip at mouse location for 1 sec if MouseTooltip = 1
            ToolTip "Microphone Mute Off"
            SetTimer () => ToolTip(), -1000
        }
        TraySetIcon "%systemroot%\System32\comres.dll", 9 ;# Icon for Live Mic
    }
    else if (SoundGetMute( , MicName) = 1) { ;### What to do if mic is Muted
        A_IconTip := "Microphone Status: Muted"
        if (MouseTooltip = 1) { ;### Makes a tooltip at mouse location for 1 sec if MouseTooltip = 1
            ToolTip "Microphone Mute On"
            SetTimer () => ToolTip(), -1000
        }
        TraySetIcon "%systemroot%\System32\comres.dll", 11 ;# Icon for Muted Mic
}
KeyWait ThisHotkey  ;### Wait for the key to be released.
}



PushToMute(ThisHotkey)
{
    if (SoundGetMute( , MicName) = 0) { ;### What to do if mic is Live
        SoundSetMute 1, , MicName
        TraySetIcon "%systemroot%\System32\comres.dll", 11 ;# Icon for Muted Mic
        KeyWait ThisHotkey  ;### Wait for the key to be released.
        SoundSetMute 0, , MicName
        TraySetIcon "%systemroot%\System32\comres.dll", 9 ;# Icon for Live Mic
    }
}