TesteEEPROM_ESP.ino

// Extarido e modificado do AutoConnectWithFSParametersAndCustomIP da biblioteca WiFiManager
// Era AutoConnectWithFSParametersAndCustomIP_V03
// Versao V03
// Versao V04  Usar interruptor para detectar reset
/*
  Nesta versao, se o interruptor estiver fechado ao ligar o modulo,
  isto pode ser verificado porque a lampada fica acessa ao ligar,
  e antes de 5 segundos for desligado o interruptor, o modulo entra em AP mode.
  Em AP mode ele cria uma rede chamada "AP_Configure", com IP 192.168.1.4.
  Acessando este IP configura-se a red com os novos parametros de:
  SSID. Password, IP, Gateway, e SubNet.
*/
#include <FS.h>                           // This needs to be first, or it all crashes and burns...
#include <EEPROM.h>
#include <ESP8266WiFi.h>                  // https://github.com/esp8266/Arduino
#include <ESP8266WebServer.h>
#include <WiFiManager.h>                  // https://github.com/tzapu/WiFiManager
#include <ArduinoJson.h>                  // https://github.com/bblanchon/ArduinoJson

char static_ip[16] = "10.0.1.56";         // Default custom static IP
char static_gw[16] = "10.0.1.1";
char static_sn[16] = "255.255.255.0";
bool shouldSaveConfig = false;            // Flag for saving data

// Port em uso
// 0 15   SHT 2 MOC 4 SW 5 LED 13 Rst
#include <SHT1x.h>                                          // https://github.com/practicalarduino/SHT1x
#define dataPin  0                                          // GPIO 0  D3  Port para o Data do SHT10
#define clockPin 15                                         // GPIO 15 D8  Port para o Clock do SHT10
SHT1x sht1x(dataPin, clockPin);                             // Instancia shtx1

