Server Roles List

Trigger: Any Trigger you want

$nomention
$reply
$allowUserMentions[]

$c[⁠ ▽ If you want to use this code you'll need an API key ▽ ]
$c[ ▽ Visit -> https://dadocs.rickyjs.xyz/ for more information ▽ ]

$var[prev-arrow.emoji;<:Meow_PreviousPage:1179715759069470741>]
$var[next-arrow.emoji;<:Meow_NextPage:1179715792292560977>]
$var[last-arrow.emoji;<:Meow_LastPage:1179715820763500605>]
$var[first-arrow.emoji;<:Meow_FirstPage:1179715724013477898>]

$var[note.emoji;📝]
$var[cross.emoji;❌]

$var[color;84e7e2]

$if[$guildID==]
    $var[cross.emoji] You cant use this in dms!
    $stop
$endif

$if[$isSlash==true]
    $defer
$else
    $botTyping
$endif

$var[key;$getVar[ApiKey]]
$var[token;$getVar[BotToken]]

$httpAddHeader[guild-id;$guildID]
$httpAddHeader[apikey;$var[key]]
$httpAddHeader[bot-token;$var[token]]

 $httpGet[https://bdfddata.rickyjs.xyz/release/guild/roles]
 $jsonParse[$httpResult]

$async[]
  $httpGet[https://bdfddata.rickyjs.xyz/release/guild/members]
  $var[mems;$httpResult]
$endasync $await[]

$var[h;1]
$var[sep;$url[decode;%0A]]
$var[roles;$eval[$repeatMessage[10;%{DOL}%if[%{DOL}%json[details\;%{DOL}%var[h\]\;id\]!=\]%{DOL}%var[h\]. <@&%{DOL}%json[details\;%{DOL}%var[h\]\;id\]> - %{DOL}%textSplit[%{DOL}%var[mems\]\;%{DOL}%json[details\;%{DOL}%var[h\]\;id\]\]%{DOL}%var[r.%{DOL}%var[h\]\;%{DOL}%sub[%{DOL}%getTextSplitLength\;1\]\] **%{DOL}%var[r.%{DOL}%var[h\]\] %{DOL}%if[%{DOL}%var[r.%{DOL}%var[h\]\]==1\]Member%{DOL}%elseMembers%{DOL}%endif**%{DOL}%var[sep\]%{DOL}%else %{DOL}%stop%{DOL}%endif%{DOL}%var[h\;%{DOL}%sum[1\;%{DOL}%var[h\]\]\]]]]

$var[guild.roles.count;$sub[$roleCount;1]]

$enableDecimals[true]
$var[div;$divide[$var[guild.roles.count];10]]

$if[$checkContains[$var[div];.]==true]
    $textSplit[$var[div];.]
    $var[total.pages;$sum[1;$splitText[1]]]
$else
    $var[total.pages;$var[div]]
$endif

$title[Server Roles ($var[guild.roles.count])]
$description[$var[roles]]
$color[$var[color]]
$footer[Page 1/$var[total.pages]]

$addButton[no;GuildRolesList-$authorID-FirstPage;;primary;yes;$var[first-arrow.emoji]]
$addButton[no;GuildRolesList-$authorID-PrevPage;;primary;yes;$var[prev-arrow.emoji]]
$addButton[no;GuildRolesListModal-$authorID-CustomPageModal;;secondary;no;$var[note.emoji]]
$addButton[no;GuildRolesList-$authorID-NextPage;;primary;$checkCondition[$var[total.pages]==1];$var[next-arrow.emoji]]
$addButton[no;GuildRolesList-$authorID-LastPage;;primary;$checkCondition[$var[total.pages]==1];$var[last-arrow.emoji]]