Exportar a Excel

clear all

* Cargar la base de datos de Latinobarometro
cd "~/Bases de Datos/Latinobarometro/"
use "Datos/Latinobarometro_2020_Esp_Stata_v1_0.dta"

* Se crea la colección para las tabla1, tabla2 y tabla3
collect create tabla1
bysort sexo: collect: ci means p72npn

collect create tabla2
bysort reeduc_1: collect: ci means p72npn

collect create tabla3
bysort reedad: collect: ci means p72npn

* Renombramos las filas y columnas de todas las tablas
foreach i in tabla1 tabla2 tabla3 {
	collect label levels result N "n", name(`i') modify
	collect label levels result mean "media", name(`i') modify
	collect label levels result se "Error Est.", name(`i') modify
	collect label levels result lb "L. Inferior IC", name(`i') modify
	collect label levels result ub "L. Superior IC", name(`i') modify


	collect style cell, name(`i') border( right, pattern(none) ) border( left, pattern(none) )
}

* Definimos la apariencia de las tablas
collect layout (sexo) (result[N] result[mean] result[se] result[lb ub]) (), name(tabla1)
collect layout (reeduc_1) (result[N] result[mean] result[se] result[lb ub]) (), name(tabla2)
collect layout (reedad) (result[N] result[mean] result[se] result[lb ub]) (), name(tabla3)

* Finalmente exportamos los resultados a Excel
collect export "Resultados/Tablas.xlsx", name(tabla1) as(xlsx) sheet(Sheet1) cell(A1) replace
collect export "Resultados/Tablas.xlsx", name(tabla2) as(xlsx) sheet(Sheet1) cell(A5) modify
collect export "Resultados/Tablas.xlsx", name(tabla3) as(xlsx) sheet(Sheet1) cell(A15) modify