ESP8266WebServer server(80);                                // Instancia server
//  Strings com HTML
String Q_1 = "<!DOCTYPE HTML><html><head><meta http-equiv='refresh' content='2;URL=/Controle'/></head><h1><center>Controle de luz, Temperatura e Umidade</center>";
String Q_2 = "</p></center><h3><BR></h3><html>\r\n";
String Ql = "";                                             // Quarto ligado
String Qd = "";                                             // Quarto desligado
String Qil = "";                                            // Quarto intermediario ligado
String Qid = "";                                            // Quarto intermediario desligado
String LuzQuarto;                                           // String para controle
float temp_c;                                               // Variavel para temperatura
int humidity;                                               // Variavel para umidade
#define Led_Ap_Mode 5                                       // Led indicativo de AP mode
#define Saida1 2                                            // GPIO2 Port para ligar Controle do triac (Pino 2 do MOC3023)
#define Switch1 4                                           // GPIO4 Port para ligar o interruptor
byte Switch1_atual = 0;                                     // Variavel para staus de GPIO5 (Status do interruptor)
unsigned long previousMillis = 0;                           // Variavel para medir periodos
const long interval = 2000;                                 // Periodo de leitura da temperatura e umidade
bool flagRst = 0;                                           // Flag para permitir reset dos parametros SSID e PW
//bool bypass = LOW;                                          // Controle do automatico
byte meuStatus = 0;
#define led5 12
//---------------------------------------
void gettemperature()                                       // Funcoa para ler temperatura e umidade
{
  if (millis() - previousMillis >= interval)                // Se passou o intervalo
  {
    previousMillis = millis();                              // Restaura valor de previousMillis
    humidity = sht1x.readHumidity();                        // Le umidade em SHT10
    temp_c = sht1x.readTemperatureC();                      // Le temperatura em SHT10
  }
}
//-------------------------------
void saveConfigCallback ()                                  // Callback notifying us of the need to save config
{
  Serial.println("Should save config");
  shouldSaveConfig = true;
}
//-------------------------------
void setup()
{
  EEPROM.begin(64);

  Ql += Q_1;                                                // Monta tela pra informar que a luz
  Ql += "<p><center>Luz</p><p><a href=\"/Controle?LuzQuarto=off \"><button style=\"background-color: rgb(255, 0,   0);height: 100px; width: 200px;\"><h1> Acesa</h1></button></a>";
  Qd += Q_1;                                                // Monta tela pra informar que a luz
  Qd += "<p><center>Luz</p><p><a href=\"/Controle?LuzQuarto=on \"><button style=\"background-color: rgb(0, 255,   0);height: 100px; width: 200px;\"><h1> Apagada</h1></button></a>";

  Serial.begin(115200);                                       // Inicializa Serial
  Serial.println();                                           // Pint
  pinMode(Led_Ap_Mode, OUTPUT);                               // Led_Ap_Mode como saida
  digitalWrite(Led_Ap_Mode, HIGH);                            // Apaga o Led indicativo de AP
  pinMode(led5, OUTPUT);
  digitalWrite(led5, LOW);
  pinMode(Switch1, INPUT_PULLUP);                             // Switch1 como entrada e liga o resistor de pullup
  delay(20);                                                  // Delay para estabilizar o port
  Switch1_atual = digitalRead(Switch1);                       // Atualiza status de Switch1_atual
  pinMode(Saida1, OUTPUT);                                    // Saida1 como saida
  digitalWrite(Saida1, LOW);                                  // Liga saída


  meuStatus = EEPROM.read(40);
  Serial.println(meuStatus);
  if (meuStatus == 55)
  {
    digitalWrite(led5, HIGH);
  }


  // Reset da rede wifi
  if (digitalRead(Switch1) == LOW)                            // Se interruptor está ligado
  {
    digitalWrite(Saida1, HIGH);                               // Liga saída1
    delay(5000);                                              // Aguarda 5 segundos
    digitalWrite(Saida1, LOW);                                // Desliga saída1
    if (digitalRead(Switch1) == HIGH)                         // Se interruptor continua ligado
    {
      Serial.println("reset SSID e IP  ");
      flagRst = HIGH;                                         // Indica reset de parametros
    }
  }
  /*
    // Bypass da rede wifi
    if (flagRst == LOW)                                          // Se não foi reseted
    {
      if (digitalRead(Switch1) == HIGH)                         // Se interruptor está liberado
      {
        digitalWrite(Saida1, LOW);                              // desliga saída1
        //      yield();
        delay(1000);                                            // Aguarda 5 segundos
        digitalWrite(Saida1, HIGH);                             // Liga saída1
        if (digitalRead(Switch1) == LOW)                        // Se interruptor esta pressionado
        {
          Serial.println("bypassed  ");
          bypass = HIGH;                                        // Desabilita o sistema de wifi
        }
      }
    }
  */
  digitalWrite(Led_Ap_Mode, HIGH);                            // Apaga o Led indicativo de AP
  delay(20);                                                  // Delay para estabilizar o port
  Switch1_atual = digitalRead(Switch1);                       // Atualiza status de Switch1_atual
  digitalWrite(Saida1, LOW);                                  // Liga saída

  //  if (bypass == LOW)                                          // Se bypass esta desabilitado
  //  {
  //  else digitalWrite(Saida1, LOW);                             // Se não deliga saida1

  //SPIFFS.format();                                          // Clean FS, for testing
  Serial.println("mounting FS...");                           // Read configuration from FS json
  if (SPIFFS.begin())
  {
    Serial.println("mounted file system");
    if (SPIFFS.exists("/config.json"))                        // If file exists, reading and loading
    {
      Serial.println("reading config file");
      File configFile = SPIFFS.open("/config.json", "r");
      if (configFile) {
        Serial.println("opened config file");
        size_t size = configFile.size();
        std::unique_ptr<char[]> buf(new char[size]);          // Allocate a buffer to store contents of the file.
        configFile.readBytes(buf.get(), size);
        DynamicJsonBuffer jsonBuffer;
        JsonObject& json = jsonBuffer.parseObject(buf.get());
        json.printTo(Serial);
        if (json.success())
        {
          Serial.println("\nparsed json");
          if (json["ip"])
          {
            Serial.println("setting custom ip from config");
            strcpy(static_ip, json["ip"]);
            strcpy(static_gw, json["gateway"]);
            strcpy(static_sn, json["subnet"]);
            Serial.println(static_ip);
          }
          else
          {
            Serial.println("no custom ip in config");
          }
        }
        else
        {
          Serial.println("failed to load json config");
        }
      }
    }
  }
  else
  {
    Serial.println("failed to mount FS");
  }
  Serial.println(static_ip);                                  // end read
  WiFiManager wifiManager;

  if (flagRst == HIGH)                                        // Se reset foi habilitado
  {
    flagRst = LOW;                                            // Desabilita reset
    wifiManager.resetSettings();                              // Reseta SSID e PW
  }
  digitalWrite(Led_Ap_Mode, HIGH);                            // Acende o Led indicativo de AP

  wifiManager.setSaveConfigCallback(saveConfigCallback);      // Set config save notify callback
  IPAddress _ip, _gw, _sn;                                    // Set static ip
  _ip.fromString(static_ip);
  _gw.fromString(static_gw);
  _sn.fromString(static_sn);
  wifiManager.setSTAStaticIPConfig(_ip, _gw, _sn);

  // wifiManager.resetSettings();                               // Reset settings - for testing
  EEPROM.write(40, 55);
  EEPROM.commit();

  wifiManager.setMinimumSignalQuality();                        // Set minimu quality of signal so it ignores AP's under that quality    //defaults to 8%
  if (!wifiManager.autoConnect("AP_Configure", "password"))
  {
    Serial.println("failed to connect and hit timeout");
    delay(3000);

    ESP.reset();                                                // Reset and try again, or maybe put it to deep sleep
    delay(5000);
  }
  //  Serial.println("connected...yeey :)");                    // If you get here you have connected to the WiFi

  EEPROM.write(40, 0);
  EEPROM.end();

  digitalWrite(Led_Ap_Mode, LOW);                               // Apaga o Led indicativo de AP
  if (shouldSaveConfig)                                         // Save the custom parameters to FS
  {
    Serial.println("saving config");
    DynamicJsonBuffer jsonBuffer;
    JsonObject& json = jsonBuffer.createObject();
    json["ip"] = WiFi.localIP().toString();
    json["gateway"] = WiFi.gatewayIP().toString();
    json["subnet"] = WiFi.subnetMask().toString();
    File configFile = SPIFFS.open("/config.json", "w");
    if (!configFile)
    {
      Serial.println("failed to open config file for writing");
    }
    json.prettyPrintTo(Serial);
    json.printTo(configFile);
    configFile.close();    //end save
  }
  Serial.println("local ip");
  Serial.println(WiFi.localIP());
  Serial.println(WiFi.gatewayIP());
  Serial.println(WiFi.subnetMask());

  server.on("/", []()                                       // Ao request
  {
    server.send(200, "text/html", Ql);                      // Executa o HTML Ql (Quarto ligado)
  });
  server.on("/Controle", []()                               // Ao requeste
  {
    //    gettemperature();                                       // Le temperatura e umidade. Comentar se tiver sem sensor pois fica lento
    LuzQuarto = server.arg("LuzQuarto");                    // Recupera o valor do parametro luz enviado
    if (LuzQuarto == "off") digitalWrite(Saida1, LOW);      // Se o valor de luz e off desliga a saida
    if (LuzQuarto == "on") digitalWrite(Saida1, HIGH);      // Se o valor de luz e on liga a saida

    if (digitalRead(Saida1) == HIGH)                        // Se a saida esta ligada, carrega a pagina "ligada"
    {
      Qil += Ql;                                            // Monta tela nova quarto ligado
      Qil +=  "<p><center>Temperatura: " + String((float)temp_c) + "C </p>";
      Qil +=  "<p><center>Umidade: " + String((int)humidity) + "% </p>";
      Qil += Q_2;
      server.send(200, "text/html", Qil);                   // Mostra Quarto ligado
      Qil = "";                                             // Limpa valor de temperatura e umidade
    }
    if (digitalRead(Saida1) == LOW)                         // Se a saida esta desligada, carrega a pagina "desligada"
    {
      Qid += Qd;                                            // Monta tela nova quarto desligado
      Qid += "<p><center>Temperatura: " + String((float)temp_c) + "C </p>";
      Qid += "<p><center>Umidade: " + String((int)humidity) + "% </p>";
      Qid += Q_2;
      server.send(200, "text/html", Qid);                   // Mostra Quarto desligado
      Qid = "";                                             // Limpa valor de temperatura e umidade
    }
    delay(100);                                             // Delay
  });
  server.begin();                                           // Inicaliza servidor
  Serial.println("HTTP server started");                    // Imprime
  //  }
}
//-------------------------------
void loop()
{
  server.handleClient();                                    // Executa instancia

  if (digitalRead(Switch1) !=  Switch1_atual)               // Se o valor do SW alterou
  {
    delay(40);                                              // Delay
    if (digitalRead(Switch1) !=  Switch1_atual)             // Se o valor do SW alterou
    {
      digitalWrite(Saida1, !digitalRead(Saida1));           // Inverte a saida lamp1
      Switch1_atual = digitalRead(Switch1);                 // Atualisa o Gpio5 atual
    }
  }
}