mIRC notices window

menu menubar,channel {
  Ayar
  .$iif(%noticewindow,$style(1)) Notice Penceresi ( $+ $iif(%noticewindow,On,Off) $+ ) {
    if (%noticewindow) { unset %noticewindow | .disable #noticewindow | echo -a $timestamp 1,15Notice Penceresi 4KAPALI }
    else { set %noticewindow on | .enable #noticewindow | echo -a $timestamp 1,15Notice Penceresi 3AÇIK }
  }
}
#noticewindow on
on ^*:notice:*:?:{
  if (!$window(@notices)) { window -mel20 @notices }
  if (. !isin $nick) && (????serv !iswm $nick) && ($network != $nick) {
    echo -m @Notices $+(5-,$nick,-) $1- | .linesep @notices | notices $nick
    halt
  }
}
alias ln return $line(@notices,$1,1)
alias notices {
  if ($ln(0) = 0) { aline -l @notices $1 | sline -l @notices 1 | halt }
  unset %notices2
  set %notices $ln(0)
  while (%notices) {
    if ($1 != $ln(%notices)) { inc %notices2 }
    if ($1 = $ln(%notices)) { sline -l @notices %notices | halt }
    dec %notices
  }
  if (%notices2 = $ln(0)) { aline -l @notices $1   }
}
on *:input:@notices:{
  if ($left($1,1) != /) {
    .notice $sline(@notices,1) $1- | echo -a 2* notice sent to $+(",$sline(@notices,1),") ->12 $1- | .linesep @notices
  }
}
#noticewindow end