Definition Script MooMoo

;Definition Script v1.0
;Made by nick1
;Last edit January 3 2012

;USAGE: /define <word> <definition number> (the definition number is optional and defaults to 1)
alias define {
  set %_def.word $1
  set %_def.num $iif($2,$2,1)
  set %_def.count 1
  sockclose define
  sockopen define ninjawords.com 80
}

on *:sockopen:define: {
  sockwrite -nt $sockname GET / $+ %_def.word HTTP/1.1
  sockwrite -nt $sockname Host: ninjawords.com
  sockwrite -nt $sockname $crlf
}

on *:SOCKREAD:define: {
  if ($sockerr) { echo -a SOCKET ERROR: $sockerr | halt }
  $iif((!%_def.count),set %_def.count 1,noop)
  sockread %sockreader
  while ($sockbr) {
    if (*<span class="correct-word">* iswm %sockreader) {
      set %_def.word $+($remove($nohtml(%sockreader),Did you mean $+ $chr(32),?),*)
    }
    if ((*<span class="definition-marker">&deg;</span>* iswm %sockreader) && (%_def.word)) {
      var %def $remove($nohtml(%sockreader),&deg;)
      if (%_def.count == %_def.num) {
        echo -at $bracketcolor(%_def.word) 10 %def
      }
      inc %_def.count
    }
    sockread %sockreader
  }
  if (%_def.count > %_def.num) {
    unset %_def.*
    sockclose $sockname
  }
}