Twitch Link Protection & Permit for VitruxPT v5.0

alias -l nk { return ( $+ $nick $+ ): }

ON !*:PART:#: { unset %permit_block_ [ $+ [ $nick ] ] | unset %permit_ [ $+ [ $nick ] ] }

ON !*:TEXT:*:#: {
  tokenize 32 $strip($1-,burci)
  if ($1 == !link) {
    if ($nick !isop $chan) && (!$check_modchixy($nick,$chan)) { .msg $chan $nk Error, You must be an channel moderator! | return }
    if ($2 == on) {
      if (%linkchixy) {
        .msg # $nk Link protection is already enabled!
        return
      }
      elseif (!%linkchixy) {
        .msg # $nk Link protection enabled.
        set %linkchixy 1
        return
      }
    }
    if ($2 == off) {
      if (%linkchixy) {
        .msg # $nk Link protection disabled.
        unset %linkchixy
        return
      }
      elseif (!%linkchixy) {
        msg # $nk Link protection is already disabled!
        return
      }
    }
  }
  if ($1 == !do) {
    if ($nick !isop $chan) && (!$check_modchixy($nick,$chan)) { .msg $chan $nk Error, You must be an channel moderator! | return }
    if (!$2) { .msg $chan $nk Error, Please specify the command! | return }
    $2-
    .msg $chan $nk The command has been executed.
    return
  }
  if ($1 == !permit) {
    if ($nick !isop $chan) && (!$check_modchixy($nick,$chan)) { .msg $chan $nk Error, You must be an channel moderator! | return }
    if (%linkchixy) {
      if (!$2) { .msg $chan $nk Error, Please specify a nickname! | return }
      if (%permit_ [ $+ [ $2 ] ]) { .msg $chan $nk Error, This user $qt($2) is already into the permit list! | return }
      set -eu180 %permit_ [ $+ [ $2 ] ] 1
      unset %permit_block_ [ $+ [ $2 ] ]
      .msg $chan ( $+ $2 $+ ): You have 3 min to post a link.
      return
    }
    elseif (!%linkchixy) { .msg $chan $nk Error, The Link Protection is NOT enabled! | return }
  }
  if (%linkchixy) {
    if ($nick isop $chan) { return }
    if ($check_modchixy($nick,$chan)) { return }
    if ($check_regchixy($nick,$chan)) { return }
    if ($check_subchixy($nick,$chan)) { return }
    if (*reddit.com/r/smite* !iswm $1-) && (*www.* iswm $1- || *http://* iswm $1- || *.com* iswm $1- || *.tv* iswm $1- || *.nl* iswm $1- || *.sh* iswm $1- || *.net* iswm $1- || *.me* iswm $1-) {
      if (%permit_ [ $+ [ $nick ] ]) {
        unset %permit_ [ $+ [ $nick ] ]
        unset %permit_block_ [ $+ [ $nick ] ]
        .msg $chan $nk Ok, You have post your link.
        return
      }
      if (!%permit_block_ [ $+ [ $nick ] ]) {
        set -eu180 %permit_block_ [ $+ [ $nick ] ] 1
        .msg $chan /timeout $nick 10
        .msg $chan $nk Please ask permittion before posting a link! - [Link] [Warning]
        return
      }
      if (%permit_block_ [ $+ [ $nick ] ] == 1) {
        set -eu180 %permit_block_ [ $+ [ $nick ] ] 2
        .msg $chan /timeout $nick 180
        .msg $chan $nk That was your 2rd link, ask for permittion now! - [Link] [10m BAN]
        return
      }
      if (%permit_block_ [ $+ [ $nick ] ] == 2) {
        unset %permit_block_ [ $+ [ $nick ] ]
        unset %permit_ [ $+ [ $nick ] ]
        .msg $chan /timeout $nick 86400
        .msg $chan $nk That was your 3rd link, Try again tomorrow! - [Link] [24h BAN]
        return
      }
    }
  }
}
alias check_regchixy {
  if (!$1) { return }
  if (!$2) { return }
  if ($me !ison $2) { return 0 }
  var %f = regularschixy.txt
  if (!$isfile(%f)) { return 0 }
  if (!$lines(%f)) { return 0 }
  var %r = $read(%f,nw,$1)
  if (%r) { return 1 }
  elseif (!%r) { return 0 }
}
alias check_modchixy {
  if (!$1) { return }
  if (!$2) { return }
  if ($me !ison $2) { return 0 }
  var %f = modschixy.txt
  if (!$isfile(%f)) { return 0 }
  if (!$lines(%f)) { return 0 }
  var %r = $read(%f,nw,$1)
  if (%r) { return 1 }
  elseif (!%r) { return 0 }
}
alias check_subchixy {
  if (!$1) { return }
  if (!$2) { return }
  if ($me !ison $2) { return 0 }
  var %f = subs.txt
  if (!$isfile(%f)) { return 0 }
  if (!$lines(%f)) { return 0 }
  var %r = $read(%f,nw,$1)
  if (%r) { return 1 }
  elseif (!%r) { return 0 }
}