FM Synthesis | FM Basics (Part 5)

/////////////////////// FM SYNTHESIS | FM Basics (Part 5) ///////////////////////
/////////////////////////////// Sound Files ////////////////////////////////


s.boot;

// Run these methods below for visual cues.

s.meter;
s.scope;
s.plotTree;

// I use the following only when necessary.

s.reboot;
s.quit;


// Part 5 continues with the code established in Part 4, but with Sound Files.

////////////////// Things To Know Before Running Code //////////////////

/*

All my original SC documents are in the "dracula" color.
To find or change this, go To SuperCollider ––> Preferences ––> Editor ––> Font & Colors.
––> Select under Color, dracula.

Arguments in Synths are represented with a backslash, "\", in green under the "dracula" color font.
Values presented with these arguments can be changed. Only remember to NEVER cross 0, when using an exponential method like "exprand."

Arguments also precede a colon ":", as seen in a list of a UGen following a variable, "var."
Example: sig = PlayBuf.ar(2, buf, rate, startPos: spos);

Argument and variable names can be changed to your liking.

Please be careful with volume output. Always have SuperCollider run through headphones. If you're unsure what the output will be, keep headphones away, with your main volume all the way down. Check your level meter and Stethoscope for visual cues. If everything looks safe (e.g. level meter is NOT in the red), proceed.

You can always execute a hard stop with Command Period.

*/

///////////////////////  Syntax For Locating Sound Files In Folders ///////////////////////

~bufPath = PathName.new(thisProcess.nowExecutingPath).parentPath ++ "drone"; // <-- insert your sound folder, in place of where my "drone" folder is. Your folder can have any name.

// Here's another folder with 3 of my sound files.

~bufPath1 = PathName.new(thisProcess.nowExecutingPath).parentPath ++ "ambient";

(
b = PathName.new(~bufPath).entries.collect({
    arg pathname;
    Buffer.read(s, pathname.fullPath);
});
)

(
c = PathName.new(~bufPath1).entries.collect({
    arg pathname;
    Buffer.read(s, pathname.fullPath);
});
)

// Make sure your sound files play back. You should see in on the scope and level meters.

// I have 3 files in my "ambient" Folder. Thus, I have below: c[0], c[1], and c[2].
// 0, being the first sound file indexed in my Folder.

b[0].play;
b[0].duration;

c[0].play;
c[1].play;
c[2].play;

// All these are 20 seconds.

c[0].duration;
c[1].duration;
c[2].duration;


// SynthDefs

Env([0, 1, 0], [0.1, 3], [1, -5]).plot; // Envelope shape to reference.
// First array, [0, 1, 0], are levels.
// Second array, [0.1, 3], are times traversing between levels.
// Third array, [1, -5], are curve values.


// What's happening here? (Hint: We've covered this line of code in FM Basics, Parts 1 & 4.)

{LFPar.ar(LFPar.kr(LFPar.kr(0.2, 0, 8, 10), 0, 200, 800), 0, 0.1)!2}.play;
// Execute a hard stop with Command Period.


// You have two Parabolic Oscillators working as controls for a Parabolic audio signal.
// {LFPar.ar(), 0, 0.1)}, the outermost part of the Function, is the signal.

// The two innermost oscillators perform the following:

// Sine tone at 800Hz travels to 1000Hz, then to 600Hz, in the course of 5 seconds.
// 800+200=1000; 800-200=600Hz.
// Simultaneously, you have a modulatory fluctuation from 10 to 2 cycles every 5 seconds.
// 10-8=2. The integer 8 determines the lowest cycle value of the innermost parabolic oscillator.


// Integrate this into a SynthDef.

// IMPORTANT: Keep amp values low when experimenting. You can always increase the amp value after hearing the Synth.

(
SynthDef.new(\sinSine, {
    arg out=0;
    var sig;
    sig = LFPar.ar(LFPar.kr(LFPar.kr(0.25, 0, 8, 10), 0, 200, 800), 0, 0.1);
    sig = sig!2; // You will not need this for a stereo sound file.
    Out.ar(out, sig);
}).add;
)

