Problema di monty

//
// Problema di monty hall
// P0: reset: disponi 2 capre e 1 macchina casualmente
// P1: TOCCO: chiedi di scegliere una PORTA C
// P2: ALLA SCELTA: il programma apre la porta con una capra fra le due residue
// P3: AL TOCCO: il programma chiede se vuoi cambiare oppure NO
// P4: ALLA SCELTA: il programma dice se hai vinto oppure no
string stato="P0";

integer portamacchina;
integer portacapra;

integer scelta;

integer handle;

default
{
    state_entry()
    {
        llSay(0, "Dispone gli oggetti");
        portamacchina=(integer)(llFrand(3)+1);
        llSay(0,"la macchina � nella porta "+(string)portamacchina);
        // vale 1,2 o 3
        stato="P1";


    }
    touch_start(integer total_number)

    {
        key id=llDetectedKey(0);
        if(stato=="P1")
        {
            handle=llListen(-1,"",id,""); llSetTimerEvent(30);
            llDialog(id,"Scegli una porta",[ "1","2","3" ],-1);
            stato="P2";
            return;
        }
        if(stato=="P3")
        {
            handle=llListen(-1,"",id,""); llSetTimerEvent(30);
            llDialog(id,"Vuoi cambiare la porta che hai scelto?",["TENGO","CAMBIO"],-1);
            stato="P4";
            return;

        }
    }
    listen(integer channel, string name, key id,string str)
    {
        llListenRemove(handle); llSetTimerEvent(0);
        if(stato=="P2")
        {
            scelta=(integer)(str);
            llSay(0,"Hai scelto "+str+" ti indico la porta con una capra");
            portacapra=0;
            while(portacapra==0)
            {
                integer r=(integer)(llFrand(3)+1);
                if(r!=portamacchina  && r!=scelta) portacapra=r;
            }
            llSay(0,"Una capra si trova nella porta "+(string)portacapra+ " tocca per andare avanti");
            stato="P3";
            return;
        }
        if(stato=="P4")
        {
            if(str=="CAMBIO")
            {
                integer i; integer cambiata;
                for(i=1;i<4;i++)
                {
                    if(i!=scelta && i!=portacapra) cambiata= i;
                }
                scelta=cambiata;
            }
            llSay(0,"porta scelta "+(string)scelta+" porta macchina "+(string)portamacchina);
            if(scelta==portamacchina)
            {
                llSay(0,"Hai vinto");
            }
            else
            {
                llSay(0,"Hai perso");
            }
            llResetScript();

        }
    }
    timer()
    {
        llListenRemove(handle); llSetTimerEvent(0);
        llResetScript();

    }


}