init3DEN.sqf

//OPTIMIZATIONS: Toggles some things off in the editor upon loading mission
isNil{

0 spawn{

set3DENLinesVisible[false,false];
set3DENIconsVisible[false,false];
set3DENModelsVisible[false,false];
setObjectViewDistance[1200,1];
setViewDistance 1200;
setTerrainGrid 50;

waitUntil{ !isNil{profileNamespace getVariable "display3DEN_panelLeft"} };
sleep 0.02;
    if ( profileNamespace getVariable "display3DEN_panelLeft" ) then
    {
        [ "collapseEntityList" ] call BIS_fnc_3DENInterface;
        sleep 0.0001;
        [ "showPanelLeft" ] call BIS_fnc_3DENInterface;
    } else {
        [ "showPanelLeft" ] call BIS_fnc_3DENInterface;
        sleep 0.0001;
        [ "collapseEntityList" ] call BIS_fnc_3DENInterface;
        sleep 0.0001;
        [ "showPanelLeft" ] call BIS_fnc_3DENInterface;
    };

    if ( profileNamespace getVariable "display3DEN_panelRight" ) then
    {
        [ "collapseAssetBrowser" ] call BIS_fnc_3DENInterface;
        sleep 0.0001;
        [ "showPanelRight" ] call BIS_fnc_3DENInterface;
    };

[] call BIS_fnc_3DENDrawLocations;
1 call BIS_fnc_3DENFlashlight;


//AUTOMATICALLY EXPORT TO MP WHEN YOU SAVE
TFR_3DENSaved = false;
add3DENEventHandler [ "OnMissionSave" ,
{
    if ( TFR_3DENSaved ) exitWith { };
    TFR_3DENSaved = true;
    0 spawn
    {
        sleep 1.5;

        do3DENAction "MissionExportMP";

        titleText
        [
            "<a font='PuristaBold' align='center' size='1.5' shadow='2'>Saved and Exported</a>" ,
            "PLAIN" ,
            0 ,
            true ,
            true
        ];

        titleFadeOut 6;

        sleep 8;

        TFR_3DENSaved = false;
    };
}];

};

};