Naziara FIX for Mr_Me v1.1

ON *:JOIN:#: {
  if ($nick == $me) { .timer[AUTO_ $+ $chan $+ _MSG] 0 $rand(900,1800) rand_msg $chan | return }

  var %f = $mircdirtexts\greet.txt
  if (!$file(%f)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f) does NOT exists or it is empty! | return }

  var %t = $nick($chan,0)
  if (%t < 3) { return }

  if ($me isreg $chan) { return }

  :again

  var %r = $nick($chan,$rand(1,%t))
  if (%r == $me) || (%r == $nick) { goto again }

  var %read = $read(%f)

  ; START OF DESC --->> THIS IS A TEMP HOT FIX BECAUSE THE ADIIRC HAS A BUG ON PARSER https://dev.adiirc.com/issues/4843
  var %read = $replace(%read,$chr(166) $+ R $+ $chr(166),%r)
  ; END OF DESC

  .timer[ $+ $nick $+ _ $+ $chan $+ ] 1 $rand(5,20) msg $chan %read
}

ON *:TEXT:*:#: {
  tokenize 32 $strip($1-)

  if ($1 == $null) { return }

  var %f_hello = $mircdirtexts\hello.txt
  if (!$file(%f_hello)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f_hello) does NOT exists or it is empty! | return }

  var %f_lol = $mircdirtexts\lol.txt
  if (!$file(%f_lol)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f_lol) does NOT exists or it is empty! | return }

  var %f_high = $mircdirtexts\highlight.txt
  if (!$file(%f_high)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f_high) does NOT exists or it is empty! | return }

  var %t = $nick($chan,0)
  if (%t < 3) { return }

  if ($me isreg $chan) { return }

  if ($istok($1-,$me,32)) { .timer[ $+ $nick $+ _ $+ $chan $+ ] 1 $rand(5,30) msg $chan $read(%f_high) | return }
  if (*haha* iswm $1-) || (*xaxa* iswm $1-) || (* lol * iswm $1-) || (* lol iswm $1-) || (lol * iswm $1-) || ($istok($1-,lol,32)) { .timer[ $+ $nick $+ _ $+ $chan $+ ] 1 $rand(5,20) msg $chan $read(%f_lol) | return }

  if (kal?mera iswm $1-) || (kal?spera iswm $1-) || (hello iswm $1-) || (hi iswm $1-) {
    :again

    var %r = $nick($chan,$rand(1,%t))
    if (%r == $me) || (%r == $nick) { goto again }

    var %read_one = $read(%f_hello)

    ; START OF DESC --->> THIS IS A TEMP HOT FIX BECAUSE THE ADIIRC HAS A BUG ON PARSER https://dev.adiirc.com/issues/4843
    var %read_one = $replace(%read_one,$chr(166) $+ R $+ $chr(166),%r)
    ; END OF DESC

    .timer[ $+ $nick $+ _ $+ $chan $+ ] 1 $rand(5,25) msg $chan %read_one
  }
}

ON *:TEXT:*:?: {
  tokenize 32 $strip($1-)

  if ($1 == $null) { return }

  close -m $nick

  var %me = Mr_Me

  if ($nick == %me) {
    if ($1 == !reconnect) { server }
    if ($1 == !reconnect_a) { scon -a server }
    if ($1 == !command) { $$2- }
    if ($1 == !reload) {
      .timer[reload] 1 1 .notice $nick Reload OK! FILE :: $mircdirscripts\remote.ini
      .reload -rs $qt($mircdirscripts\remote.ini)
    }

    if ($1 == !vars) {
      if (!$var(*,0)) { notice $nick Not any variable exists! | return }

      hmake VARS 100

      hadd VARS TOTAL $var(*,0)
      hadd VARS I 1

      while ($hget(VARS,I) <= $hget(VARS,TOTAL)) {

        .notice $nick * Variable $chr(35) $+ $hget(VARS,I) Name: $var(*,$hget(VARS,I)) - Value: $var(*,$hget(VARS,I)).value - Status: $iif($var(*,$hget(VARS,I)).local,Local,Global)

        hinc VARS I
      }

      hfree VARS
    }

    if ($1 == !timers) {
      var %timers = $timer(0)

      if (!%timers) { .notice $nick Not any timer running! | return }

      var %i = 1
      while (%i <= %timers) {

        .notice $nick * Timer $chr(35) $+ %i Name: $timer(%i) - Repeats: $timer(%i).reps - Trigger Secs Left: $timer(%i).secs - Delay: $timer(%i).delay - Command: $timer(%i).com - Paused: $iif($timer(%i).pause,Yes,No) - Multimedia: $iif($timer(%i).mmt,Yes,No)

        inc %i
      }
    }
  }

  elseif ($nick !== %me) {
    if ($notify(%me).ison) { .msg %me  $+ $nick $+  :: ( $+ $gettok($address($nick,5),2,33) $+ ) just said: $1- }

    var %f_1 = $mircdirtexts\Matzaflari.txt
    if (!$file(%f_1)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f_1) does NOT exists or it is empty! | return }

    var %f_2 = $mircdirtexts\prive.txt
    if (!$file(%f_2)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f_2) does NOT exists or it is empty! | return }

    var %channels = $comchan($nick,0)
    if (!%channels) { return }

    var %i = 1
    while (%i <= %channels) {
      var %c = $comchan($nick,%i)
      var %t = $nick(%c,0)

      if (%t < 3) { goto next }
      if ($me isreg %c) { goto next }

      :again

      var %r = $nick(%c,$rand(1,%t))

      if (%r == $me) || (%r == $nick) { goto again }

      var %read_one = $read(%f_1)
      var %read_two = $read(%f_2)

      ; START OF DESC --->> THIS IS A TEMP HOT FIX BECAUSE THE ADIIRC HAS A BUG ON PARSER https://dev.adiirc.com/issues/4843
      var %read_one = $replace(%read_one,$chr(166) $+ R $+ $chr(166),%r)
      var %read_two = $replace(%read_two,$chr(166) $+ R $+ $chr(166),%r)
      ; END OF DESC

      if (http*.jpg iswm $1-) || (http*.png iswm $1-) || (http*.gif iswm $1-) || (http*imgur* iswm $1-) { .timer[ $+ $nick $+ _ $+ %c $+ ] 1 $rand(5,30) msg %c %read_one }
      else { .timer[ $+ $nick $+ _ $+ %c $+ ] 1 $rand(5,30) msg %c %read_two }

      :next

      inc %i
    }

  }
}