Synth(\sinSine);
// Execute hard stop with Command Period.


// Now, for a sound file, you will only one Control signal (e.g. one LFPar) for the audio signal.
// Thus, I'm using only 2 LFPar UGens. By the way, you can use other UGen oscillators, though I'd avoid Pulse.

(
SynthDef.new(\sineSound, {
    arg buf=0, rate=1, spos=0, amp=1, pan=0, out=0;
    var sig, par;
    par = LFPar.ar(LFPar.kr(0.25, 0, 8, 10), 0, 0.5); // 0.5 is the mul value, which is scaling the output by one half.
    sig = PlayBuf.ar(
        2,
        buf,
        BufRateScale.kr(buf) * rate,
        spos
    );
    sig = sig * par;
    sig = Pan2.ar(sig, pan, amp);
    Out.ar(out, sig);
}).add;
)

Synth(\sineSound, [\buf, b[0]]);

// Command Period, or wait until the sound file is released at the end of its duration.
// NOTE: If you only have one sound file in a Folder, the code can be:
Synth(\sineSound, [\buf, 0]); // Notice, I do not include here the global variable, "b".


Synth(\sineSound, [\buf, c[0], \amp, rrand(0.8, 1)]);
// Go between c[0], c[1], and c[2]...if you have 3 sound files, like I have.


// IMPORTANT: Notice the Synths have not freed themselves. Let's work with an Envelope.


// Add an Envelope

Env([0, 1, 0], [0.1, 8], [1, -2]).plot;

// Here's another way of writing out the arguments.
// Check PlayBuf in the Help browser, in order to see the designated argument names.

(
SynthDef.new(\sineSound1, {
    arg buf=0, rate=1, spos=0, amp=1, pan=0,
    atk=0.1, rel=8, c1=1, c2=(-5), out=0;
    var sig, par, env;
    env = Env([0, 1, 0], [atk, rel], [c1, c2]).kr(2);
    par = LFPar.ar(LFPar.kr(0.25, 0, 8, 10), 0, 0.8);
    sig = PlayBuf.ar(
        numChannels: 2,
        bufnum: buf,
        rate: BufRateScale.kr(buf) * rate,
        startPos: spos
    );
    sig = sig * par * env;
    sig = Pan2.ar(sig, pan, amp);
    Out.ar(out, sig);
}).add;
)

Synth(\sineSound1, [\buf, b[0]]); // Synth releases after 8 seconds.
Synth(\sineSound1, [\buf, c[0], \rel, rrand(8, 12)]);


// Add argument names to change argument values in real time.
// Keep in mind, you don't need to name these in any particular order.

(
SynthDef.new(\sineSound2, {
    arg buf=0, rate=1, spos=0, atk=0.1, rel=12, c1=1, c2=(-5),
    parCtrl=0.25, parMin=8, parMax=10, addCtrl=0.8,
    amp=1, pan=0, out=0;
    var sig, par, env;
    env = Env([0, 1, 0], [atk, rel], [c1, c2]).kr(2);
    par = LFPar.ar(LFPar.kr(parCtrl, 0, parMin, parMax), 0, addCtrl);
    sig = PlayBuf.ar(
        numChannels: 2,
        bufnum: buf,
        rate: BufRateScale.kr(buf) * rate,
        startPos: spos
    );
    sig = sig * par * env;
    sig = Pan2.ar(sig, pan, amp);
    Out.ar(out, sig);
}).add;
)

Synth(\sineSound2, [\buf, b[0]]);
Synth(\sineSound2, [\buf, c[2]]);


// Add Arguments
// For \buf, go between Folders, if applicable (e.g. \buf, b[0], \buf, c[0], \buf, c[1], \buf, c[2]).


