FM Synthesis | FM Basics (Part 6)

/////////////////////// FM SYNTHESIS | FM Basics (Part 6) ///////////////////////
/////////////////////////////// Env Perc ////////////////////////////////


s.boot;

// Run these methods below for visual cues.

s.meter;
s.scope;
s.plotTree;

// I use the following only when necessary.

s.reboot;
s.quit;

////////////////// Things To Know Before Running Code //////////////////

/*

All my original SC documents are in the "dracula" color.
To find or change this, go To SuperCollider ––> Preferences ––> Editor ––> Font & Colors.
––> Select under Color, dracula.

Arguments in Synths are represented with a backslash, "\", in green under the "dracula" color font. Values presented with these arguments can be changed. Only remember to NEVER cross 0, when using an exponential method like "exprand."

Arguments also precede a colon ":", as seen in a list of a UGen following a variable, "var."
Example: sig = PlayBuf.ar(2, buf, rate, startPos: spos);

Argument and variable names can be changed to your liking.

Please be careful with volume output. Always have SuperCollider run through headphones. If you're unsure what the output will be, keep headphones away, with your main volume all the way down. Check your level meter and Stethoscope for visual cues. If everything looks safe (e.g. level meter is NOT in the red), proceed.

You can always execute a hard stop with Command Period.

*/

///////////////////////  Syntax For Locating Sound Files In Folders ///////////////////////

~bufPath = PathName.new(thisProcess.nowExecutingPath).parentPath ++ "ambient"; // <-- insert your sound folder, in place of where my "ambient" folder is. Your folder can have any name.


(
b = PathName.new(~bufPath).entries.collect({
    arg pathname;
    Buffer.read(s, pathname.fullPath);
});
)


// Make sure your soundfiles play back. You should see it on the scope and level meters.

// I have 3 files in my "ambient" Folder. Thus, I have below: b[0], b[1], b[2].
// 0, being the first sound file indexed in my Folder.

b[0].play; // Change between b[0], b[1], b[2].

b[0].duration;
b[0].numChannels;
b[0].sampleRate;
b[0].numFrames;



Env([0, 1, 0], [0.01, 3], [1, -5]).plot; // Envelope shape to reference.
// First array, [0, 1, 0], are levels.
// Second array, [0.01, 3], are times traversing between levels.
// Third array, [1, -5], are curve values.


// Sine Tone

(
SynthDef.new(\sine, {
    arg atk=0.01, rel=3, c1=1, c2=(-5),
    freq=400, amp=0.5, out=0; // Be careful with amp values (0-1).
    var sig, sine, env;
    env = Env([0, 1, 0], [atk, rel], [c1, c2]).kr(2); // Env().kr(2) is a shortcut for "doneAction: 2"
    sig = SinOsc.ar(freq);
    sig = sig * env * amp;
    sig = sig!2;
    Out.ar(out, sig);
}).add;
)

Synth(\sine);

// Add an Env.perc for short, sharp sounds.

Env.perc(0.001, 1, 1, -3).plot; // Env with a very sharp attack
// Env.perc(attackTime, releaseTime, level, curve)

(
SynthDef.new(\sine, {
    arg freq=400, amp=0.2, gate=1, out=0;
    var sig, sine, env;
    env = EnvGen.ar(
        Env.perc(0.001, 1, 1, -3),
        gate,
        doneAction: 2
    );
    sig = SinOsc.ar(freq);
    sig = sig * env * amp;
    sig = sig!2;
    Out.ar(out, sig);
}).add;
)

Synth(\sine, [\freq, rrand(200, 800)]);
// Randomly selects frequencies between 200 and 800Hz

---------------------------------------------------------------

// Sound Files

Env([0, 1, 0], [0.1, 8], [1, -2]).plot;

(
SynthDef.new(\sound, {
    arg buf=0, rate=1, spos=0, amp=1, pan=0,
    atk=0.01, rel=8, c1=1, c2=(-2), out=0;
    var sig, par, env;
    env = Env([0, 1, 0], [atk, rel], [c1, c2]).kr(2);
    par = LFPar.ar(LFPar.kr(0.25, 0, 8, 10), 0, 0.8);
    sig = PlayBuf.ar(
        2,
        buf,
        BufRateScale.kr(buf) * rate,
        spos
    );
    sig = sig * par * env;
    sig = Pan2.ar(sig, pan, amp);
    Out.ar(out, sig);
}).add;
)

Synth(\sound, [\buf, b[0]]);


// Add an Env.perc for short, sharp sounds.

Env.perc(0.001, 1, 1, -3).plot;
// Note: My b[1], b[2] in the Folder have the best attacks.
// See which sound files in your Folders have the best attacks.


(
SynthDef.new(\sound, {
    arg buf=0, rate=1, spos=0,
    amp=1, pan=0, gate=1, out=0;
    var sig, par, env;
    env = EnvGen.ar(
        Env.perc(0.001, 1, 1, -3),
        gate,
        doneAction: 2
    );
    par = LFPar.ar(LFPar.kr(0.25, 0, 9, 12), 0, 0.8);
    sig = PlayBuf.ar(
        2,
        buf,
        BufRateScale.kr(buf) * rate,
        spos
    );
    sig = sig * par * env;
    sig = Pan2.ar(sig, pan, amp);
    Out.ar(out, sig);
}).add;
)

(
Synth(\sound, [
    \buf, b[1],
    \amp, rrand(0.1, 1),
    \rate, rrand(0, 24).midiratio
]);
)