Yste's Radar

{                             -> entity
  Gemini Decomposition        -> entity, entity
  Compass' Purification       -> entity, loc
  Vista's Distillation        -> entity, coord
  Gemini Decomposition        -> entity, coord, coord
  Vector Disintegration       -> entity, coord, x, y, z
  Numerical Reflection: 0     -> entity, coord, x, y, z, 0
  Maximus Distillation        -> entity, coord, x, y, bool
  {
    Bookkeeper's Gambit: vvvv ->
  }
  {
    Bookkeeper's Gambit: --vv -> entity, coord
    Jester's Gambit           -> coord, entity
    {
      "* &b"
      "\n  &a"
    }
    Flock's Disintegration    -> coord, entity, "* &b", "\n  &a"
    Rotation Gambit II        -> coord, "\n  &a", entity, "* &b"
    Prospector's Gambit       -> coord, "\n  &a", entity, "* &b", entity
    Scrivener's Purification  -> coord, "\n  &a", entity, "* &b", "<entity>"
    Concat. Distillation      -> coord, "\n  &a", entity, "* &b<entity>"
    Rotation Gambit II        -> coord, "* &b<entity>", "\n  &a", entity
    Compass' Purification     -> coord, "* &b<entity>", "\n  &a", loc
    Mind's Reflection         -> coord, "* &b<entity>", "\n  &a", loc, SELF
    Compass' Purification     -> coord, "* &b<entity>", "\n  &a", loc, loc
    Subtractive Distillation  -> coord, "* &b<entity>", "\n  &a", dir
    Length Purification       -> coord, "* &b<entity>", "\n  &a", dist
    Scrivener's Purification  -> coord, "* &b<entity>", "\n  &a", "<dist>"
    Concat. Distillation      -> coord, "* &b<entity>", "\n  &a<dist>"
    Concat. Distillation      -> coord, "* &b<entity>/n  &a<dist>"
    Callig. Purification      -> coord, visage("* &b<entity>/n  &a<dist>")
    Numerical Reflection: 1   -> coord, visage("* &b<entity>/n  &a<dist>"), 1
    Etch Visage               ->
  }
  Augur's Exaltation          -> entity, coord, x, y, [patterns]
  Hermes' Gambit              ->
}
Mind's Reflection             -> SELF
Compass' Purification         -> loc
Numerical Reflection: 30      -> loc, 30
Zone Distillation: Living     -> [entities]
Mind's Reflection             -> SELF
Single's Purification         -> [SELF]
Exclusionary Distillation     -> [entities]
Gemini Decomposition          -> [entities], [entities]
Abacus Purification           -> [entities], num
Numerical Reflection: 32      -> [entities], num, 32
Dioscuri Gambit               -> [entities], num, 32, num, 32
Minimus Distillation          -> [entities], num, 32, bool
Rotation Gambit II            -> [entities], bool, num, 32
Augur's Exaltation            -> [entities], num
Numerical Reflection: 0       -> [entities], num, 0
Jester's Gambit               -> [entities], 0, num
Selection Exaltation          -> [entities]
Thoth's Gambit                -> []