S7 Gauntlets

actor S7_Gauntlets : S7_BaseWeapon {
    weapon.AmmoUse 0
    weapon.AmmoGive 0
	weapon.SlotNumber 0
    states {
    Ready:
		SGTS AB 1
    Ready2:
        SGNT A 1 A_WeaponReady
        loop

	Fire:
		SGNT A 1
		SGTS BA 1
	Hold:
		TNT1 A 1
		SGNT B 1 A_PlaySound ("Weapons/Raptor/Melee", CHAN_Weapon)
		SGNT CD 1 A_SetAngle (angle - 0.85)
		TNT1 A 0 A_CustomPunch (0, TRUE, 0, "S7_GauntletsMeleeSound")
		SGNT E 1 A_CustomPunch (random (1, 3) * 6, TRUE, 0, "S7_GauntletsMelee")
		SGNT FGHI 1
		TNT1 A 0 A_Refire ("Hold2")
		goto Fire.Finish
	Hold2:
		TNT1 A 1
		SGNT J 1 A_PlaySound ("Weapons/Raptor/Melee", CHAN_Weapon)
		SGNT KL 1 A_SetAngle (angle + 0.85)
		TNT1 A 0 A_CustomPunch (0, TRUE, 0, "S7_GauntletsMeleeSound")
		SGNT M 1 A_CustomPunch (random (1, 3) * 6, TRUE, 0, "S7_GauntletsMelee")
		SGNT NOPQ 1
		TNT1 A 0 A_Refire ("Hold")
		goto Fire.Finish
	Fire.Finish:
		TNT1 A 1
		SGTS AB 1
		SGNT A 1
		goto Ready2

	AltFire:
		SGNT ARST 2
	AltHold:
		SGNT UVW random (2, 3) A_CustomPunch (random (1, 3) * 6, TRUE, 0, "S7_GauntletsMelee", 0, 0.68)
		TNT1 A 0 A_Refire ("AltHold")
		goto AltFire.Finish
	AltFire.Finish:
		SGNT TSRA 2
		goto Ready2

	Select:
		TNT1 A 0 A_Raise
		wait
	Deselect:
		SGNT A 1
		SGTS BA 1
		TNT1 A 0 A_Lower
		wait
    }
}

actor S7_GauntletsMelee : S7_BulletPuff {
	+NoExtremeDeath
}

actor S7_GauntletsMeleeSound : S7_BulletPuff {
	seeSound    "Weapons/Gauntlets/Hit"
	attackSound "Weapons/Gauntlets/HitWall"

	+NoExtremeDeath +PuffOnActors +AlwaysPuff
    states {
    Spawn:
        TNT1 A 1
        stop
    }
}