On $*:TEXT:/^[!@.]setvid/Si:#: {
  if ($nick isvoice $chan) || ($nick ishop $chan) || ($nick isop $chan) {
    writeini youtube.ini Vids Vidnum $calc($readini(youtube.ini,Vids,Vidnum) + 1)
    writeini youtube.ini Vids $readini(youtube.ini,Vids,Vidnum) $replace($2-,|,$chr(34))
    notice $nick Your youtube link has been saved. It's id number is $readini(youtube.ini,Vids,Vidnum) $+ . Type !vid $readini(youtube.ini,Vids,Vidnum) to see it.
  }
  else {
    notice $nick You must have atleast voice to perform this command.
  }
}
On $*:TEXT:/^[!@.]vid/Si:#: {
  if ($2 isnum) && ($readini(youtube.ini,Vids,$2) != $null) {
    $iif($left($1,1) == @,msg $chan,notice $nick) Youtube ID $2 $+ : $readini(youtube.ini,Vids,$2)
  }
  else {
    notice $nick The Youtube ID $2 doesn't exist, please try another.
  }
}
On $*:TEXT:/^[!@.]clearvid/Si:#: {
  if ($nick isop $chan) {
    if ($2 == all) {
      remini youtube.ini Vids
      notice $nick All Youtube links have been removed.
    }
    elseif ($2 isnum) && ($readini(youtube.ini,Vids,$2) != $null) {
      remini youtube.ini Vids $2
      notice $nick Youtube video $2 has been removed.
    }
    else {
      notice $nick This Youtube link ID doesn't exist, please try another.
    }
  }
  else {
    notice $nick You must be a channel operator to perform this command.
  }
}