Country Scan And Ban for Makis v1.6

alias -l channel { return #gayhellas }
alias -l ban_delay { return 10800 }

ON ME:*:JOIN:$($channel): { mode $chan b | mode $chan e | mode $chan I }

ON @!*:JOIN:$($channel): {
  var %not_hosts = 109.169.31.4 107.161.19.53 107.161.19.109

  if (*!*@ $+ $site isexcept $chan) || ($nick $+ !*@* isexcept $chan) { return }
  if (o !isincs $usermode) || (*.gr iswm $site) || (*kiwiirc* iswm $site) || ($istok(%not_hosts,$site,32)) || (*.cosmote.net iswm $site) { return }

  if (*HIDE-IP* iswm $site) || (*.IP iswm $site) { set -e %userip_nicks $addtok(%userip_nicks,$nick,32) | userip $nick | return }

  .timer[VPN_ $+ $nick $+ _CHECK] 1 $rand(1,10) vpn_check $nick $site
}

raw 340:*: {
  var %n = $gettok($2,1,61)
  var %h = $gettok($2,2,64)

  if (%n) && (%h) && ($istok(%userip_nicks,%n,32)) {
    haltdef

    set -e %userip_nicks $remtok(%userip_nicks,%n,1,32)

    .timer[VPN_ $+ %n $+ _CHECK] 1 $rand(1,10) vpn_check %n %h
  }
}

raw 367:*: { if ($2 == $channel) { haltdef } }
raw 368:*: { if ($2 == $channel) { haltdef } }
raw 346:*: { if ($2 == $channel) { haltdef } }
raw 347:*: { if ($2 == $channel) { haltdef } }
raw 348:*: { if ($2 == $channel) { haltdef } }
raw 349:*: { if ($2 == $channel) { haltdef } }

alias -l bold { return $+($chr(2),$1-,$chr(2)) }
alias -l under { return $+($chr(31),$1-,$chr(31)) }

alias -l vpn_check {
  if (!$1) && (!$2) && ($me !ison $channel) && ($me !isop $channel) && ($1 !ison $channel) { return }

  var %s = $iif($ban_delay,$v1,10800)

  var %v1 = SCAN_VPN_ $+ $rand(1,1000000000)

  JSONOpen -ud %v1 http://ip-api.com/json/ $+ $2
  if ($jsonerror) { goto second }

  var %country = $json(%v1,countryCode).value

  if (%country) && (%country !== GR) { ban -ku $+ %s $channel $1 2 Your IP/Host ( $+ $bold($2) $+ ) Connecting From: $bold(%country) --> $under(Open Proxy) $+ / $+ $under(VPN) $+ / $+ $under(TOR Exit) - Rules: $under(http://tiny.cc/gayhellas_rules) - Bantime: $bold($duration(%s)) }

  return

  :second

  var %v2 = SCAN_VPN2_ $+ $rand(1,1000000000)

  JSONOpen -ud %v2 https://ipinfo.io/ $+ $2 $+ /json?token=7247b6c26b2413
  if ($jsonerror) { return }

  var %country = $json(%v2,country).value

  if (%country) && (%country !== GR) { ban -ku $+ %s $channel $1 2 Your IP/Host ( $+ $bold($2) $+ ) Connecting From: $bold(%country) ---> $under(Open Proxy) $+ / $+ $under(VPN) $+ / $+ $under(TOR Exit) - Rules: $under(http://tiny.cc/gayhellas_rules) - Bantime: $bold($duration(%s)) }
}