User's Roles Sorting (Using API)

$nomention

$if[$message==]
    $var[member;$authorID]
$elseif[$findUser[$message;no]==]
        $var[member;$message]
        $onlyIf[$userExists[$var[member]]==true;`❌` User or Member `"$message"` not found.]
$else
    $var[member;$findUser[$message;no]]
$endif

$httpAddHeader[apikey;$getVar[ApiKey]]
$httpAddHeader[bot-token;$getVar[BotToken]]
$httpAddHeader[guild-id;$guildID]
$httpAddHeader[member;$var[member]]

$httpGet[https://bdfddata.rickyjs.xyz/release/guild/members]
$jsonParse[$httpResult]

$var[user.roles.length;$jsonArrayCount[details;roles]]

$if[$json[details;message]==Unknown Member]
    That user isn't in this server.
$else
    $if[$var[user.roles.length]==0]
        $username[$var[member]] has no roles.
    $else
        $textSplit[$jsonJoinArray[details;roles;-];-]
        $var[user.roles.length;$getTextSplitLength]

        $jsonParse[{ "sorted.roles": [\] }]

        $var[x;1]
        $var[code;%{DOL}%var[role-id\;%{DOL}%splitText[%{DOL}%var[x\]\]\]%{DOL}%jsonSetString[%{DOL}%rolePosition[%{DOL}%var[role-id\]\]\;%{DOL}%var[role-id\]\]%{DOL}%var[x\;%{DOL}%calculate[%{DOL}%var[x\] + 1\]\]]

        $if[$var[user.roles.length]<=100]
            $var[loop;$replaceText[$cropText[$repeatMessage[10;$repeatMessage[10;@]];$var[user.roles.length];];@;$var[code]]]
        $else
            $var[loop;$replaceText[$cropText[$repeatMessage[10;$repeatMessage[10;$repeatMessage[10;#]]];$var[user.roles.length];];#;$var[code]]]
        $endif

        $eval[$var[loop]]

        $var[n;1]
        $var[code;%{DOL}%if[%{DOL}%jsonArrayCount[sorted.roles\]==%{DOL}%var[user.roles.length\]\]%{DOL}%stop%{DOL}%endif%{DOL}%if[%{DOL}%json[%{DOL}%var[n\]\]!=\]%{DOL}%jsonArrayAppend[sorted.roles\;"%{DOL}%json[%{DOL}%var[n\]\]"\]%{DOL}%endif%{DOL}%var[n\;%{DOL}%calculate[%{DOL}%var[n\] + 1\]\]]

        $eval[$replaceText[$cropText[$repeatMessage[10;$repeatMessage[10;$repeatMessage[3;~]]];250;];~;$var[code]]]

        $var[separator;, ]
        $var[final.result;<@&$replaceText[$jsonJoinArray[sorted.roles;>$var[separator]<@&]>;";]]

        $description[$var[final.result]]
        $color[8fdbd7]
        $footer[$username[$var[member]] has $jsonArrayCount[sorted.roles] roles]
    $endif
$endif