BRF+ Technical Log -> HTML Control

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:sap="http://www.sap.com/sapxsl" version="1.0">

  <xsl:param name="BSP_URL"/>

  <xsl:strip-space elements="*"/>
  <xsl:output method="html" encoding="ISO-8859-1"/>

  <xsl:template match="FDT">
    <xsl:apply-templates/>
  </xsl:template>

  <xsl:template match="FUNCTION">
    <xsl:call-template name="unit">
      <xsl:with-param name="title">Funktion <xsl:value-of select="@Name"/></xsl:with-param>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="RULESET">
    <xsl:call-template name="unit">
      <xsl:with-param name="title">Regelsatz "<xsl:value-of select="./TEXT"/>"</xsl:with-param>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="EXPRESSION">
    <xsl:call-template name="unit">
      <xsl:with-param name="title">Ausdruck <i><xsl:value-of select="@Name"/></i></xsl:with-param>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="CONTEXT">
    <xsl:call-template name="showData">
      <xsl:with-param name="title">Datenobjekt</xsl:with-param>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="CONTEXT_UPDATE">
    <xsl:call-template name="showData">
      <xsl:with-param name="title">Update Datenobjekt</xsl:with-param>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="RESULT">
    <xsl:call-template name="showData">
      <xsl:with-param name="title">Ergebnis-Datenobjekt</xsl:with-param>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="TEXT">
    <div><xsl:value-of select="."/></div>
  </xsl:template>

  <xsl:template match="IterationIndex">
    <div class="iteration"><xsl:value-of select="."/>. Iteration</div>
  </xsl:template>

  <xsl:template match="StartProcessingTimeStamp|EndProcessingTimeStamp"/>

  <xsl:template name="showData">
    <xsl:param name="title">Datum</xsl:param>
    <div class="data">
      <a href="SAPEVENT:SHOW_DATA?id={@DataObjectID}"><xsl:value-of select="$title"/>&#xA0;<xsl:value-of select="@DataObjectName"/></a>
      <div>
        <xsl:value-of select="."/>
      </div>
    </div>
  </xsl:template>

  <xsl:template name="unit">
    <xsl:param name="title"/>
    <div class="unit {name()}">
      <xsl:call-template name="control"/>
      <h3><xsl:value-of select="$title"/></h3>
      <xsl:apply-templates/>
    </div>
  </xsl:template>

  <xsl:template name="control">
    <div class="control">
      <xsl:call-template name="button">
        <xsl:with-param name="title">Alles aufklappen</xsl:with-param>
        <xsl:with-param name="fcode">EXPAND_ALL</xsl:with-param>
        <xsl:with-param name="icon_filename">s_b_aexp.gif</xsl:with-param>
      </xsl:call-template>
      <xsl:call-template name="button">
        <xsl:with-param name="title">Nächste Ebene aufklappen</xsl:with-param>
        <xsl:with-param name="fcode">EXPAND</xsl:with-param>
        <xsl:with-param name="icon_filename">s_b_expa.gif</xsl:with-param>
      </xsl:call-template>
      <xsl:call-template name="button">
        <xsl:with-param name="title">Nächste Ebene zuklappen</xsl:with-param>
        <xsl:with-param name="fcode">COLLAPSE</xsl:with-param>
        <xsl:with-param name="icon_filename">s_b_cols.gif</xsl:with-param>
      </xsl:call-template>
      <xsl:call-template name="button">
        <xsl:with-param name="title">Alles zuklappen</xsl:with-param>
        <xsl:with-param name="fcode">COLLAPSE_ALL</xsl:with-param>
        <xsl:with-param name="icon_filename">s_b_acom.gif</xsl:with-param>
      </xsl:call-template>
    </div>
  </xsl:template>

  <xsl:template name="button">
    <xsl:param name="icon_filename"/>
    <xsl:param name="title"/>
    <xsl:param name="fcode"/>
    <button title="{$title}" class="{$fcode}">
      <img src="{$BSP_URL}PUBLIC/BC/Icons/{$icon_filename}"
           width="16"
           height="14"/>
    </button>
  </xsl:template>

</xsl:transform>