toggle Swift Compiler warnings

###########################################################
-->> ABOUT
###########################################################
(*

 Phil Stokes -- 2017
 applehelpwriter.com
 sqwarq.com

 See: http://applehelpwriter.com/2017/07/15/toggle-swift-compiler-warnings/

*)
###########################################################
-->> DESCRIPTION
###########################################################
(*

This script toggles Xcode's Swift compiler warnings for Debug builds on and off.


*)
###########################################################
-->> USAGE
###########################################################
(*

Best made into a Service or executed from a script runner like FastScripts or Keyboard Maestro


*)
###########################################################
-->> IMPORT STATEMENTS
###########################################################

use AppleScript version "2.4" -- Yosemite (10.10) or later
use scripting additions

###########################################################
-->> HANDLERS
###########################################################


on sendNotification(aVal)

    display notification "Suppress Warnings was set to " & aVal with title "Swift Compiler - Warnings Policies"

end sendNotification
###########################################################
-->> COMMANDS
###########################################################

tell application id "com.apple.dt.Xcode"
    tell its front document
        tell its front project
            tell its front target
                tell its build configuration "Debug"
                    set b to build setting "SWIFT_SUPPRESS_WARNINGS"
                    if b's value is "NO" then
                        set b's value to "YES"
                    else
                        set b's value to "NO"
                    end if
                    my sendNotification(b's value)
                end tell
            end tell
        end tell
    end tell
end tell

#EOF