(
Synth(\sineSound2, [
    \buf, c[2],
    \amp, rrand(0.1, 1),
    \atk, rrand(0.1, 1),
    \rel, rrand(2, 8),
    \c1, rrand(1, 4),
    \c2, rrand(-1, -5),
    \parCtrl, rrand(0.125, 4),
    \parMin, rrand(3, 8),
    \parMax, rrand(9, 10),
    \addCtrl, rrand(0.1, 1),
]);
)


// Add the "midiratio" method to change the pitch of sound files.
// 0.midiratio is the original pitch. In my example, this is Middle C.
// +1 is up a half step; -1 is down a half step. Use the rate argument for this (e.g. \rate, 3.midiratio).


(
Synth(\sineSound2, [
    \buf, c[2],
    \rate, rrand(0, 24).midiratio,
    \amp, rrand(0.1, 1),
    \atk, rrand(0.001, 0.1),
    \rel, rrand(10, 20),
    \c1, rrand(1, 4),
    \c2, rrand(-1, -3),
    \parCtrl, rrand(0.125, 0.5),
    \parMin, rrand(5, 8),
    \parMax, rrand(9, 10),
    \addCtrl, rrand(0.5, 1),
]);
)


  --------------------------------------------------------------------------------
//////////////////////////////////////  Slower Motion //////////////////////////////////////

{LFPar.ar(LFPar.kr(0.2, 0, 400, 800), 0, 0.1)!2}.play;
// Execute hard stop with Command Period.


// SynthDef Version

(
SynthDef.new(\slowSine, {
    arg out=0;
    var sig;
    sig = LFPar.ar(LFPar.kr(0.2, 0, 400, 800), 0, 0.1);
    sig = sig!2;
    Out.ar(out, sig);
}).add;
)

Synth(\slowSine);

// Add an Envelope, Arguments, and Sound Files
// Note: Applying these values don't make the sound file aurally that interesting. This is because the FM values are more perceptible than the nature of the sound file.

(
SynthDef.new(\slowSine, {
    arg buf=0, rate=1, spos=0, atk=0.1, rel=8, c1=1, c2=(-5),
    parCtrl=0.25, parMin=400, parMax=800,
    parAmp=0.5, amp=1, pan=0, out=0;
    var sig, par, env;
    env = Env([0, 1, 0], [atk, rel], [c1, c2]).kr(2);
    par = LFPar.ar(LFPar.kr(parCtrl, 0, parMin, parMax), 0, parAmp);
    sig = PlayBuf.ar(
        2,
        buf,
        BufRateScale.kr(buf) * rate,
        spos
    );
    sig = sig * par * env;
    sig = Pan2.ar(sig, pan, amp);
    Out.ar(out, sig);
}).add;
)

Synth(\slowSine, [\buf, b[0]]);

(
Synth(\slowSine, [
    \buf, c[2],
    \rate, rrand(0, 12).midiratio, // Ranges between original pitch and 1 octave higher.
    \amp, rrand(0.5, 0.8),
    \atk, rrand(0.001, 0.1),
    \rel, rrand(8, 20),
    \c1, rrand(1, 4),
    \c2, rrand(-1, -2),
    \parCtrl, rrand(0.125, 0.5),
    \parMin, rrand(100, 200),
    \parMax, rrand(400, 800),
    \parAmp, rrand(0.3, 0.8)
]);
)

// Keep modulatory values low, if you want to perceive more the Sound File and less FM.

(
Synth(\slowSine, [
    \buf, c[2],
    \rate, rrand(0, 12).midiratio,
    \amp, rrand(0.8, 1),
    \atk, rrand(0.001, 0.1),
    \rel, rrand(8, 20),
    \c1, rrand(1, 4),
    \c2, rrand(-1, -2),
    \parCtrl, rrand(0.125, 0.5),
    \parMin, rrand(10, 20), // I suggest not exceeding 20, to have a better effect.
    \parMax, rrand(400, 500),
    \parAmp, rrand(0.5, 1)
]);
)