Reversi fight place for IchigoJam

new

10 'Ichigo Reversi V1
50 CLS:UART0:N=4
70 FOR X=1TO8:LCX,0:?X;:LC0,X:?X;:FOR Y=1TO8
110 LCX,Y:?CHR$(#A5);:NEXT:NEXT
120 LC4,4:?"OX";:LC4,5:?"XO";:LC0,0:?" "
160 LC0,10:U=#4F
200 N=N+1:T=U:IFU=#4F:U=#58 ELSE U=#4F
210 IFN>65:GOTO900:ELSE:GOTO800
300 IFX=0 GOTO900
305 IFX=0 GOTO900
310 VIDEO1:UART2:?X,Y:UART0
320 IFSCR(X,Y)!=#A5THEN?"TRY AGAIN";:BEEP:WAIT(30):GOTO210
330 C=0:FORI=-1TO1:FORJ=-1TO1
340 IF(I=0ANDJ=0)GOTO500
350 K=1
360 L=PEEK(Y*32+X+#900+I*K+J*K*32)
370 IFL=T K=K+1:GOTO360
380 IFL!=U GOTO 500
400 K=K-1:IFK<1 GOTO500
410 C=C+1:POKEY*32+X+#900+(J*32+I)*K,U:GOTO400
500 NEXT:NEXT
510 IFC=0 LC0,13:?"Error":WAIT(60):GOTO210
520 LCX,Y:?CHR$(U);
530 GOTO 200
800 'TUGINO TE NYUURYOKU
810 LC0,-1:UART1:?"#";N:FORY=0TO8:FORX=0TO8:?CHR$(SCR(X,Y));:NEXT:?:NEXT:?"":UART0
820 FORX=#A40TO#ACF:POKEX,00:NEXT:LC0,10
830 ?CHR$(U);":"
840 LC0,11
850 IFU=#58THEN LRUN1
860 LRUN2
900 A=0:B=0
910 UART2:FORX=1TO8:FORY=1TO8
920 IFSCR(X,Y)=U A=A+1
930 IFSCR(X,Y)=T B=B+1
940 NEXT:NEXT:LC0,14:?CHR$(U);"=";A,CHR$(T);"=";B:?"END"

save 0


new

10 'Ichigo PLAYER
20 VIDEO0
30 UART2:LC0,-1
100 D=0:X=0:Y=0
110 FOR A=1TO8:FOR B=1TO8
330 C=0:FORI=-1TO1:FORJ=-1TO1
340 IF(I=0ANDJ=0)GOTO500
350 K=1:IFSCR(A,B)!=#A5 GOTO500
360 L=PEEK(B*32+A+#900+I*K+J*K*32)
370 IFL=T K=K+1:GOTO360
380 IFL!=U GOTO 500
430  C=C+K-1
500 NEXT:NEXT
510 IFC>D THEN X=A:Y=B:D=C:GOTO540
515 IF C=0 GOTO 540
520 IF C=D IF RND(10)>5 X=A:Y=B:D=C
540 NEXT:NEXT
800 LRUN0,300

save 1

new

10 'Ichigo reversi MAN
20 INPUT"ENTER X:",X
30 INPUT"ENIRT Y:",Y
40 LRUN0,300

save 2

lrun0