Image Viewer

;ImageViewer Script
;Made by nick1
;Last edit November 18 2012

alias GetPic {
  SockOpen GetPic %download.host 80
}
On *:sockopen:getpic*:{
  sockwrite -nt $sockname GET %download.link HTTP/1.1
  sockwrite -nt $sockname Host: %download.host
  ;echo -a GET %download.link from %download.host for %download.img
  sockwrite -nt $sockname
}
on *:sockread:getpic*:{
  if (!$sock($sockname).mark) {
    var %SockReader
    sockread %SockReader
    if (%SockReader == $null) {
      sockmark $sockname 1
      .timerclose $+ $sockname 1 5 imagetimeout $sockname
    }
  }
  else {
    sockread &picture
    .bwrite $qt($mIRCDirDownloads\ $+ %download.img) -1 -1 &picture
  }
}

alias imagetimeout {
  sockclose $1-
  showpic
}

on *:sockclose:getpic*: {
  .timerclose $+ $sockname off
  showpic
}
Alias ShowPic {
  var %file $qt($mIRCDirDownloads\ $+ %download.img)
  var %w $pic(%file).width
  var %h $pic(%file).height
  if (%w == 0) {
    .remove %file
    halt
  }
  else {
    var %win $+(@,%download.img,-,$chr(40),%w,x,%h,$chr(41))
    window -dCpk0 %win -1 -1 %w $calc(%h + 28)
    .timer 1 120 .remove %file
    drawpic %win -1 -1 %file
  }
}

on $^*:HOTLINK:/(?:http\x3A\/\/)?(.+?\.\w{2,})(\/.+\.(?:jpg|gif|png))($| )/Si:*:{
  if ($mouse.key & 1) {
    if (!$sock(getpic)) {
      var %a $remove($1,http://,https://)
      ;BEGIN SPECIAL LINK REPLACEMENT
      var %a $replace(%a,/v/,/e/)
      ;END SPECIAL LINK REPLACEMENT
      set %download.link $+(/,$gettok(%a,2-,47))
      set %download.host $gettok(%a,1,47)
      set %download.img $gettok(%a,$numtok(%a,47),47)
      if (!$file($qt($mIRCDirDownloads\ $+ %download.img))) {
        getpic
      }
    }
  }
}

on *:HOTLINK:/(?:http\x3A\/\/)?(.+?\.\w{2,})(\/.+\.(?:jpg|gif|png|jpeg))($| )/Si:*:{
  url $1
}