setCategorieHomeModello

<cffunction name="setCategorieHomeModello" returntype="void" access="public">
        <cfargument type="string" name="categorieHome" required="true" />
        <cfargument type="numeric" name="marchioid" required="true" />
        <cfargument type="numeric" name="tipologia" required="true" />
        <cfargument type="string" name="nome" required="true" />

        <cfif APPLICATION.Utenti.canViewFunzioniRiservate(ruoli=THIS.ruoliAbilitati)>
            <cftransaction>
                <cfquery name="LOCAL.q">
                    SELECT
                        *
                    FROM
                        ottica_categorie_modelli_home
                    WHERE
                        marchioid = <cfqueryparam cfsqltype="cf_sql_integer" value="#ARGUMENTS.marchioid#" />
                        AND tipologia = <cfqueryparam cfsqltype="cf_sql_integer" value="#ARGUMENTS.tipologia#" />
                        AND nome = <cfqueryparam cfsqltype="cf_sql_varchar" value="#ARGUMENTS.nome#" />
                </cfquery>
                <cfset LOCAL.ordinamento = {} />
                <cfset LOCAL.ordinamento[ARGUMENTS.marchioid] = {} />
                <cfset LOCAL.ordinamento[ARGUMENTS.marchioid][ARGUMENTS.tipologia] = {} />
                <cfset LOCAL.ordinamento[ARGUMENTS.marchioid][ARGUMENTS.tipologia][ARGUMENTS.nome] = {} />
                <cfloop query="LOCAL.q">
                    <cfset LOCAL.ordinamento[LOCAL.q.marchioid][LOCAL.q.tipologia][LOCAL.q.nome][LOCAL.q.id_categoria] = LOCAL.q.ordine />
                </cfloop>
                <cfquery>
                    DELETE FROM
                        ottica_categorie_modelli_home
                    WHERE
                        marchioid = <cfqueryparam cfsqltype="cf_sql_integer" value="#ARGUMENTS.marchioid#" />
                        AND tipologia = <cfqueryparam cfsqltype="cf_sql_integer" value="#ARGUMENTS.tipologia#" />
                        AND nome = <cfqueryparam cfsqltype="cf_sql_varchar" value="#ARGUMENTS.nome#" />
                </cfquery>
                <cfloop list="#ARGUMENTS.categorieHome#" index="LOCAL.catId">
                    <cfset LOCAL.setOrdine = 999 />
                    <cfif structKeyExists(LOCAL.ordinamento,ARGUMENTS.marchioid) AND
                        structKeyExists(LOCAL.ordinamento[ARGUMENTS.marchioid],ARGUMENTS.tipologia) AND
                        structKeyExists(LOCAL.ordinamento[ARGUMENTS.marchioid][ARGUMENTS.tipologia],ARGUMENTS.nome) AND
                        structKeyExists(LOCAL.ordinamento[ARGUMENTS.marchioid][ARGUMENTS.tipologia][ARGUMENTS.nome],LOCAL.catId)>
                            <cfset LOCAL.setOrdine = LOCAL.ordinamento[ARGUMENTS.marchioid][ARGUMENTS.tipologia][ARGUMENTS.nome][LOCAL.catId] />
                    </cfif>
                    <cfquery>
                        INSERT INTO
                            ottica_categorie_modelli_home
                        SET
                            id_categoria = <cfqueryparam cfsqltype="cf_sql_integer" value="#LOCAL.catId#" />,
                            marchioid = <cfqueryparam cfsqltype="cf_sql_integer" value="#ARGUMENTS.marchioid#" />,
                            tipologia = <cfqueryparam cfsqltype="cf_sql_integer" value="#ARGUMENTS.tipologia#" />,
                            nome = <cfqueryparam cfsqltype="cf_sql_varchar" value="#ARGUMENTS.nome#" />,
                            ordine = <cfqueryparam cfsqltype="cf_sql_integer" value="#LOCAL.setOrdine#" />
                    </cfquery>
                </cfloop>
            </cftransaction>
        </cfif>
    </cffunction>