TacO Installer Script

; Example of Inno Setup Script for the English versions of the TacO Setup file.

[Setup]
; The GUID of AppId must be a unique value
; Inno Setup Studio/Compiler automatically creates a unique GUID
AppId={{########-####-####-####-############}
AppName=GW2 TacO ReActif EN
AppVerName=GW2 TacO ReActif EN
AppVersion=047.2802r
VersionInfoProductName=GW2 TacO ReActif (English)
VersionInfoProductTextVersion=0.47.2802.r
VersionInfoDescription=GW2 TacO ReActif with english markers
VersionInfoCopyright=BoyC (boyc@scene.hu)
VersionInfoOriginalFileName=GW2TacO.exe
VersionInfoCompany=ReActif (https://reactif.games)
VersionInfoVersion=2020.07.09.0
AppContact=ReActif
AppComments=Enjoy a part of TacO
AppCopyright=BoyC (boyc@scene.hu)
AppPublisher=ReActif
AppPublisherURL=https://reactif.games/taco/?lang=en
AppSupportURL=https://reactif.games/taco/?lang=en#faq
AppUpdatesURL=https://reactif.games/taco/?lang=en#download
DefaultDirName={commonpf}\GW2 TacO ReActif EN
DefaultGroupName=GW2 TacO ReActif EN
UsePreviousAppDir=yes
UsePreviousGroup=yes
AllowNoIcons=yes
Uninstallable=yes
UninstallDisplayIcon={app}\GW2TacO.ico
UninstallDisplayName=GW2 TacO ReActif (English)
OutputDir=#:\
OutputBaseFilename=GW2 TacO ReActif EN Setup
SetupIconFile=GW2TacO.ico
SolidCompression=yes
Compression=lzma2/ultra
CloseApplications=force
; (Optional) Show a text in a window before the install
;InfoBeforeFile=InformationBeforeInstall.txt

[Languages]
; Language of the text in the Setup
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
; Indicate if the creation of a Desktop Icon are pre-check or not (here = uncheck by default)
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Icons]
; Set shortcut (must be configured even if the user does not use them)
Name: "{group}\TacO ReActif EN"; Filename: "{app}\GW2TacO.exe"; IconFilename: "{app}\GW2TacO.ico"
Name: "{commondesktop}\TacO ReActif EN"; Filename: "{app}\GW2TacO.exe"; IconFilename: "{app}\GW2TacO.ico"; Tasks: desktopicon

[InstallDelete]
; Configures the files of the installation folder which, if present, must be deleted before copying the new files
; This allows to delete a file that is no longer present in the new version or to remove the old log files
; The configuration or validation files are commented out to keep the parameters chosen by the user
;Type: files; Name: "{app}\activationdata.xml"
Type: files; Name: "{app}\categorydata.xml"
Type: files; Name: "{app}\crash.log"
Type: files; Name: "{app}\GW2TacO.exe"
Type: files; Name: "{app}\GW2TacO.ico"
Type: files; Name: "{app}\GW2TacO.log"
Type: files; Name: "{app}\hpgrids.xml"
Type: files; Name: "{app}\locationaltimers.xml"
Type: files; Name: "{app}\maptimer.xml"
Type: files; Name: "{app}\TacO_Language_cn.xml"
Type: files; Name: "{app}\TacO_Language_de.xml"
Type: files; Name: "{app}\TacO_Language_en.xml"
Type: files; Name: "{app}\TacO_Language_fr.xml"
Type: files; Name: "{app}\TacO_Language_sp.xml"
;Type: files; Name: "{app}\TacOConfig.xml"
Type: files; Name: "{app}\UI.wbs"
Type: files; Name: "{app}\UI.xml"
Type: files; Name: "{app}\UI_large.css"
Type: files; Name: "{app}\UI_larger.css"
Type: files; Name: "{app}\UI_normal.css"
Type: files; Name: "{app}\UI_small.css"
Type: filesandordirs; Name: "{app}\Data\*"
Type: filesandordirs; Name: "{app}\Img\*"
; Only XML files are deleted (not external pack)
Type: filesandordirs; Name: "{app}\POIs\*.xml"


[UninstallDelete]
; When uninstalling, remove files, folders of TacO and shortcuts (Start Menu and if exist Desktop)
Type: filesandordirs; Name: "{app}"
Type: files; Name: "{commondesktop}\TacO ReActif EN.lnk"

[Files]
; List of all the files which will be installed
; Source = The location of the file on the development PC (no relation to the user's PC)
; DestDir = Destination in the installation folder of TacO {app}.
Source: "#:\TacO\Release\GW2TacO.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\GW2TacO.ico"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\categorydata.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\hpgrids.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\locationaltimers.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\maptimer.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\TacO_Language_cn.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\TacO_Language_de.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\TacO_Language_en.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\TacO_Language_fr.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\TacO_Language_sp.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\TacOConfig.xml"; DestDir: "{app}"; Flags: onlyifdoesntexist
Source: "#:\TacO\Release\UI.wbs"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\UI.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\UI_large.css"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\UI_larger.css"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\UI_normal.css"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\UI_small.css"; DestDir: "{app}"; Flags: ignoreversion
Source: "#:\TacO\Release\Data\*"; DestDir: "{app}\Data\"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "#:\TacO\Release\Img\*"; DestDir: "{app}\Img\"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "#:\TacO\Release\POIs\*"; DestDir: "{app}\POIs\"; Flags: ignoreversion recursesubdirs createallsubdirs
; NOTE: Don't use "Flags: ignoreversion" on any shared system files