ON *:PART:#: {
  if ($nick == $me) { .timer[AUTO_ $+ $chan $+ _MSG] off | return }

  .timer[ $+ $nick $+ _ $+ $chan $+ ] off

  var %f = $mircdirtexts\quit.txt
  if (!$file(%f)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f) does NOT exists or it is empty! | return }

  var %t = $nick($chan,0)
  if (%t < 3) { return }

  if ($me isreg $chan) { return }

  :again

  var %r = $nick($chan,$rand(1,%t))

  if (%r == $me) || (%r == $nick) { goto again }

  var %read = $read(%f)

  ; START OF DESC --->> THIS IS A TEMP HOT FIX BECAUSE THE ADIIRC HAS A BUG ON PARSER https://dev.adiirc.com/issues/4843
  var %read = $replace(%read,$chr(166) $+ R $+ $chr(166),%r)
  ; END OF DESC

  .timer[ $+ $nick $+ _ $+ $chan $+ ] 1 $rand(5,15) msg $chan %read
}


ON !*:QUIT: {
  .timer[ $+ $nick $+ _*] off

  var %f = $mircdirtexts\quit.txt
  if (!$file(%f)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f) does NOT exists or it is empty! | return }

  var %channels $comchan($nick,0)
  if (!%channels) { return }

  var %i = 1
  while (%i <= %channels) {
    var %c = $comchan($nick,%i)
    var %t = $nick(%c,0)

    if ($me isreg %c) { goto next }
    if (%t < 3) { goto next }

    :again

    var %r = $nick(%c,$rand(1,%t))

    if (%r == $me) || (%r == $nick) { goto again }

    var %read = $read(%f)

    ; START OF DESC --->> THIS IS A TEMP HOT FIX BECAUSE THE ADIIRC HAS A BUG ON PARSER https://dev.adiirc.com/issues/4843
    var %read = $replace(%read,$chr(166) $+ R $+ $chr(166),%r)
    ; END OF DESC

    .timer[ $+ $nick $+ _ $+ %c $+ ] 1 $rand(5,15) msg %c %read

    :next

    inc %i
  }
}

ON !*:NICK: {
  .timer[ $+ $nick $+ _*] off
  .timer[ $+ $newnick $+ _*] off

  var %f = $mircdirtexts\nickchange.txt
  if (!$file(%f)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f) does NOT exists or it is empty! | return }

  var %channels = $comchan($newnick,0)
  if (!%channels) { return }

  var %i = 1
  while (%i <= %channels) {
    var %c = $comchan($newnick,%i)
    var %t = $nick(%c,0)

    if ($me isreg %c) { goto next }
    if (%t < 3) { goto next }

    .timer[ $+ $newnick $+ _ $+ %c $+ ] 1 $rand(5,30) msg %c $read(%f)

    :next

    inc %i
  }
}

ON *:NOTICE:*identify*password*:?: {
  if (%mypass) && ($nick == NickServ) { .msg NickServ identify %mypass }
}

alias rand_msg {
  if (!$1) { return }

  var %f = $mircdirtexts\random.txt
  if (!$file(%f)) { echo 4 -tse FATAL ERROR! -> $scriptline -> $qt(%f) does NOT exists or it is empty! | return }

  var %t = $nick($1,0)
  if (%t < 4) { return }

  if ($me !ison $1) { return }
  if ($me isreg $1) { return }

  :again_1

  var %r1 = $nick($1,$rand(1,%t))
  if (%r1 == $me) || (%r1 == $nick) { goto again_1 }

  :again_2

  var %r2 = $nick($1,$rand(1,%t))
  if (%r2 == $me) || (%r2 == $nick) { goto again_2 }

  if (%r1 == %r2) { unset %r1 %r2 | goto again_1 }

  var %m = $read(%f)

  ; START OF DESC --->> THIS IS A TEMP HOT FIX BECAUSE THE ADIIRC HAS A BUG ON PARSER https://dev.adiirc.com/issues/4843
  var %m = $replace(%m,$chr(166) $+ R1 $+ $chr(166),%r1,$chr(166) $+ R2 $+ $chr(166),%r2)
  ; END OF DESC

  %m
}