Points System by OrFeAsGr

ON *:TEXT:*:#: {
  tokenize 32 $strip($1-)
  if ($istok(!points+ !points- !resetpoints,$1,32)) {
    if ($nick isop $chan) {
      if ($1 == !resetpoints) { tokenize 32 !resetpoints $nick }
      if ($3) {
        if ($1 == !points+) {
          .timer 1 1 msg $chan $nick gave $3 points to $+($2,!!!) $iif($4-, $+($chr(40),Reason: $4-,$chr(41)), $null) $iif(!$($+(%,points.,$2),2), $+($chr(40),$2,'s first points!,$chr(41)), $+($2,'s new points: $calc($v1 + $3)))
          inc $+(%,points.,$2) $3
          set %pointslatest + $nick $2 $3 $date $time $ctime
        }
        if ($1 == !points-) {
          .timer 1 1 msg $chan $nick took away $3 points from $+($2,...) $iif($4-, $+($chr(40),Reason: $4-,$chr(41)), $null) $+($2,'s new points: $calc($($+(%,points.,$2),2) - $3))
          dec $+(%,points.,$2) $3
          set %pointslatest - $nick $2 $3 $date $time $ctime
        }
      }
      elseif (!$3) { msg $chan $1 USAGE: $1 nick points reason }
      if ($1 == !resetpoints) {
        if (!%resetpoints) {
          inc -u200 %resetpoints 1
          .timer 1 1 msg $chan This command will 4delete all the points of all users. If you really want to continue with this type $1 again.
        }
        elseif (%resetpoints == 1) {
          inc -u120 %resetpoints 1
          .timer 1 1 msg $chan Just checking to be sure... Using this command will 4delete all points! If you use $1 one more time they will be 4deleted.
        }
        elseif (%resetpoints == 2) {
          unset %resetpoints
          .timer 1 1 msg $chan All the points were deleted.
          unset %points.*
          unset %pointslatest
        }
      }
    }
    elseif ($nick !isop $chan) {
      .timer 1 1 msg $chan You need to be opped to use !points+ or !points- or !resetpoints
    }
  }
  if ($1 == !pointslatest) {
    tokenize 32 %pointslatest
    .timer 1 1 msg $chan Last Points Activity: $2 $iif($1 == -, took away $4 points from, gave $4 points to) $3 at $5 $6 $+($chr(40),$duration($calc($ctime - $7)) ago,$chr(41))
  }
  if ($1 == !getpoints) {
    var %n = $iif($2, $v1, $nick)
    if ($($+(%,points.,%n),2)) {
      .timer 1 1 msg $chan $+(%n,'s) Points: $v1
    }
    else {
      .timer 1 1 msg $chan $iif($2, There are not points for this nick..., You haven't got any points yet $nick)
    }
  }
}