; ===========================================================================
; ---------------------------------------------------------------------------
; H-blank interrupt - Scroll test
; ---------------------------------------------------------------------------

ST_HBICode:
        move.w  ST_SH_Reg.w,VDP_Ctrl_Port.l     ; set shadow/highlight for this scanline
        move.w  ST_Sprite_Table_Reg.w,VDP_Ctrl_Port.l   ; set location of sprite table
        eor.b   #$06,ST_Sprite_Table_Reg+$01.w      ; switch between $F800 and $F400
        move.w  d0,-(sp)                ; push d0.w (save)
        move.w  ST_Scanline.w,d0            ; get scanline value
        addq.w  #$01,d0                 ; increment
        cmp.w   Floor_Pos.w,d0              ; have we reached the reflection floor?
        bne.s   .Return                 ; if not, branch
        move.w  #$8C00|%10001001,ST_SH_Reg.w        ; otherwise, switch (shadow/highlight will activate next frame)

.Return:
        move.w  d0,ST_Scanline.w            ; save scanline counter
        move.w  (sp)+,d0                ; pop d0.w (restore)
        rte                     ; return
ST_HBICode_End: