BackupBattlersData

BackupBattlersData:
	push {r4, lr}
	ldr r4, =(gAiStructPtr)
	ldr r3, [r4]
	ldr r4, [r3, #backup]
	cmp r0, #0x0
	beq BackupBattlers_Cont
	ldr r4, [r3, #backup2]
BackupBattlers_Cont:
	mov r0, r4
	ldr r1, =(battle_data)
	mov r2, #0x16
	lsl r2, #0x4					@0x160 (0x58 * 4)
	add r4, r2						@r4 = backup.statuses3
	bl WordMemCopy
	mov r0, r4
	ldr r1, =(gStatuses3)
	mov r2, #0x4 * 4
	bl WordMemCopy
	add r4, #0x10					@r4 = backup.status5
	mov r0, r4
	ldr r1, =(status5)
	mov r2, #0x2 * 4
	bl WordMemCopy
	add r4, #0x8					@r4 = backup.sideTimers
	mov r0, r4
	ldr r1, =(gSideTimers)
	mov r2, #0xC * 2
	bl WordMemCopy
	add r4, #0x18					@r4 = backup.battlers
	ldr r1, =(b_attacker)
	ldrb r0, [r1]
	strb r0, [r4]
	ldrb r0, [r1, #0x1]				@b_defender
	strb r0, [r4, #0x1]
	add r4, #0x2					@r4 = backup.weather
	ldr r1, =(weather)
	ldrh r0, [r1]
	strh r0, [r4]
	add r4, #0x2					@r4 = backup.disableStructs
	mov r0, r4
	ldr r1, =(gDisableStructs)
	mov r2, #0x1C * 4
	bl WordMemCopy
	add r4, #0x70					@r4 = backup.sideStatuses
	ldr r1, =(gSideStatuses)
	ldrh r0, [r1]
	strh r0, [r4]
	ldrh r0, [r1, #0x2]
	strh r0, [r4, #0x2]
	add r4, #0x4					@r4 = backup.fieldstatus
	ldr r1, =(fieldstatus)
	ldr r0, [r1]
	str r0, [r4]
	ldr r0, [r1, #0x4]
	str r0, [r4, #0x4]
	add r4, #0x8					@r4 = backup.sidestatus
	ldr r1, =(sidestatus)
	ldr r0, [r1]
	str r0, [r4]
	ldr r0, [r1, #0x4]
	str r0, [r4, #0x4]
	pop {r4, pc}