Bounty Hunter

10 ON ERROR GOTO 7300
20 KEY OFF
30 REM * bounty hunter *
40 REM * by martin richardson *
50 REM * 12-19-86 *
60 CLS
70 LOCATE 9,1
80 PRINT TAB(34);"Bounty Hunter"
90 PRINT TAB(28);"Adventure in the Old West"
100 PRINT:PRINT:PRINT TAB(25);"Do you need instructions (Y or N)? ";
110 N=N+1:IF N>32767 THEN N=-32768!
120 A$=INKEY$
130 IF A$="" THEN 110 ELSE RANDOMIZE N
140 PRINT A$
150 IF A$="Y" THEN GOSUB 6360
160 DIM MAP(10,10),OBJ$(6)
170 DIM DECK$(52),C$(13),S$(4),PACK(52),V(52)
180 DEF FNR(X)=INT(RND*X)+1
190 MAP(1,1)=6
200 FOR X=0 TO 6:READ OBJ$(X):NEXT X
210 FOR X=2 TO 5:READ P$(X):NEXT X
220 DATA ". ","Y ","C ","S ","M ","V ","T "
230 DATA "dark cave","old shack","old mine","abandoned village"
240 FOR X=1 TO 9:READ N$(X)
250 A=FNR(8):IF A=8 THEN 270
260 B=FNR(8-A):C=8-B-A
270 A(X)=10+A:D(X)=10+B:S(X)=10+C
280 A=0:B=0:C=0
290 NEXT X
300 DATA "Black Bruce","Fast Phil","Mean Morgan"
310 DATA "The Boss","One-eyed Ned","Gruesome Jack"
320 DATA "Evil Edgar","Sly Sam","The Lone Stranger"
330 DIR$="NSEW"
340 FOR X=1 TO 4:READ D$(X):NEXT X
350 DATA "north","south","east","west"
360 REM *** cards ***
370 DATA "2","3","4","5","6","7","8","9","10"
380 DATA "Jack","Queen","King","Ace"
390 DATA "diamonds","clubs   ","hearts  ","spades  "
400 Z=0
410 FOR X=1 TO 13:READ C$(X):NEXT X
420 FOR X=1 TO 4:READ S$(X):NEXT X
430 FOR X=1 TO 4:FOR Y=1 TO 13
440 Z=Z+1:DECK$(Z)=C$(Y)+" of "+S$(X)
450 V(Z)=Y+1:IF V(Z)<>14 AND V(Z)>10 THEN V(Z)=10
460 IF V(Z)=14 THEN V(Z)=11
470 NEXT Y,X
480 REM ****** cactus ******
490 PRINT:PRINT:PRINT:PRINT "Setting up the old west ";
500 FOR X=1 TO 15
510 Y=FNR(10):Z=FNR(10):IF MAP(Y,Z)<>0 THEN 510
520 FOR A=Y-1 TO Y+1:FOR B=Z-1 TO Z+1
530 IF A<1 OR B<1 OR A>10 OR B>10 THEN 550
540 IF MAP(A,B)<>0 THEN 510
550 NEXT B:NEXT A
560 MAP(Y,Z)=1
570 PRINT ". ";
580 NEXT X
590 PRINT:PRINT "   ";
600 GOSUB 690:MAP(X,Y)=2 'cave
610 PRINT ". ";
620 GOSUB 690:MAP(X,Y)=3 'cabin hideout
630 PRINT ". ";
640 GOSUB 690:MAP(X,Y)=4 'old mine
650 PRINT ". ";
660 GOSUB 690:MAP(X,Y)=5 'abandoned villiage
670 PRINT ". "
680 GOTO 720
690 X=FNR(10):Y=FNR(10):IF X<5 AND Y<5 THEN 690
700 IF MAP(X,Y)<>0 THEN 690
710 RETURN
720 AIM=10:DEX=10:ST=10:OS=ST:POINTS=8
730 I=1:J=1
740 CLS
750 HORSE=2:GUN=0:FOOD=30:BULLETS=12:LOADED=6:SCORE=0
760 PRINT TAB(20);"Bounty Hunter"
770 PRINT TAB(15);"Adventure in the Old West"
780 PRINT:PRINT:GOSUB 790:ST=OS:GOTO 970
790 PRINT "Your abilities are:":PRINT
800 PRINT "Aim       ";AIM
810 PRINT "Dexterity ";DEX
820 PRINT "Stamina   ";OS
830 PRINT:PRINT "You have";POINTS;"points to distribute"
840 PRINT "to them.  Input the ability, a comma, and then"
850 PRINT "number of points (up to";POINTS;") to distribute"
860 PRINT "(i.e. Aim,4)";
870 INPUT A$,A:A=INT(A):A$=LEFT$(A$,1)
880 IF A$<>"A" AND A$<>"D" AND A$<>"S" THEN 790
890 IF A<1 OR A>POINTS THEN PRINT "You don't have"A"points!":PRINT:GOTO 790
900 IF A$="A" THEN IF AIM+A<=18 THEN AIM=AIM+A:POINTS=POINTS-A:GOTO 940
910 IF A$="D" AND DEX+A<=18 THEN DEX=DEX+A:POINTS=POINTS-A:GOTO 940
920 IF A$="S" AND OS+A<=18 THEN OS=OS+A:POINTS=POINTS-A:YES=1:GOTO 940
930 PRINT "Your abilities cannot exeed 18!":PRINT:GOTO 790
940 IF POINTS<1 THEN RETURN
950 PRINT:GOTO 790
960 REM ****** game start ******
970 OS=ST
980 CLS
990 PRINT:GOSUB 6150
1000 IF MAP(I,J)<>0 THEN GOSUB 1180:GOTO 1030
1010 GOSUB 3160:IF MAP(I,J)<>0 THEN GOSUB 1180
1020 REM *** options ***
1030 DAY=DAY+1:IF DAY<4 THEN 1100
1040 DAY=0:PRINT:PRINT "Next day":FOR X=1 TO 500:NEXT X
1050 IF PEACE>1 THEN PEACE=PEACE-1
1060 IF FOOD>0 THEN FOOD=FOOD-1:PRINT "Your food supply now totals";FOOD;".":GOTO 1100
1070 PRINT:PRINT "You are out of food! ";:ST=ST-1
1080 PRINT "Your stamina is now";ST
1090 IF ST<1 THEN PRINT "YOU ARE DEAD!":GOTO 6330
1100 IF LOADED<1 THEN PRINT:PRINT "Your gun is unloaded" ELSE PRINT
1110 PRINT "What do you do now";:INPUT Q$:Q$=LEFT$(Q$,1)
1120 IF Q$="N" OR Q$="S" OR Q$="E" OR Q$="W" THEN GOSUB 2180:GOTO 990
1130 IF Q$="M" THEN PRINT:GOSUB 6150:GOTO 1100
1140 IF Q$="I" THEN GOSUB 2930:GOTO 1100
1150 IF Q$="L" THEN GOSUB 3080:GOTO 1100
1160 PRINT:PRINT "That is not a valid command.":GOTO 1100
1170 PRINT:PRINT "The Commands are:":GOSUB 7100:GOTO 1100
1180 C=MAP(I,J):ON C-1 GOSUB 1210,1220,1230,1240,1250
1190 IF C=6 THEN 990
1200 GOTO 2350
1210 PRINT:PRINT "You are standing before the mouth of a dark cave.":RETURN
1220 PRINT:PRINT "You are standing in front of an old wooden shack.":RETURN
1230 PRINT:PRINT "The entrance to an old mine looms before you.":RETURN
1240 PRINT:PRINT "You stand on the outskirts of an abandoned villiage.":RETURN
1250 PRINT:PRINT "You are now in the town of Dusty Gulch"
1260 PRINT:PRINT "You may:"
1270 PRINT TAB(3);"1..Visit the local inn"
1280 PRINT TAB(3);"2..Visit the general store"
1290 PRINT TAB(3);"3..Visit the town jail"
1300 PRINT TAB(3);"4..Visit the training center"
1310 PRINT TAB(3);"5..Leave the town"
1320 PRINT:INPUT "Well";A:IF A<1 OR A>6 THEN 1320
1330 ON INT(A) GOTO 1360,1520,1800,2090,1340
1340 GOSUB 6150:GOTO 1100
1350 REM ****** inn ******
1360 PRINT:PRINT "There is drinking and dancing here along"
1370 PRINT "with warm meals and warm beds."
1380 PRINT "You may stay the night for $10 and heal your"
1390 PRINT "wounds or you may leave";
1400 IF MONEY>=10 THEN 1440
1410 PRINT ".  However, because of"
1420 PRINT "lack of funds, you are forced to leave."
1430 GOTO 1250
1440 INPUT " (S)tay or L)eave)";A$:IF A$<>"S" AND A$<>"L" THEN 1440
1450 IF A$="L" THEN PRINT:PRINT "Sorry you couldn't stay.  Come back again!":GOTO 1250
1460 MONEY=MONEY-10:ST=ST+10:IF ST>OS THEN ST=OS
1470 PRINT:PRINT "Ahhh!  The food was good and the bed was good."
1480 PRINT "Your stamina is now";ST;"."
1490 DAY=0
1500 GOTO 1250
1510 REM ****** general store ******
1520 PRINT:PRINT "Welcome to the Dusty Gulch General store"
1530 PRINT "Here's what we got fer sale:":PRINT
1540 PRINT TAB(3);"1..Bullets";TAB(26);"$50 per box of 18"
1550 PRINT TAB(3);"2..Smith and Wesson";TAB(26);"$150"
1560 PRINT TAB(3);"3..Food";TAB(26);"$30 for seven days worth
1570 PRINT TAB(3);"4..Riding Horse";TAB(26);"$250"
1580 IF ARTIFACT<>1 THEN PRINT TAB(3);"5..Old Indian Artifact";TAB(26);"$150"
1590 IF MONEY<30 THEN PRINT:PRINT "Since you aint got enuff money,  I'll be seein' ya!":GOTO 1250
1600 PRINT:PRINT "Your money pouch holds $";MONEY
1610 INPUT "What'll ya be needin";A
1620 IF A<1 OR A>5 THEN PRINT "Sorry, but we ain't got that.  Bye!":GOTO 1250
1630 IF A=5 AND ARTIFACT=1 THEN PRINT "Sorry, but we ain't got that.  Bye!":GOTO 1250
1640 IF A=1 AND MONEY<50 THEN PRINT "You ain't got enuff money!":PRINT:GOTO 690
1650 IF A=1 THEN MONEY=MONEY-50:BULLETS=BULLETS+18
1660 IF A=3 THEN MONEY=MONEY-30:FOOD=FOOD+7
1670 IF A=2 AND MONEY<150 THEN PRINT "You ain't got that much money!":PRINT:GOTO 690
1680 IF A=2 THEN GUN=2:MONEY=MONEY-150
1690 IF A=4 AND MONEY<250 THEN PRINT "You ain't got that much money!":PRINT:GOTO 690
1700 IF A=4 THEN HORSE=2:MONEY=MONEY-250
1710 IF A=5 AND MONEY<150 THEN PRINT "You ain't got that much money!":PRINT:GOTO 690
1720 IF A=5 THEN ARTIFACT=1:MONEY=MONEY-150
1730 PRINT:PRINT "It's a sale!"
1740 IF MONEY<30 THEN 1770
1750 PRINT:INPUT "You be needin anything else";A$
1760 IF LEFT$(A$,1)="Y" THEN PRINT:GOTO 1530
1770 PRINT:PRINT "Bye!  Come back agin, ya hear?"
1780 GOTO 1250
1790 REM ****** town jail ******
1800 IF CAUGHT=1 THEN 1880
1810 IF V<>0 THEN 1840
1820 D=FNR(9):IF D=V THEN 1820 ELSE V=D
1830 PLACE=FNR(4)+1:REWARD=(A(V)+D(V)+S(V))*10
1840 PRINT:PRINT "Wanted: ";N$(V)
1850 PRINT "Last seen at the ";P$(PLACE)
1860 PRINT "Reward: $";REWARD
1870 GOTO 1250
1880 PRINT:PRINT "Congratulations on catching ";N$(V)
1890 PRINT "Your reward is $";REWARD
1900 MONEY=MONEY+REWARD:SCORE=SCORE+REWARD
1910 FOR X=1 TO 2000:NEXT X
1920 PRINT:PRINT "'I'll get ya fer this!' snarles ";N$(V);"."
1930 FOR X=1 TO 1000:NEXT X
1940 X=1
1950 WHILE A(V)+D(V)+S(V)<54 AND X<3
1960 FLAG=0
1970 WHILE FLAG=0
1980 ON FNR(3) GOTO 1990,2000,2010
1990 IF A(V)<18 THEN A(V)=A(V)+1:FLAG=1:GOTO 2020
2000 IF D(V)<18 THEN D(V)=D(V)+1:FLAG=1:GOTO 2020
2010 IF S(V)<18 THEN S(V)=S(V)+1:FLAG=1
2020 WEND
2030 X=X+1
2040 WEND
2050 PRINT:PRINT "There is a new wanted poster up."
2060 FOR X=1 TO 1000:NEXT X
2070 CAUGHT=0:GOTO 1820
2080 REM ****** training center ******
2090 PRINT:PRINT "Welcome to the town training center"
2100 PRINT "Here you can improve any of your abilities."
2110 PRINT "We require a $500 fee, though."
2120 IF MONEY<500 THEN PRINT "Sorry Charlie.  Bye!":GOTO 1250
2130 IF AIM+DEX+ST=18*3 THEN PRINT "You cannot improve your abilities any more.":GOTO 1250
2140 MONEY=MONEY-500:PRINT:PRINT "You now have $";MONEY
2150 IF 18*3-(AIM+DEX+ST)<2 THEN POINTS=18*3-(AIM+DEX+ST) ELSE POINTS=2
2160 GOSUB 790:GOTO 1250
2170 REM ****** moving on ******
2180 D=INSTR(DIR$,Q$)
2190 IF HORSE=1 THEN M=1:GOTO 2230
2200 PRINT "You can move up to 2 spaces."
2210 PRINT "How many spaces ";D$(D);" to move";:INPUT M
2220 IF M<0 OR M>2 THEN 1100
2230 FOR X=1 TO M
2240 IF Q$="N" THEN I=I-1:IF I<1 THEN I=1:PRINT "The mountains block further progress north.":X=M
2250 IF Q$="N" AND MAP(I,J)=1 THEN I=I+1:PRINT "You can't move through a cactus!":X=M
2260 IF Q$="S" THEN I=I+1:IF I>10 THEN I=10:PRINT "The Great Canyon prevents further movement south.":X=M
2270 IF Q$="S" AND MAP(I,J)=1 THEN I=I-1:PRINT "You can't move through a cactus!":X=M
2280 IF Q$="E" THEN J=J+1:IF J>10 THEN J=10:PRINT "The ocean is in the way of further eastern travel.":X=M
2290 IF Q$="E" AND MAP(I,J)=1 THEN J=J-1:PRINT "You can't move through a cactus!":X=M
2300 IF Q$="W" THEN J=J-1:IF J<1 THEN J=1:PRINT "Western movement through the Great Swamp is impossible.":X=M
2310 IF Q$="W" AND MAP(I,J)=1 THEN J=J+1:PRINT "You can't move through a cactus!":X=M
2320 NEXT X
2330 RETURN
2340 REM ****** entry ******
2350 IF C=PLACE THEN 2430
2360 ON FNR(4) GOTO 2370,2380,2390,2400
2370 PRINT:PRINT "The ";P$(C);" is deserted.":GOTO 2410
2380 PRINT:PRINT "There is nothing in the ";P$(C);".":GOTO 2410
2390 PRINT:PRINT "Your search of the ";P$(C);" turns up nothing.":GOTO 2410
2400 PRINT:PRINT "The ";P$(C);" is empty."
2410 RETURN
2420 REM ****** the shootout ******
2430 PRINT:PRINT "Suddenly, ";N$(V);" jumps out"
2440 PRINT "of the shadows, his six shot revolver in his"
2450 PRINT "hand."
2460 S1=S(V):L=6:B=10+FNR(10)
2470 PRINT:IF LOADED>0 THEN PRINT "S)hoot, ";
2480 IF LOADED<6 AND BULLETS>0 THEN PRINT "D)odge and reload, ";
2490 PRINT "R)un";
2500 INPUT Q$:Q$=LEFT$(Q$,1)
2510 IF Q$<>"S" AND Q$<>"D" AND Q$<>"R" THEN 2470
2520 IF Q$="R" THEN RAN=1:DX=1:GOTO 2610
2530 IF Q$="D" AND BULLETS<1 THEN PRINT:PRINT "You are out of bullets!":GOTO 2490
2540 IF Q$="D" AND LOADED=6 THEN PRINT:PRINT "Your gun is already loaded!":GOTO 2490
2550 IF Q$="D" THEN LL=6-LOADED:IF BULLETS<LL THEN LL=BULLETS
2560 IF Q$="D" THEN LOADED=LOADED+LL:PRINT "Your gun is now loaded.":GOTO 2610
2570 IF Q$="S" AND LOADED<1 THEN PRINT "Your gun isn't loaded!":GOTO 2470
2580 GOSUB 2640
2590 IF CAUGHT=1 THEN PRINT "Time to move on...":FOR X=1 TO 1000:NEXT X:RETURN
2600 IF RIN=1 THEN PRINT:PRINT "He got away!":RIN=0:PLACE=0:V=0:RETURN
2610 GOSUB 2740
2620 IF RAN=1 THEN PRINT "You got away!":RAN=0:PLACE=0:V=0:RETURN
2630 GOTO 2470
2640 PRINT:PRINT:PRINT TAB(20);"*** BANG! ***":PRINT:FOR X=1 TO 100:NEXT X
2650 LOADED=LOADED-1
2660 R=FNR(8)-4:HIT=(AIM-D(V))+R+GUN
2670 IF DD=1 THEN HIT=HIT-INT(D(V)/4)+RIN:IF B<6 THEN R=B ELSE R=6
2680 IF DD=1 THEN DD=0:L=R:B=B-R
2690 IF HIT<1 THEN PRINT "You missed!":FOR X=1 TO 1000:NEXT X:RETURN
2700 PRINT "YOU HIT HIM!!!!"
2710 S1=S1-HIT:FOR X=1 TO 500:NEXT X
2720 IF S1<1 THEN PRINT:PRINT N$(V);" surrenders.  You got him!":CAUGHT=1:PLACE=0:FOR X=1 TO 2000:NEXT X
2730 RETURN
2740 PRINT
2750 IF L>1 THEN PRINT "He shoots at YOU!":GOTO 2800
2760 IF B<1 THEN PRINT "He's out of bullets and tries to get away!":RIN=1:DD=1:RETURN
2770 PRINT "He dodges to reload!":DD=1
2780 L=6:B=B-6:IF B<0 THEN L=L+B
2790 RETURN
2800 R=FNR(8)-4:HIT=(A(V)-DEX)+R
2810 IF DX=1 THEN HIT=HIT-INT(DEX/4)+RAN:DX=0
2820 PRINT:PRINT:PRINT TAB(20);"*** POW! ***":PRINT:FOR X=1 TO 100:NEXT X
2830 L=L-1
2840 IF HIT<1 THEN PRINT "He missed you!":FOR X=1 TO 1000:NEXT X:RETURN
2850 IF HORSE=2 AND FNR(10)=1 THEN PRINT:PRINT "He hit your horse and killed it!":HORSE=1:FOR X=1 TO 1000:NEXT X:RETURN
2860 PRINT "HE HIT YOU!!!!    OUCH!!!!"
2870 ST=ST-HIT:FOR X=1 TO 500:NEXT X
2880 IF ST<1 THEN PRINT:PRINT "You are now dead!":GOTO 6330
2890 PRINT:PRINT "Your stamina is now";ST;"."
2900 FOR X=1 TO 1000:NEXT X
2910 RETURN
2920 REM ****** inventory ******
2930 PRINT:PRINT "You are in possession of:"
2940 IF MONEY>0 THEN PRINT "Cash: $";MONEY
2950 IF FOOD>0 THEN PRINT "Food:  ";FOOD
2960 IF HORSE>1 THEN PRINT "A horse"
2970 IF ARTIFACT=1 THEN PRINT "An old Indian artifact"
2980 IF GUN=2 THEN PRINT "A Smith and Wesson" ELSE PRINT "A gun"
2990 IF BULLETS>0 THEN PRINT "  Bullets left:";BULLETS
3000 IF LOADED>0 THEN PRINT "  Bullets loaded:";LOADED
3010 IF CAUGHT=1 THEN PRINT N$(V)
3020 PRINT:PRINT "Your statistics are:"
3030 PRINT "Aim      :";AIM
3040 PRINT "Dexterity:";DEX
3050 PRINT "Stamina  :";ST
3060 PRINT:RETURN
3070 REM ****** load gun ******
3080 IF BULLETS<1 THEN PRINT:PRINT "You have no more bullets!":RETURN
3090 IF LOADED=6 THEN PRINT "Your gun is already loaded!":RETURN
3100 LL=6-LOADED
3110 IF BULLETS<LL THEN LL=BULLETS
3120 LOADED=LOADED+LL:BULLETS=BULLETS-LL
3130 PRINT:PRINT "Your gun is now loaded."
3140 RETURN
3150 REM ****** movement hazards ******
3160 ON FNR(11) GOTO 3170,3170,3220,3170,3170,3810,3170,3170,5960,3170,3170
3170 ON FNR(3) GOTO 3180,3190,3200
3180 PRINT:PRINT "A tumbleweed blows past you as you travel":PRINT "along.":RETURN
3190 PRINT:PRINT "A gentle breeze causes the fields to sway":PRINT "about you.":RETURN
3200 PRINT:PRINT "The hot sun flares down on you during your":PRINT "travel.":RETURN
3210 REM ****** indians! ******
3220 IF PEACE>0 THEN GOTO 3170
3230 PRINT:PRINT "Suddenly, a group of Indians come riding"
3240 PRINT "towards you yelling all sorts of war cries."
3250 PRINT:PRINT TAB(10);"E E E I I Y Y Y O O !!!"
3260 PRINT:PRINT "Will you 1..Try to make peace"
3270 PRINT "         2..Fight them"
3280 PRINT "         3..Try to get away"
3290 PRINT:INPUT "Your choice (1-3)";Q
3300 IF Q<1 OR Q>3 THEN 3260
3310 ON Q GOTO 3330,3410,3690
3320 REM *** try to make peace ***
3330 IF ARTIFACT<>1 THEN PRINT:PRINT "They refuse to make peace and attack!":GOTO 3410
3340 PRINT:PRINT "You hold up the Indian artifact you bought"
3350 PRINT "at the general store.  They pull to a halt near"
3360 IF HORSE=2 THEN PRINT "your horse "; ELSE PRINT "you ";
3370 PRINT "and take the artifact.  Then, grinning,"
3380 PRINT "the Indians go riding off into the hills."
3390 ARTIFACT=0:PEACE=7:RETURN
3400 REM *** fight ***
3410 IF BULLETS<1 AND LOADED<1 THEN PRINT "You have no bullets to fight with!":GOTO 3620
3420 PRINT:FOR X=1 TO 10:ON FNR(3) GOSUB 3460,3470,3480
3430 FOR Y=1 TO 150:NEXT Y
3440 NEXT X
3450 GOTO 3490
3460 PRINT TAB(FNR(7)*5);"Bang!!":RETURN
3470 PRINT TAB(FNR(7)*5);"Pow!!":RETURN
3480 PRINT TAB(FNR(7)*5);"Twang!!":RETURN
3490 X=FNR(10)+2:LOADED=LOADED-X
3500 IF LOADED<0 THEN BULLETS=BULLETS+LOADED:LOADED=0
3510 IF BULLETS<0 THEN 3610
3520 IF FNR(10)>1 THEN 3570
3530 IF HORSE<>2 THEN 3550
3540 PRINT:PRINT "A stray arrow kills your horse!":HORSE=1:GOTO 3570
3550 PRINT:PRINT "A stray arrow hits you!":ST=ST-FNR(4)
3560 IF ST>0 THEN PRINT "Your stamina is now";ST ELSE PRINT "YOU ARE DEAD!":GOTO 6330
3570 PRINT:PRINT "You killed them all!":BOOTY=FNR(10)+10
3580 PRINT "They were carrying $";BOOTY;"."
3590 MONEY=MONEY+BOOTY
3600 RETURN
3610 PRINT:PRINT "You ran out of bullets!"
3620 PRINT:PRINT "You try to run...":GOTO 3690
3630 FOR X=1 TO 1000:NEXT X
3640 PRINT TAB(5);"TWANG!!";:FOR X=1 TO 300:NEXT X
3650 FOR Y=1 TO 6:PRINT "--> ";:FOR X=1 TO 200:NEXT X:NEXT Y
3660 PRINT "THOCK!!":FOR X=1 TO 1000:NEXT X
3670 PRINT:PRINT "You have been gored by an arrow!":GOTO 6330
3680 REM *** run away to fight another day ***
3690 IF HORSE<>2 THEN PRINT:PRINT "On foot, your running does not take you far...":GOTO 3640
3700 X=FNR(10)+INT(DEX/3):IF X>9 THEN PRINT:PRINT "You got clean away.  Whew!!":RETURN
3710 IF FNR(10)<3 THEN 3770
3720 PRINT:PRINT "THOCK!!  An arrow hits you as you make your"
3730 PRINT "escape!"
3740 ST=ST-(FNR(3)+2):IF ST<1 THEN 3640
3750 PRINT "Your stamina is now";ST;"."
3760 RETURN
3770 PRINT:PRINT "THUNK!!  An arrow kills your horse as you escape!"
3780 HORSE=1
3790 RETURN
3800 REM *** the gambler ***
3810 PRINT:PRINT "You suddenly run across a stagecoach sitting"
3820 PRINT "unmoving in the middle of the plains.  Suddenly,"
3830 PRINT "A chubby head thrusts itself out of one of the"
3840 PRINT "windows and, spotting you, begins to speak."
3850 PRINT "  'How do you do!  I'm a gambler,' says the head."
3860 PRINT "How'd you like to step inside my office here and"
3870 PRINT "try your luck?'"
3880 PRINT "will you T)ry your luck or R)ide off";
3890 INPUT Q$:IF Q$="T" THEN 3930
3900 PRINT "  'Oh well.  Good day sir!' says the head as it"
3910 PRINT "retreats into the coach.":RETURN
3920 REM *** the gambling games ***
3930 IF MONEY<10 THEN PRINT:PRINT "  'You are too poor for me!' says the gambler.":RETURN
3940 ON FNR(3) GOTO 3960,4340,4760
3950 REM * russian rullet *
3960 NERVE=0
3970 PRINT:PRINT "  'This is a take all, lose all game called"
3980 PRINT "Russian Rullet,' says the gambler.  He takes a gun"
3990 PRINT "and loads one bullet in it.":X=FNR(6)
4000 PRINT "  'You can chicken out at any time but if you"
4010 PRINT "do, you lose $10!"
4020 PRINT "  'Just to prove I'm a sport, I'll let you go"
4030 PRINT "first,' he says, handing you the gun."
4040 PRINT:INPUT "Press <RETURN> to squeeze the trigger, Q to quit";Q$
4050 IF Q$<>"Q" THEN 4080
4060 PRINT:PRINT "  'Chicken,' chuckles the gambler as he collects"
4070 PRINT "his $10 from you.":MONEY=MONEY-10:RETURN
4080 Y=FNR(6):IF Y=X THEN 4230
4090 PRINT:PRINT TAB(20);"CLICK!":FOR Z=1 TO 500:NEXT Z
4100 PRINT:PRINT "Sweating, you hand the gun over to the gambler."
4110 PRINT "  'Your turn,' you say as he accepts the gun."
4120 FOR Z=1 TO 1000:NEXT Z
4130 NERVE=NERVE+1
4140 IF FNR(10)+NERVE<11 THEN 4180
4150 PRINT:PRINT "The gambler breaks down and, giving you $10,"
4160 PRINT "shoos you out of his stagecoach."
4170 MONEY=MONEY+10:RETURN
4180 Y=FNR(6):IF Y=X THEN 4270
4190 PRINT:PRINT TAB(20);"CLICK!":FOR Z=1 TO 500:NEXT Z
4200 PRINT:PRINT "Grinning, he hands the gun back to you."
4210 PRINT "  'Your turn now,' he says."
4220 GOTO 4040
4230 PRINT:PRINT TAB(16);"*** BANG! ***":PRINT
4240 FOR X=1 TO 1000:NEXT X:PRINT "You are dead!"
4250 PRINT "The gambler chuckles as he empties your pockets."
4260 GOTO 6330
4270 PRINT:PRINT TAB(16);"*** BANG! ***":PRINT
4280 FOR X=1 TO 1000:NEXT X:PRINT "The gambler falls to the floor dead."
4290 PRINT "You get his hoard of $";
4300 BOOTY=FNR(100)+100:PRINT BOOTY;"!"
4310 MONEY=MONEY+BOOTY
4320 RETURN
4330 REM * dice *
4340 PRINT:PRINT "  'Let's play craps!' says the gambler withdrawing"
4350 PRINT "a pair of dice from his coat pocket."
4360 PRINT "  'If you get a seven on your first roll, you win!"
4370 PRINT "If you get any other number on your first roll,"
4380 PRINT "you must roll that number again without rolling"
4390 PRINT "a seven.  If you roll a seven after you first"
4400 PRINT "roll of something else, you lose.  Easy!'"
4410 PRINT "  'The bet is $10.  Would you like to increase"
4420 PRINT "it?'":BET=10
4430 INPUT "S)tay with same bet, I)ncrease bet";Q$
4440 IF LEFT$(Q$,1)="S" THEN PRINT:PRINT "  'Very well.  ";:GOTO 4520
4450 PRINT:PRINT "You have $";MONEY;"in your money pouch."
4460 PRINT "  'How much do you increase the bet by?' inquires the gambler."
4470 INPUT "Increase";Q
4480 IF Q<0 THEN PRINT "  'You can't bet a negative amount!'":GOTO 4450
4490 IF MONEY-10<Q THEN PRINT "  'How can you bet with what you don't have?'":GOTO 4450
4500 BET=BET+Q:PRINT:PRINT "  'Very well.  The new betting amount is $";BET;","
4510 PRINT "says the gambler.  '";
4520 PRINT "Let us begin...'":ROLL=1:Y1=0:Z1=0
4530 PRINT:INPUT "Hit <RETURN> to roll the dice";Q$
4540 PRINT
4550 FOR X=1 TO 10:Y=FNR(6):Z=FNR(6)
4560 FOR A=1 TO 40*X:NEXT A
4570 IF X=10 THEN PRINT
4580 PRINT TAB(15);Y;" - ";Z;
4590 IF X=10 THEN PRINT "=";Y+Z ELSE PRINT
4600 NEXT X
4610 FOR X=1 TO 500:NEXT
4620 IF ROLL=1 AND Y+Z=7 THEN 4710
4630 IF Y1+Z1=Y+Z THEN 4710
4640 IF ROLL>1 AND Y+Z=7 THEN 4680
4650 IF ROLL=1 THEN Y1=Y:Z1=Z:ROLL=ROLL+1
4660 PRINT:PRINT "  'Your match total is";Y1+Z1;".  Roll again'"
4670 GOTO 4530
4680 PRINT:PRINT "  'You lose!' cries the gambler, grabbing your"
4690 PRINT "money.  You leave $";BET;"poorer."
4700 MONEY=MONEY-BET:RETURN
4710 PRINT:PRINT "  'You win!' growles the gambler giving you a"
4720 PRINT "nasty look.  'Take your money and get out!'
4730 PRINT "You leave $";BET;"richer."
4740 MONEY=MONEY+BET:RETURN
4750 REM * 21 *
4760 PRINT:PRINT "  'This is a game called 21,' says the gambler,"
4770 PRINT "saliva dripping from his chin."
4780 PRINT "  'With cards, you try to get them to total as"
4790 PRINT "close to 21 as possible without going over."
4800 PRINT "If your total is higher than mine, you win."
4810 PRINT "If I bust (which is highly unlikely), you win."
4820 PRINT "If your total is equal to mine, we play again."
4830 PRINT "If your total is less than mine or you go"
4840 PRINT "over 21, I WIN!
4850 PRINT "  'Jacks, Kings, and Queens count as 10.  Aces"
4860 PRINT "count as either 11 or 1 depending on your hand."
4870 PRINT "Number cards count their face value.'"
4880 PRINT "  'On your turn you can increase the bet and then"
4890 PRINT "either Hit (get another card) or Stay with what"
4900 PRINT "you have for the rest of the game.'"
4910 PRINT:INPUT "Hit <RETURN> to start the game";Q$
4920 PRINT:PRINT "The initial bet is $10.":BET=10:TIE=0
4930 PRINT:PRINT "  'I'll deal the cards,' grins the gambler."
4940 FOR X=1 TO 52:PACK(X)=0:NEXT X:S$=""
4950 REM *** mix ***
4960 FOR X=1 TO 52
4970 Y=FNR(52):IF PACK(Y)<>0 THEN 4970
4980 PACK(Y)=X
4990 NEXT X
5000 REM *** setup hands ***
5010 FOR X=1 TO 2:YH(X)=PACK(X):GH(X)=PACK(X+2):NEXT X
5020 Y=2:G=2
5030 GOSUB 5680:GOSUB 5860
5040 REM *** game routine ***
5050 GOSUB 5060:GOTO 5190
5060 PRINT:PRINT "My hand";TAB(20);"Your hand"
5070 PRINT "-------";TAB(20);"---------"
5080 IF Y>G THEN Z=Y ELSE Z=G
5090 FOR X=1 TO Z
5100 IF X=1 THEN PRINT "XXX of XXXXXX";:GOTO 5130
5110 IF X>G THEN PRINT;:GOTO 5130
5120 PRINT DECK$(GH(X));
5130 IF X>Y THEN PRINT:GOTO 5150
5140 PRINT TAB(20);DECK$(YH(X))
5150 NEXT X
5160 PRINT:PRINT TAB(20);"Total:";TOTAL
5170 FOR X=1 TO 1000:NEXT X
5180 RETURN
5190 IF MONEY=BET THEN IF LEFT$(S$,1)="S" THEN 5420 ELSE 5330
5200 PRINT:PRINT "  'The bet is $";BET;".'"
5210 PRINT "  'Would you like to increase the bet?' asks the"
5220 INPUT "gambler.  Y)es or N)o";Q$
5230 IF Q$<>"Y" THEN 5310
5240 PRINT:PRINT "Your money pouch holds $";MONEY
5250 PRINT "  'How much do you want to increase it by?'"
5260 INPUT "Increase";Q
5270 IF Q<0 THEN PRINT:PRINT "  'You cannot bet a negative amount!'":GOTO 5210
5280 IF Q>MONEY+10 THEN PRINT:PRINT "  'You don't have that much money!'":GOTO 5210
5290 BET=BET+Q
5300 PRINT:PRINT "  'Very well.  The bet is now $";BET
5310 IF LEFT$(S$,1)="S" THEN 5420
5320 GOSUB 5060
5330 PRINT:INPUT "H)it or S)tay";S$
5340 IF LEFT$(S$,1)="S" THEN 5420
5350 Y=Y+1:YH(Y)=PACK(Y+G)
5360 GOSUB 5680:GOSUB 5060
5370 IF TOTAL<22 THEN 5420
5380 PRINT:PRINT "  'You busted!!!' cries the gambler as he scoops"
5390 PRINT "up your money.  'So long sucker!'"
5400 MONEY=MONEY-BET
5410 RETURN
5420 PRINT:PRINT "  'My turn,' grumbles the gambler."
5430 FOR X=1 TO 1000:NEXT X
5440 IF TOT<18 THEN 5490
5450 IF TOT<=FTOT THEN 5490
5460 PRINT:PRINT "  'I'll stay,' he says confidently."
5470 IF LEFT$(S$,1)="S" THEN 5600
5480 GOTO 5050
5490 PRINT:PRINT "  'I'll take a card,' he says."
5500 G=G+1:GH(G)=PACK(G+Y)
5510 GOSUB 5860:GOSUB 5060
5520 IF TOT<22 THEN PRINT:PRINT "  'Your turn.'":GOTO 5050
5530 PRINT:PRINT "My hand":PRINT "-------"
5540 FOR X=1 TO G:PRINT DECK$(GH(X)):NEXT X
5550 PRINT:PRINT "Total:";TOT
5560 PRINT:PRINT "  'I busted???' he screams in disbelief.  Chuckling,"
5570 PRINT "you scoop up your winnings and make a hasty"
5580 PRINT "retreat."
5590 MONEY=MONEY+BET:RETURN
5600 PRINT:PRINT "  'Let's compare totals,' says the gambler."
5610 FOR X=1 TO 1000:NEXT X
5620 PRINT:PRINT "  'My total is";TOT;"and your total is";TOTAL;"."
5630 IF TOT=TOTAL THEN PRINT:PRINT "  'It's a tie!  We must play again.'":TIE=1:GOTO 4930
5640 IF TOT>TOTAL THEN PRINT:PRINT "  'I win!' cries the gambler as he scoops":GOTO 5390
5650 PRINT:PRINT "  'You win???' cries the gambler in disbelief as"
5660 GOTO 5570
5670 REM *** your hand total ***
5680 YES=0:TOTAL=0:FOR X=1 TO Y
5690 TOTAL=TOTAL+V(YH(X))
5700 IF V(YH(X))=11 THEN YES=YES+1
5710 NEXT X
5720 IF TOTAL<22 THEN 5760
5730 IF YES<1 THEN 5760
5740 YES=YES-1:TOTAL=TOTAL-10
5750 GOTO 5720
5760 YES=0:FTOT=0:FOR X=2 TO Y
5770 FTOT=FTOT+V(YH(X))
5780 IF V(YH(X))=11 THEN YES=YES+1
5790 NEXT X
5800 IF FTOT<22 THEN 5840
5810 IF YES<1 THEN 5840
5820 YES=YES-1:FTOT=FTOT-10
5830 GOTO 5800
5840 RETURN
5850 REM *** gambler hand total ***
5860 YES=0:TOT=0:FOR X=1 TO G
5870 TOT=TOT+V(GH(X))
5880 IF V(GH(X))=11 THEN YES=YES+1
5890 NEXT X
5900 IF TOT<22 THEN 5940
5910 IF YES<1 THEN 5940
5920 YES=YES-1:TOT=TOT-10
5930 GOTO 5900
5940 RETURN
5950 REM *** dust storm! ***
5960 PRINT:PRINT "Suddenly, a dust storm appears throwing your"
5970 PRINT "entire sense of direction off..."
5980 FOR X=1 TO 2000:NEXT X
5990 PRINT:PRINT TAB(10);"W H O O O O S S H H !"
6000 FOR X=1 TO 1000:NEXT X:PRINT
6010 ON FNR(4) GOTO 6020,6050,6080,6110
6020 I=I+1:IF I>10 THEN I=10:GOTO 6010
6030 IF MAP(I,J)=1 THEN I=I-1:GOTO 6010
6040 GOTO 6130
6050 I=I-1:IF I<1 THEN I=1:GOTO 6010
6060 IF MAP(I,J)=1 THEN I=I+1:GOTO 6010
6070 GOTO 6130
6080 J=J-1:IF J<1 THEN J=1:GOTO 6010
6090 IF MAP(I,J)=1 THEN J=J+1:GOTO 6010
6100 GOTO 6130
6110 J=J+1:IF J>10 THEN J=10:GOTO 6010
6120 IF MAP(I,J)=1 THEN J=J-1:GOTO 6010
6130 GOSUB 6150:RETURN
6140 REM ****** map of the old west ******
6150 FOR X=1 TO 10:FOR Y=1 TO 10
6160 IF I=X AND J=Y THEN PRINT "H ";:GOTO 6180
6170 PRINT OBJ$(MAP(X,Y));
6180 NEXT Y
6190 ON X GOSUB 6220,6230,6240,6250,6260,6270,6280,6290,6300,6310
6200 NEXT X
6210 RETURN
6220 PRINT "    KEY:":RETURN
6230 PRINT "    . = Empty Space":RETURN
6240 PRINT "    H = The Bounty Hunter (You)":RETURN
6250 PRINT "    Y = Cactus":RETURN
6260 PRINT "    T = Town of Dusty Gulch":RETURN
6270 PRINT "    C = Dark Cave":RETURN
6280 PRINT "    S = Old Shack":RETURN
6290 PRINT "    M = Old Mine":RETURN
6300 PRINT "    V = Abandoned Village":RETURN
6310 PRINT:RETURN
6320 REM ****** end of game ******
6330 PRINT:PRINT "Your final score was";SCORE;"."
6340 PRINT:PRINT:PRINT:PRINT TAB(20);"GAME OVER"
6350 END
6360 CLS:PRINT TAB(34);"Bounty Hunter"
6370 PRINT TAB(28);"Adventure in the Old West"
6380 PRINT:PRINT:PRINT "Welcome to the old west, partner!"
6390 PRINT:PRINT "In this game, you are a bounty hunter trying to capture and bring back"
6400 PRINT "criminals for bucks."
6410 PRINT:PRINT "To do this, you must first visit the jail in the town of Dusty Gulch"
6420 PRINT "and look at the wanted poster to see who to go after."
6430 PRINT "Then, saddling up your trusty horse (if it hasn't been killed), you take"
6440 PRINT "out across the old west to the site where the criminal was last seen."
6450 PRINT:PRINT "At the site, you and the criminal will engage in a rootin-tootin gun fight"
6460 PRINT "which will end in your death, his surrender, or one of you running away."
6470 PRINT:PRINT "Then, all you have to do is carry the criminal back to the jail, get your"
6480 PRINT "reward money, and look at the next wanted poster."
6490 PRINT:PRINT:INPUT "Hit <RETURN> to continue";R$
6500 CLS
6510 PRINT "ABILITIES"
6520 PRINT:PRINT:PRINT "Your character has 3 abilities: his aim, his dexterity, and his stamina"
6530 PRINT:PRINT "AIM       - This is your ability to shoot accurately.  The higher your aim"
6540 PRINT "            score, the better chance you have of hitting something."
6550 PRINT "DEXTERITY - This is your ability to dodge bullets.  The higher this score is,"
6560 PRINT "            the less chance you have of getting shot."
6570 PRINT "STAMINA   - This is your hit point score.  Every time you are shot, a"
6580 PRINT "            certain number of points are deducted from this total.  If it"
6590 PRINT "            should reach 0, you will die."
6600 PRINT:PRINT "At the beginning of the game, each of these abilities will be set at 10"
6610 PRINT "You will then be given a number of points to distribute to them in any way"
6620 PRINT "you want.  Distribute them wisely"
6630 PRINT:PRINT "Each of the criminals also has those 3 abilities only you don't know"
6640 PRINT "what they are."
6650 PRINT "Each time you bring a criminal in, one of his abilities goes up by 1 point so"
6660 PRINT "if he should escape, he will be harder to capture."
6670 PRINT:PRINT:INPUT "Hit <RETURN> to continue";R$
6680 CLS
6690 PRINT "DUSTY GULCH INN"
6700 PRINT:PRINT:PRINT "Should your stamina get low, you can visit the inn and for the low,"
6710 PRINT "low cost of $10 you can get a hot meal and a place to sleep"
6720 PRINT:PRINT "This will increase your stamina by a certain number of points."
6730 PRINT:PRINT:INPUT "Hit <RETURN> to continue";R$
6740 CLS
6750 PRINT "DUSTY GULCH GENERAL STORE"
6760 PRINT:PRINT:PRINT "At the general store, you can buy things with your reward money"
6770 PRINT:PRINT "Bullets          - Your gun needs bullets to shoot."
6780 PRINT "Smith and Wesson - A better gun than the one you own in that it is more"
6790 PRINT "                   accurate."
6800 PRINT "Food             - You must eat to keep your stamina up."
6810 PRINT "Riding Horse     - Should your horse get killed, you may want another one."
6820 PRINT "Indian Artifact  - It's been said that artifacts calm the savage Indian."
6830 PRINT:PRINT:INPUT "Hit <RETURN> to continue";R$
6840 CLS
6850 PRINT "DUSTY GULCH JAIL"
6860 PRINT:PRINT:PRINT "Here is where you will find wanted posters."
6870 PRINT "Here is where you bring criminals for reward money."
6880 PRINT:PRINT "Should you have to escape from a criminal, come back here and a new"
6890 PRINT "wanted poster will be up."
6900 PRINT:PRINT:PRINT:PRINT
6910 PRINT "DUSTY GULCH TRAINING CENTER"
6920 PRINT:PRINT:PRINT "Here you can improve your abilities, for the right price."
6930 PRINT:PRINT:INPUT "Hit <RETURN> to continue";R$
6940 CLS
6950 PRINT "MOVEMENT EFFECTS"
6960 PRINT:PRINT:PRINT "Moving across the old west can result in one of the following:"
6970 PRINT:PRINT "NOTHING    - nothing happens"
6980 PRINT "DUST STORM - A dust storm appears out of nowhere sending you off in a random"
6990 PRINT "             direction."
7000 PRINT "INDIANS    - Indians can attack at any time.  Just a lot of bullets is needed"
7010 PRINT "             to fend them off, though.  Once peace is made, they will not"
7020 PRINT "             attack for 3 days."
7030 PRINT "GAMBLER    - A gambler in a stagecoach is also moving through the old west,"
7040 PRINT "             should you care to try your luck."
7050 PRINT:PRINT "Four moves constitute one day."
7060 PRINT:PRINT:INPUT "Hit <RETURN> to continue";R$
7070 GOSUB 7080:GOTO 7190
7080 CLS
7090 PRINT "COMMANDS:"
7100 PRINT:PRINT "N, S, E, W - Movement commands (N = North, E = East, etc.)"
7110 PRINT "I)NVENTORY - To get an inventory of your possessions and a listing"
7120 PRINT "             of your attributes"
7130 PRINT "L)OAD      - Your gun only holds 6 bullets which are discharged at criminals"
7140 PRINT "             and Indians and so must be reloaded frequently."
7150 PRINT "M)AP       - A map of the old west"
7160 PRINT:PRINT "When confronting a criminal, you will be given a new set of commands."
7170 PRINT "The ones above cannot be used until after the fight."
7180 RETURN
7190 PRINT:PRINT:INPUT "Hit <RETURN> to continue";R$
7200 CLS
7210 PRINT "GENERAL"
7220 PRINT:PRINT:PRINT "1 unit of food is automatically deducted at the end of each day."
7230 PRINT:PRINT "You can only walk one space at a time but with a horse you can move"
7240 PRINT "up to 2 spaces."
7250 PRINT:PRINT:PRINT "Well partner, strap on your six shooter and prepare to fight criminals"
7260 PRINT "in the old west."
7270 PRINT:PRINT:INPUT "Hit <RETURN> to start the game";R$
7280 RETURN
7290 REM ---------- OUT OF MEMORY ERROR TRAP
7300 IF ERR<>7 THEN ON ERROR GOTO 0
7310 GOSUB 6150:PRINT
7320 RESUME 1100