Get all units for each side according to mods

span class="re5"> TRA_data = [
    [ [], [], [], [], [], [], [] ], //EAST
    [ [], [], [], [], [], [], [] ], //WEST
    [ [], [], [], [], [], [], [] ], //INDEPENDENT
    [ [], [], [], [], [], [], [] ]  //CIVILIAN
];

// Returns True/False
TRA_modCheck = {
    params ["_class"];
    private _mod = configSourceMod (configFile >> "CfgVehicles" >> configName _class);

    if (_mod in ["@RHSUSAF", "@RHSAFRF", "@RHSGREF"]) exitWith {
        true
    };
    false
};

{
    if ( getNumber( _x >> "scope" ) isEqualTo 2 ) then {
        _index = switch ( true ) do {
            case ( configName _x isKindOf "CAManBase" ) : {
                0
            };
            case ( configName _x isKindOf "Car_F" ) : {
                1
            };
            case ( configName _x isKindOf "Tank" ) : {
                2
            };
            case ( configName _x isKindOf "Helicopter" ) : {
                3
            };
            case ( configName _x isKindOf "Plane" ) : {
                4
            };
            case ( configName _x isKindOf "Ship" ) : {
                5
            };
            case ( configName _x isKindOf "StaticWeapon" ) : {
                6
            };
            default{ -1 };
        };

        if ( _index > -1 ) then {
            _side = getNumber( _x >> "side" );
            if ( _side in [ 0, 1, 2, 3 ] ) then {
                if (_x call TRA_modCheck) then {
                    TRA_data select _side select _index pushBack configName _x;
                };
            };
        };
    };
}forEach ( "true" configClasses( configFile >> "CfgVehicles" ));