Inno Script - TextReplace

; Определяем замены. Имена, которые будут заменены их значениями.

#define ProjectDir "D:\MyDocum\TextReplace\!Install"
#define MyAppName "TextReplace"
#define MyAppExeName "TextReplace"
#define MyAppVersion "1.1"
#define MyAppURL "http://azjio.ucoz.ru/"
#define MyAppPublisher "AZJIO_Soft"
#define Author "AZJIO"

; Параметры установщика. Пути, ссылки, сжатие, иконки
[Setup]
; Не используйте уникальный AppId-GUID в установщиках для других приложений.
; (Чтобы создать новый идентификатор GUID, нажмите Сервис | Генерировать GUID в интегрированной среде разработки).
AppId={{A03705FC-3743-429B-99B4-7864C94DD003}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\{#Author}_Soft\{#MyAppExeName}
DefaultGroupName={#Author}_Soft\{#MyAppExeName}
AllowNoIcons=yes
LicenseFile={#ProjectDir}\RootFolder\License.txt
OutputDir={#ProjectDir}
OutputBaseFilename={#MyAppExeName}_Setup
SetupIconFile={#ProjectDir}\icons\Setup.ico
Compression=lzma2
SolidCompression=yes
ArchitecturesInstallIn64BitMode=x64

; Задаёт свойства файла установщика
VersionInfoVersion={#MyAppVersion}
VersionInfoCompany={#MyAppPublisher}
VersionInfoCopyright={#Author}
VersionInfoDescription={#MyAppExeName}_Setup.exe

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"
Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl"

; Задачи. Текущая создать ли иконку на рабочем столе
[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked
; Name: "readme"; Description: "Readme"; Flags: unchecked

; Файлы дистрибутива. Источник - папка, Назначение - папка приложения
; Флаги: папки-рекурсивно, заменять игнорируя версии, создавать все подкаталоги
[Files]
Source: "{#ProjectDir}\RootFolder\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "{#ProjectDir}\icons\unins000.ico"; DestDir: "{app}"; Flags: ignoreversion
; Source: "{#ProjectDir}\RootFile\TextReplace.chm"; DestDir: "{app}"; Flags: ignoreversion
; Source: "{#ProjectDir}\RootFile\Readme.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "{#ProjectDir}\RootFile\TextReplace.exe"; DestDir: "{app}"; Check: IsOtherArch; Flags: ignoreversion solidbreak
; Параметр Check проверяет триггер 64-битной системы, чтобы извлечь соответствующий файл
Source: "{#ProjectDir}\RootFile\TextReplaceX64.exe"; DestDir: "{app}"; DestName: "TextReplace.exe"; Check: IsX64; Flags: ignoreversion solidbreak
; Добавляет на последнем шаге установке "Прочитать Readme.txt", но отсутствует возможность unchecked
; Только один файл может быть с флагом isreadme
; Source: "{#ProjectDir}\RootFile\Readme.txt"; DestDir: "{app}"; Flags: isreadme
; Source: "{#ProjectDir}\RootFile\TextReplace.chm"; DestDir: "{app}"; Flags: isreadme
; Примечание: Не используйте "Flags: ignoreversion" для любых общих системных файлов

; Секция создаёт иконки ярлыкам, установщику, деинсталятору
; {group} - Главное меню всех пользователей. Filename - путь от {app} - папки установки
; {commondesktop} - этот ярлык на рабочий стол
[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}.exe"
Name: "{group}\{#MyAppName} Help"; Filename: "{app}\{#MyAppExeName}.chm"
Name: "{group}\{cm:ProgramOnTheWeb,{#MyAppName}}"; Filename: "{#MyAppURL}"
Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"; IconFilename: "{app}\unins000.ico"
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}.exe"; Tasks: desktopicon

; Предложить запустить программу
[Run]
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent unchecked

; Две функции проверяют что 32-битная система или 64-битная
[Code]
function IsX64: Boolean;
begin
  Result := Is64BitInstallMode and (ProcessorArchitecture = paX64);
end;

function IsOtherArch: Boolean;
begin
  Result := not IsX64;
end;