begin ab01StriderActiSndScr

; assuming 17 new jblSilt_01 .. jblSilt_17 sounds are available
; attach this local script to a_siltstrider activator /abot

if ( MenuMode )
	return
endif

; stop standard sounds
StopSound Silt_1
StopSound Silt_2
StopSound Silt_3

float t1
if ( t1 > 0 )
	set t1 to ( t1 - GetSecondsPassed )
	return
endif
set t1 to Random 1001
set t1 to ( t1 * 0.0005 ) ; 0 <= t1 <= 0.5
set t1 to ( t1 + 9.5 ) ; 9.5 <= t1 <= 10, change delay as needed

short i1
set i1 to Random 16001
set i1 to ( i1 * 0.001 ) ; 0 <= i1 <= 16 )
set i1 to ( i1 + 1 ) ; 1 <= i1 <= 17 )

if ( i1 >= 12 )
	if ( i1 == 17 )
		PlaySound3dVP jblSilt_17 1.0 1.0
		; (eventually, if you need a different delay); same for the other sounds e.g.
		; set t1 to 8.7
		return
	endif
	if ( i1 == 16 )
		PlaySound3dVP jblSilt_16 1.0 1.0
		return
	endif
	if ( i1 == 15 )
		PlaySound3dVP jblSilt_15 1.0 1.0
		return
	endif
	if ( i1 == 14 )
		PlaySound3dVP jblSilt_14 1.0 1.0
		return
	endif
	if ( i1 == 13 )
		PlaySound3dVP jblSilt_13 1.0 1.0
		return
	endif
	if ( i1 == 12 )
		PlaySound3dVP jblSilt_12 1.0 1.0
		return
	endif
	return
endif

if ( i1 >= 6 )
	if ( i1 == 11 )
		PlaySound3dVP jblSilt_11 1.0 1.0
		return
	endif
	if ( i1 == 10 )
		PlaySound3dVP jblSilt_10 1.0 1.0
		return
	endif
	if ( i1 == 9 )
		PlaySound3dVP jblSilt_09 1.0 1.0
		return
	endif
	if ( i1 == 8 )
		PlaySound3dVP jblSilt_08 1.0 1.0
		return
	endif
	if ( i1 == 7 )
		PlaySound3dVP jblSilt_07 1.0 1.0
		return
	endif
	if ( i1 == 6 )
		PlaySound3dVP jblSilt_06 1.0 1.0
		return
	endif
	return
endif

if ( i1 == 5 )
	PlaySound3dVP jblSilt_05 1.0 1.0
	return
endif

if ( i1 == 4 )
	PlaySound3dVP jblSilt_04 1.0 1.0
	return
endif

if ( i1 == 3 )
	PlaySound3dVP jblSilt_03 1.0 1.0
	return
endif

if ( i1 == 2 )
	PlaySound3dVP jblSilt_02 1.0 1.0
	return
endif

if ( i1 == 1 )
	PlaySound3dVP jblSilt_01 1.0 1.0
endif

end