Example of a DEMO script using a timer (both Attach and REZ).lsl

//MH+ presents, join us! => https://discord.link/SLguru
//時限でDEMOするスクリプトの例 (Attach物とREZ物の両対応)
//注意：たとえ制作者であっても時間経過後は問答無用で動作するので作者の場合とか例外処理が必要な場合は各自で付与すること
integer TIME_Left = 120;//秒で指定
key Owner_KEY = NULL_KEY;

default{
    on_rez(integer num){
        //on_rezイベントは、①地域にREZした　②アバターに装着した　③アバターに装着したままログインした
        //この３つの発生パターンがあります
        if(llGetOwner() != Owner_KEY){
            llResetScript();//所有者が異なっていたらリセット
        }
    }
    state_entry(){
        //state_entryイベントは①スクリプトが起動したとき　②リセットしたとき　③stateが変更されたとき
        //この３つの発生パターンがあります
        Owner_KEY = llGetOwner();//所有者のKEY取得
        //NEXT Permissionのチェック
        integer perm_mask = llGetObjectPermMask( MASK_NEXT );
//      if(perm_mask & PERM_COPY)     llOwnerSay("このアイテムはコピー可能です。");
//      if(perm_mask & PERM_MODIFY)   llOwnerSay("このアイテムは編集可能です。");
//      if(perm_mask & PERM_TRANSFER) llOwnerSay("このアイテムは譲渡可能です。");
        if(perm_mask & PERM_MODIFY){
            llOwnerSay("このアイテムは編集可能です。");
            llOwnerSay("オブジェクトの設定を変更してください。");
            llRemoveInventory(llGetScriptName());//このスクリプトを除去する
        }else{
            llOwnerSay("製品のDEMOを開始します。(残り時間 : " + (string)TIME_Left + " 秒)");
            llSetTimerEvent(1.0);//１秒間隔
        }
    }
    run_time_permissions(integer perm){
        //run_time_permissionsイベントはRequestPermissionsの応答です
        if( perm & PERMISSION_ATTACH ){
            if(llGetAttached()){
                llDetachFromAvatar();
            }else{
                llDie();//直REZの場合は自爆
            }
        }else{
            llDie();//ATTACH拒否は自爆(自分の持ち物なのでこのパターンはあり得ない)
        }
    }
    timer(){
        //指定した時間間隔でイベント発生。
        if(--TIME_Left <= 0){//　== 0としないこと。Timerは止めていないので時間経過しても継続させる→再装着対処
            llOwnerSay("製品のDEMOを終了します。");
            llSetText("",<1,1,1>,1.0);//必要なら残り時間をテキスト表示
            if(llGetAttached()){
                llRequestPermissions(Owner_KEY, PERMISSION_ATTACH);//パーミッション取得を要求
            }else{
                llDie();//直REZの場合は自爆
            }
        }else{
            llSetText("(残り時間 : " + (string)TIME_Left + " 秒)",<1,1,1>,1.0);//必要なら残り時間をテキスト表示
        }
    }
}