CHM в онлайн

#include <File.au3>
#include <Array.au3>

Global $kTotal

$Path=@ScriptDir
$Pattern1='<a href="JavaScript:hhctrl.Click()"><IMG NAME="botton" title="Открыть" style=''margin: 5px 4px 4px 10px;'' src=''../images/Open.gif''" border="0" align=''right''></a>'
$Pattern2='<a href="JavaScript:hhctrl.Click()"><IMG NAME="botton" title="Открыть" style=''margin: 20px 4px 4px 10px;'' src=''../images/Open.gif''" border="0" align=''right''></a>'

$FileList=_FileListToArray($Path&'\libfunctions')
If Not @error Then
    ; переводим тексты в нижний регистр
    For $i = 1 to $FileList[0]
        $FileList[$i]=StringLower($FileList[$i])
    Next

    ; переименовываем файлы
    $err=0
    For $i = 1 to $FileList[0]
        If FileMove($Path&'\libfunctions\'&$FileList[$i], $Path&'\libfunctions\#@%'&$FileList[$i]) Then
            If Not FileMove($Path&'\libfunctions\#@%'&$FileList[$i], $Path&'\libfunctions\'&$FileList[$i]) Then $err+=1
        EndIf
        ToolTip('ReName '&$i&' - '&$FileList[$i])
    Next
    If $err > 0 Then MsgBox(0, '', 'Была ошибка при переименовании файлов')
    MsgBox(0, '', 'Переименование выполнено')

    _Processing($FileList, 'libfunctions', 'UDF', 1)
    MsgBox(0, '', 'Количество замен в UDF - libfunctions = '&$kTotal)
EndIf

$FileList=_FileListToArray($Path&'\keywords')
If Not @error Then
    _Processing($FileList, 'keywords', 'KEY', 0)
    MsgBox(0, '', 'Количество замен в keywords = '&$kTotal)
EndIf

$FileList=_FileListToArray($Path&'\functions')
If Not @error Then
    _Processing($FileList, 'functions', 'FUNC', 0)
    MsgBox(0, '', 'Количество замен functions = '&$kTotal)
EndIf

Func _Processing($FileList, $folder, $text, $Tr=0)
    $kTotal=0
    ; заменяем все тексты на тексты в нижнем регистре
    For $i = 1 to $FileList[0]
        $html = FileRead($Path&'\'&$folder&'\'&$FileList[$i])
        $k=0
        ToolTip($text&' '&$i&' - '&$FileList[$i])

        If $Tr Then
            $aLink=StringRegExp($html, '(<a href=".*?\.htm")', 3)
            If Not @error Then
                For $j = 0 to UBound($aLink)-1
                    $html = StringReplace($html, $aLink[$j], StringLower($aLink[$j])) ; заменит без учёта регистра в нижний регистр
                Next
            EndIf
        EndIf

        $html = StringReplace($html, '::/html/', '../') ; заменит внутренние пути CHM на внешние
        $k+=@extended

        ; удалить кнопку "Открыть" сверху
        $html = StringReplace($html, $Pattern1, '') ;
        $k+=@extended

        ; удалить кнопку "Открыть" снизу
        $html = StringReplace($html, $Pattern2, '') ;
        $k+=@extended

        ; если изменения произошли, то сохраняем в файл
        If $k > 0 Then
            $file = FileOpen($Path&'\'&$folder&'\'&$FileList[$i], 2)
            FileWrite($file, $html)
            FileClose($file)
        EndIf
        $kTotal+=$k
    Next
EndFunc