FM Synthesis | FM Basics (Part 2)

/////////////////////// FM SYNTHESIS | FM Basics (Part 2) ///////////////////////
    ///////////////////////////// FM or AM? ///////////////////////////////


// Question: FM or AM? What's the difference?

// LFO is Low Frequency Oscillator, an oscillation control of 20Hz and below (inaudible).
// Question: Can you see where I'm implementing an LFO in the SynthDef below?

s.boot;

// Run these methods below for visual cues.

s.meter;
s.scope;
s.plotTree;

// I use the following only when necessary.

s.reboot;
s.quit;

/////////////////////// Things To Know Before Running Code ///////////////////////

/*

All my original SC documents are in the "dracula" color.
To find or change this, go To SuperCollider ––> Preferences ––> Editor ––> Font & Colors.
––> Select under Color, dracula.

Arguments in Synths are represented with a backslash, "\", in green under the "dracula" color font.
Values presented with these arguments can be changed. Only remember to NEVER cross 0, when using an exponential method like "exprand."

Argument and variable names can be changed to your liking.

Please be careful with volume output. Always have SuperCollider run through headphones. If you're unsure what the output will be, keep headphones away, with your main volume all the way down. Check your level meter and Stethoscope for visual cues. If everything looks safe (e.g. level meter is NOT in the red), proceed.

*/


// SynthDefs

Env([0, 1, 0], [0.1, 3], [1, -5]).plot; // Envelope shape to reference.
// First array, [0, 1, 0], are levels.
// Second array, [0.1, 3], are times traversing between levels.
// Third array, [1, -5], are curve values.

(
SynthDef.new(\sine, {
    arg atk=0.1, rel=3, c1=1, c2=(-5),
    freq=400, amp=0.3, out=0; // Be careful with amp values (0-1).
    var sig, sine, env;
    env = Env([0, 1, 0], [atk, rel], [c1, c2]).kr(2); // Env().kr(2) is a shortcut for "doneAction: 2"
    sig = SinOsc.ar(freq);
    sig = sig * env * amp;
    sig = sig!2;
    Out.ar(out, sig);
}).add;
)

Synth(\sine);


// SinOsc (SinOsc Control Variable)
// IMPORTANT: The "sinCtrl" argument below is causing the synth to perform amplitude modulation (AM).

(
SynthDef.new(\sinSine, {
    arg atk=0.1, rel=3, c1=1, c2=(-5),
    sinCtrl=1, sinFreq=400, amp=0.5, out=0;
    var sig, sine, env;
    env = Env([0, 1, 0], [atk, rel], [c1, c2]).kr(2);
    sine = SinOsc.ar(sinCtrl); // control value is 1Hz; this is effectively an LFO (e.g. < 20Hz).
    // traversing through these sine tone values in 1 second: (from, 0 to 0.5, then to -0.5, then back to 0).
          // Remember, 0.5 is my amp value here.
    // Use this following line of code for your reference: {SinOsc.ar(400, 0, 0.5)}.plot;
    sig = SinOsc.ar(sinFreq); // 400 Hz is the default.
    sig = sig * sine * env * amp;
    sig = sig!2; // Converts this to a stereo signal.
    // See the SynthDef below (\sinSine1) for another way to convert signal to stereo.
    Out.ar(out, sig);
}).add;
)

{SinOsc.ar(400, 0, 0.5)}.plot; // This is the reference for the current sine oscillator given.
// Reminder: The "sinCtrl" argument here is causing the synth to perform AM, not FM.
// Be sure to listen for the dip in volume as the sine tone of 400Hz crosses amp values, 0, 0.5, and -0.5.


Synth(\sinSine);
Synth(\sinSine, [\amp, 0.3, \rel, 8]); // Change amp values between 0 and 1 (..but, don't do 0).

// Be careful with amp values. Anything exceeding 0.5, in this case, is fairly loud.

// Here's another way to convert the signal to stereo.

(
SynthDef.new(\sinSine1, { // Note the name change for our SynthDef. Always check your names!
    arg atk=0.1, rel=8, c1=1, c2=(-5),
    sinCtrl=1, sinFreq=400, amp=0.5, out=0;
    var sig, sine, env;
    env = Env([0, 1, 0], [atk, rel], [c1, c2]).kr(2);
    sine = SinOsc.ar(sinCtrl);
    sig = SinOsc.ar(sinFreq)!2; // Create a stereo signal.
    sig = sig * sine * env * amp;
    Out.ar(out, sig);
}).add;
)

Synth(\sinSine1);
Synth(\sinSine1, [\amp, 0.4, \rel, rrand(2, 8)]); // Release ranges between 2 and 8 seconds.

(
Synth(\sinSine1, [
    \amp, rrand(0.1, 0.4),
    \sinCtrl, rrand(0.25, 4), // AM ranges between 1 cycle per 4 seconds to 4 cycles per second.
    \sinFreq, rrand(200, 1000), // Frequency ranges from 200Hz to 1000Hz.
]);
)

// By now you see that we have been working with Amplitude Modulation, not Frequency Modulation.
// Be sure to check out Part 3 of FM Basics, for a more in-depth review of FM. To be posted soon. Thank you!