class RandomWeekly extends KFGameInfo_WeeklySurvival;

static event class<GameInfo> SetGameType( string MapName, string Options, string Portal )
{
    return default.class;
}

function CreateOutbreakEvent()
{
    super(KFGameInfo).CreateOutbreakEvent();
}

function WaveStarted()
{
    local byte RandomEvent;
    local string PrimaryMessage, SecondaryMessage;
    local KFPlayerController KFPC;
    local KFWeeklyOutbreakInformation WeeklyInfo;

    super.WaveStarted();

    KFPC = KFPlayerController( MyKFGRI.GetALocalPlayerController() );

    RandomEvent = Rand(8);

    OutbreakEvent.SetActiveEvent( RandomEvent );

    if ( KFPC != None && KFPC.MyGFxHUD != None && KFPC.MyGFxManager != None )
    {
        WeeklyInfo = class'KFMission_LocalizedStrings'.static.GetWeeklyOutbreakInfoByIndex( RandomEvent );

        PrimaryMessage = WeeklyInfo.FriendlyName;
        SecondaryMessage = WeeklyInfo.DescriptionStrings[0];

        KFPC.MyGFxManager.QueueDelayedPriorityMessage( PrimaryMessage, SecondaryMessage, 5.f );
    }
}

function byte GetWaveStartMessage()
{
    if ( OutbreakEvent != None  )
    {
        return GMT_WaveStartWeekly;
    }

    return super.GetWaveStartMessage();
}

function WaveEnded( EWaveEndCondition WinCondition )
{
    local KFPawn KFP;

    super.WaveEnded( WinCondition );

    OutbreakEvent.ClearActiveEvent();

    foreach WorldInfo.AllPawns( class'KFPawn', KFP )
    {
        KFP.IntendedBodyScale = 1.f;
    }
}

function bool UsesModifiedDifficulty()
{
    return false;
}

function bool UsesModifiedLength()
{
    return false;
}