ModPanelTrigger/Slash

$var[er;F04947] $c[Error embed color]
$var[nm;2b2d31] $c[Normal embed color]
$var[trigger;(prefix)modpanel] $c[Trigger command]
$nomention
$onlyIf[$guildID!=;]
$if[$checkUserPerms[$botID;moderatemembers;kick;ban]==false]
$addField[Failed;$username[$botID] needs permission to Timeout/Kick/Ban members]
$color[$var[er]]
$elseif[$checkUserPerms[$botID;moderatemembers;kick;ban]==true]
 $var[unban;yes]
$if[$isSlash==false]
 $if[$userExists[$message[1]]==true]
 $var[userID;$message[1]]
  $if[$isBanned[$var[userID]]==true]
  $var[unban;no]
  $endif
 $endif
$endif
$if[$findUser[$message;no]!=]
$var[userID;$findUser[$message;no]]
$endif
$var[untimeout;yes]
$try
$if[$isTimedOut[$findUser[$message;no]]==true]
 $var[untimeout;no]
$endif
$endtry
$var[up;yes]
$if[$userExists[$findUser[$var[userID];no]]==true]
 $var[up;no]
$endif

$if[$isSlash==true]
$var[userID;$findUser[$message[user];no]]
$endif
$if[$userExists[$var[userID]]==false]
$addField[Invalid usage;Try ``$var[trigger] {UserID/@mention}``]
 $color[$var[er]]
$elseif[$userExists[$var[userID]]==true]
$author[Mod Panel]
$authorIcon[$authorAvatar]
$thumbnail[$userAvatar[$var[userID]]]
$addField[User;<@$var[userID]> / $username[$var[userID]]]
$addField[UserID;$var[userID]]
$addField[Joined Discord;$creationDate[$var[userID];Mon Jan 02, 2006 at 3:04PM]]
$try
$addField[Joined Server;$userJoined[$var[userID];Mon Jan 02, 2006 at 3:04PM]]
$endtry
$footer[Moderator - $username[$authorID]]
$color[$var[nm]]
$addTimestamp
$addButton[yes;$var[userID]~RolesList-$authorID;Roles;primary;$var[up];]
$addButton[no;$var[userID]~PermsList-$authorID;Permissions;primary;$var[up];]
$addButton[no;CloseMP-$authorID;;secondary;no;🚫]
$addButton[yes;$var[userID]~Timeout-$authorID;Timeout;danger;$var[up];]
$addButton[no;$var[userID]~Kick-$authorID;Kick;danger;$var[up];]
$addButton[no;$var[userID]~Ban-$authorID;Ban;danger;$var[up];]
$addButton[yes;$var[userID]~UnTO-$authorID;Remove Timeout;success;$var[untimeout];]
$addButton[no;$var[userID]~UnBn-$authorID;UnBan;success;$var[unban];]

$endif
$endif
$endif